急！！！根据车牌号码特征判断车类型

lizhiliang531

各位大神好：有个问题需要请教，万分感激。要求如下：
表1

城市	车牌号	本地车/外地车
北京	京Q0M
北京	京GKZ
北京	京YAL
北京	京LP8
北京	京Q9D
北京	津QM2
北京	京Q50
北京	冀R1X
北京	京QP1
杭州	浙A41
杭州	沪A11
杭州	浙E0Y

表2
车牌特征判断依据

城市	车牌号
北京	京
天津	津
杭州	浙A

要求：C列判断是外地车还是本地车
1、城市是北京的，车牌号含有京的即为本地车
2、城市是天津的，车牌号含有津的即为本地车
3、城市是杭州的，车牌号前两位是浙A的即为本地车

只列举了几个例子，实际数据量很大，城市也很多，希望有方便的办法根据表2解决表1这个问题

dingding0211

虽然我的水平不能直接解决你的问题，但是我觉得有必要建立一个辅助表，就是本地车的对应关系，北京 京，天津 津 ，吉林 吉，这样的。。。

tianyunjie

=IFERROR(IF(LOOKUP(1,0/(LEFT(B2)=LEFT($G$2:$G$4)),$F$2:$F$4)=A2,"本地车","外地车"),"外地车")

zengyidin

数组公式

1. =IF(COUNT(FIND(F$2:G$4,A2:B2))=2,"本地车","外地车")

复制代码

新建_Microsoft_Excel_工作表.rar (7.63 KB, 下载次数: 25)

2016-7-27 11:19 上传

点击文件名下载附件

问山8828680

IFERROR(IF(LOOKUP(,-FIND($G$2:$G$4,B2),$F$2:$F$4)=A2,"本","外"),"外")&"地车"

dingding0211

问山8828680 发表于 2016-7-27 11:20
IFERROR(IF(LOOKUP(,-FIND($G$2:$G$4,B2),$F$2:$F$4)=A2,"本","外"),"外")&"地车"

学习咯，好厉害~~~

heike2004

=IF(SUM((LEFT(B2)={"京","津"})*1,(LEFT(B2,2)="浙A")*1),"本地车","外地车")数组

袁勇

非数组：

1. =IF(OR(MMULT(ISNUMBER(FIND(F$2:G$4,A2:B2))*1,{1;1})=2),"本","外")

复制代码

七夕、

1. =TEXT(IFERROR(-(LOOKUP(,-FIND(G$2:G$4,B2),F$2:F$4)=A2),),";本;外")&"地车"

复制代码

Mr宋

1. =IF(ISERR(FIND(VLOOKUP(A2,$F$2:$G$4,2,),B2)),"外地车","本地车")

复制代码