根据关键字拆分表

寻桑人

工资表里面想根据B列部门，拆分成5个sheet，分别按1部、2部、3部、4部、5部命名，每个sheet里面都只有关键字部门的内容。在网上找到了一个代码，但是现在想要每个部门之间多一个空格隔开（大家发工资条的时候都是要隔开的吧），希望大神能帮忙解决下，正在学vba，菜鸟一枚！

寻桑人

不是在1部、2部、3部、4部、5部里面写代码，是把工资汇总表里面的那个代码改下，自动生成的是有空格的，大家不要想错了

gdw831001

透视表应该可以解决的吧

魂断蓝桥

寻桑人 发表于 2016-9-5 11:48
不是在1部、2部、3部、4部、5部里面写代码，是把工资汇总表里面的那个代码改下，自动生成的是有空格的，大 ...

Sub a()
Dim arr, brr(1 To 999, 1 To 18), i%, j%, m%, d, sh As Worksheet, k, x%, t
Set d = CreateObject("Scripting.Dictionary")
Application.DisplayAlerts = False
Application.ScreenUpdating = False
For Each sh In Sheets
    If sh.Name <> "工资汇总表" Then
        sh.Delete
    End If
Next
Application.DisplayAlerts = True
arr = Sheet1.[a1].CurrentRegion
For i = 2 To UBound(arr)
    d(arr(i, 2)) = ""
Next
k = d.keys
Set d = Nothing
For x = 0 To UBound(k)
    For i = 2 To UBound(arr)
        If arr(i, 2) = k(x) Then
            m = m + 1
            t = t + 1
            For j = 2 To 18
                    brr(m, 1) = t
                    brr(m, j) = arr(i, j)
                    brr(m + 1, 1) = ""
                    brr(m + 1, j) = ""
            Next
                m = m + 1
        End If
    Next
        Sheets.Add(after:=Sheets(Sheets.Count)).Name = k(x)
        Sheet1.[a1:r1].Copy [a1]
        [a2].Resize(m, 18) = brr
        m = 0
        t = 0
Next
Application.ScreenUpdating = True
End Sub

zhangzhang

详见附件》》》》》》》》》》》》》》

寻桑人

我弄掉了一个，除了空格以外还有首行的标题。

寻桑人

zhangzhang 发表于 2016-9-5 13:15
详见附件》》》》》》》》》》》》》》

你这个和我上传的是一样的，传错了吗

zhangzhang

Sub 如何将一个Excel工作表的数据拆分成多个工作表()
    Dim Arr, Rng As Range, Sht As Worksheet, Dic As Object
    Dim k, t, Str As String, i As Long, lc As Long, lr As Long
    Application.ScreenUpdating = False '关闭屏幕更新
    Arr = Range("A1").CurrentRegion.Value
    lc = UBound(Arr, 2) '求取最后一列的列号
    Set Rng = Range("A1").Resize(, lc) '标题行
    Set Dic = CreateObject("Scripting.Dictionary") '创建字典
    For i = 2 To UBound(Arr)
        Str = Arr(i, 2) '关键字
        If Not Dic.Exists(Str) Then '如果字典没有关键字
            Set Dic(Str) = Cells(i, 1).Resize(, lc) '把当前行装入到字典中
        Else '否则(字典中存在关键字)
            Set Dic(Str) = Union(Dic(Str), Cells(i, 1).Resize(, lc)) '把行连合起来
        End If
    Next
    k = Dic.Keys '字典关键字集合
    t = Dic.Items '字典项目集合
    On Error Resume Next
    With Sheets
        For i = 0 To Dic.Count - 1 '循环关键字的个数
            Set Sht = .Item(k(i)) '给变量赋值(工作表名为关键字)
            If Sht Is Nothing Then '该工作表不存在则插入一个空工作表
                .Add(After:=.Item(.Count)).Name = k(i) '新建的工作表将置于所有工作表之后，并命名为关键字
                Set Sht = ActiveSheet '活动工作表给变量
            Else '否则
                Sht.Cells.Clear '清除工作中所有内容和格式
            End If
            'Rng.Copy Sht.Range("A1") '把标题写入第一行
            t(i).Copy Sht.Range("A1") '写入其他内容
            Sht.Cells.EntireColumn.AutoFit '自动调整全工作表单元格的列宽
            Set Sht = Nothing '变量处于初始状态
        Next
    End With
   
    For i = 0 To Dic.Count - 1
        lr = Sheets(k(i)).Range("A65536").End(xlUp).Row
            For lc = lr To 1 Step -1
                Sheets(k(i)).Rows(lc).Insert
                Sheets(k(i)).Rows(lc).Insert
                Rng.Copy Sheets(k(i)).Cells(lc + 1, 1)
            Next lc
        Sheets(k(i)).Rows(1).Delete
    Next i
   
    Set Dic = Nothing
    Sheets(1).Activate '第1个工作表处于激活状态
    Application.ScreenUpdating = True '打开屏幕更新

End Sub

zhangzhang

详见附件》》》》》》》》》》》》

寻桑人

zhangzhang 发表于 2016-9-5 22:00
Sub 如何将一个Excel工作表的数据拆分成多个工作表()
    Dim Arr, Rng As Range, Sht As Worksheet, Dic  ...

大神，厉害，厉害。就是这样的。谢谢了