一个纯数字字符串的冒泡排序

sealand71

一个字符串，如34681479345803782369，请问要怎么样对它进行冒泡排序呢，我试了好久都搞不好，请大师帮帮忙，谢谢。
字符串长度固定20位

如附件，A1单元格为原始数据，A3单元格为需要的效果，请大师帮忙，谢谢

我是来讨说法的

冒泡排序，百度一搜一大堆
For i = 1 To n - 1
For j = 1 To n-i
If a(j) > a(j+1) Then
temp=a(j)： a(j)=a(j+1)： a(j+1)=temp
End if
Next j
Next i

蓝桥玄霜

附件不能显示？

sealand71

已修复，请帮我看一下

sealand71

蓝桥玄霜 发表于 2016-7-14 15:20
附件不能显示？

附件已修复，请帮我看一下，谢谢

蓝桥玄霜

请见代码。

sealand71

谢谢，你这种方法稍微复杂一点，我无法理解，不过还是谢谢你

香川群子

sealand71 发表于 2016-7-16 17:54
谢谢，你这种方法稍微复杂一点，我无法理解，不过还是谢谢你

纯数字字符串的排序，可以通过定义数组a(9)来记录数字并得到自然的排序结果，
即：数组a的0-9位置下标，可作为自然排序的指针，无需单独进行一个排序过程。

例如： 32198 排序过程：
定义a(9) 结果为 --------- （这里以-代替空白）
取3 存入数组得到  ---3------
取2 存入数组得到  --23------
取1 存入数组得到  -123------
取9 存入数组得到  -123-----9
取8 存入数组得到  -123----89

因此，尽管按原数值字符串先后顺序读取到的结果是乱序的，
但存入a(9)数组后自然就得到了按数字顺序（其实也是数组a的下标顺序）的排序结果。

就是这么简单、高效！

写成自定义函数的代码示例：

1. Function f(t)
   
2.     Dim a(9)
   
3.     For i = 1 To Len(t)
   
4.         s = Mid(t, i, 1)
   
5.         a(s) = a(s) & s
   
6.     Next
   
7.     f = Join(a, "")
   
8. End Function

复制代码

香川群子

另外，如果是任意文本字符串，则无法用定义数组a(9)的方法来排序，
只有通过比较排序来完成。

以下是我写的逐个插入比较排序代码。
过程稍复杂，但效率比冒泡排序高一些。

1. Function f(t) '本排序方法可以对任意字符串进行逐个排序，不比限制对象为数值串
   
2.     l = Len(t) '字符串长度l
   
3.     ReDim a(l - 1) '定义存放排序结果的数组a
   
4.     For i = 1 To l '遍历字符串中每个字符
   
5.         s = Mid(t, i, 1) '提取i位置该字符s
   
6.         For j = 0 To n   '从低位开始把已排序的n个结果依次和s作比较(n起始=0)
   
7.             If a(j) > s Then '如果当前j位置值已经比该字符s更大则不用继续比了 说明s就该排序在这个j位置
   
8.                 For k = n To j + 1 Step -1 '把当前j位置开始所有比s更大的值 倒序向后移动1个位置以便腾出当前j为空位
   
9.                     a(k) = a(k - 1) '依次倒序向后移动1个位置
   
10.                 Next
    
11.                 a(k) = s '腾出的当前j空位写入s 完成s的排序
    
12.                 Exit For '退出本次s值的检查比较
    
13.             End If
    
14.         Next
    
15.         If j > n Then a(j - 1) = s '如果检查到n都没有比s值更大的值，则s为最大值应该在最后位置写入s
    
16.         n = n + 1 '记录已经完成排序的个数(位置)
    
17.     Next
    
18.     f = Join(a, "") '完成所有值的比较排序 输出合并字符串
    
19. End Function

复制代码

香川群子

下面介绍正宗的冒泡算法排序：

1. Function f(t) '本方法采用冒泡排序算法可以对任意字符串进行逐个排序，不比限制对象为数值串
   
2.     l& = Len(t) '字符串长度l
   
3.     ReDim a(1 To l) '定义存放排序结果的数组a
   
4.     For i = 1 To l '遍历字符串中每个字符
   
5.         a(i) = Mid(t, i, 1) '提取i位置该字符s 写入待排序的数组a
   
6.     Next
   
7.     Call BubbleSortA(a, 1, l) '调用冒泡排序算法函数过程
   
8.     f = Join(a, "") '完成所有值的比较排序 输出合并字符串
   
9. End Function
   
10. 
    
11. Sub BubbleSortA(tr, l&, u&) '上浮冒泡算法
    
12.     Dim i&, j&, t$
    
13.     For i = l To u - 1 '检查每一个值
    
14.         For j = u To i + 1 Step -1 '从底部开始倒序检查到已完成排序的i+1位置
    
15.             If tr(j) < tr(j - 1) Then t = tr(j): tr(j) = tr(j - 1): tr(j - 1) = t
    
16.             '如当前值较小就向前交换位置完成一对数的排序交换 看上去较小的数会不断冒泡向上浮动
    
17.         Next
    
18.     Next
    
19. End Sub
    

复制代码