求助，vba中SQL语句能否多次重复执行！

左手转弯

vba中SQL语句能否多次重复执行，条件语句带一个变量，每次只执行第一个，后面几个都查询不到数据。oracle数据库源.

Renco

LZ你问的比较笼统，可能你的意思是，相让数据库返回，多组数据集，每组数据集都有一个独立的SQL语句，当然参数变量等都可能不一样，一般呢VBA用ADO对象和语法来解决，对于这类多记录集返回的，主要是有两种方式，用多个recordset对象来对应多个返回记录集，也就类似于，把你想要的多个SQL,分别运行一次，一次只运行一个查询的SQL，
第二种方式呢，用一句SQL，默认打开的是你的第一句SQL,然后你的recordset对象用NextRecordset方法，来切到你的下一个记录集，

建议你用第一种方式，

左手转弯

Renco 发表于 2016-6-14 16:08
LZ你问的比较笼统，可能你的意思是，相让数据库返回，多组数据集，每组数据集都有一个独立的SQL语句，当然 ...

谢谢老师!我上面的问题，我自己解决了！但是不知道我理解的是不是正确的！
下面是我之前的代码，每次只能更新最先遍历的那个工作表：
Private Sub 更新数据_Click()
    Dim Conn As Object, rs As Object
    Dim ws As Worksheet
    Dim gzbm As String
    Dim strConn As String
    Dim sql As String
    On Error Resume Next

    Set Conn = CreateObject("ADODB.connection")
    Set rs = CreateObject("ADODB.Recordset")
    strConn = "Provider=MSDAORA.1; user id="
    strConn = strConn & txt用户名.Value
    strConn = strConn & "; password=" & txt密码.Value
    strConn = strConn & "; data source = " & txt数据库.Value
    strConn = strConn & "; Persist Security Info=True"

    For Each ws In Worksheets
        If ws.Name <> "增加工作表" Then
            gzbm = ws.Name
            Conn.Open strConn
            sql = "SELECT RQ,SCSJ,FROM SD.DBA01 DBA01 WHERE (MZ='" & gzbm & "') ORDER BY RQ"
            rs.Open sql, Conn
            ThisWorkbook.Sheets(gzbm).[A3].CopyFromRecordset rs
            Conn.Quit
            Set Conn = Nothing
        End If
    Next
End Sub

左手转弯

我的解决问题之后的代码在下面，也就是把Set Conn = CreateObject("ADODB.connection")，Set rs = CreateObject("ADODB.Recordset") 把这两句放在For Each……循环里面。我认为是这样，代码开始执行时候前面两句Set rs、Set Con执行了，当第一个SQL执行完后，Conn.Quit ，Set Conn = Nothing 这两句关闭了数据库，第二次循环执行的时候从FOR each……开始执行，没有执行Set rs、Set Con，相当于数据没有再次连接上。 不知道这么理解对不对！
   
Private Sub 更新数据_Click()
    Dim Conn As Object, rs As Object
    Dim ws As Worksheet
    Dim gzbm As String
    Dim strConn As String
    Dim sql As String
    On Error Resume Next
    strConn = "Provider=MSDAORA.1; user id="
    strConn = strConn & txt用户名.Value
    strConn = strConn & "; password=" & txt密码.Value
    strConn = strConn & "; data source = " & txt数据库.Value
    strConn = strConn & "; Persist Security Info=True"

    For Each ws In Worksheets
        If ws.Name <> "增加井号" Then
            gzbm = ws.Name
            Set Conn = CreateObject("ADODB.connection")
            Set rs = CreateObject("ADODB.Recordset")
            Conn.Open strConn
            sql = "SELECT RQ,SCSJ,FROM SD.DBA01 DBA01 WHERE (MZ='" & gzbm & "') ORDER BY RQ"
            rs.Open sql, Conn
            ThisWorkbook.Sheets(gzbm).[A3].CopyFromRecordset rs
            Conn.Quit
            Set Conn = Nothing
        End If
    Next
End Sub

Renco

从资源和效率方面，应当把
Set Conn = CreateObject("ADODB.connection")
            Set rs = CreateObject("ADODB.Recordset")
Conn.Open
放在For..next 外面
从数据连接方面，我们是先连接到数据库源，再去打开我们需要的数据集，这循环中，原则上我们只要连接数据库源一次就行了，所以不必要在For 。。。next里如下进行个更改：

Private Sub 更新数据_Click()
    Dim Conn As Object, rs As Object
    Dim ws As Worksheet
    Dim gzbm As String
    Dim strConn As String
    Dim sql As String
    On Error Resume Next
    strConn = "Provider=MSDAORA.1; user id="
    strConn = strConn & txt用户名.Value
    strConn = strConn & "; password=" & txt密码.Value
    strConn = strConn & "; data source = " & txt数据库.Value
    strConn = strConn & "; Persist Security Info=True"
   
   Set Conn = CreateObject("ADODB.connection")
    Set rs = CreateObject("ADODB.Recordset")
   Conn.Open strConn

    For Each ws In Worksheets
        If ws.Name <> "增加井号" Then
            gzbm = ws.Name
           
            sql = "SELECT RQ,SCSJ,FROM SD.DBA01 DBA01 WHERE (MZ='" & gzbm & "') ORDER BY RQ"
            rs.Open sql, Conn
            ThisWorkbook.Sheets(gzbm).[A3].CopyFromRecordset rs
            rs.close   '记得用完了，要关闭
           
        End If
    Next

  Conn.close   'ADO的Connection，没有Quit的用法，而是用Close来关闭，后面用 Set 对象=Nothing 来释放资源

Set rs = Nothing
Set Conn = Nothing
End Sub

生活如水

Renco 发表于 2016-6-15 11:30
从资源和效率方面，应当把
Set Conn = CreateObject("ADODB.connection")
            Set rs = CreateOb ...

您好！请教您一个问题，我使用ADO+SQL查询数据表，采用自连接方式，执行第一次SQL后，代码中有CNN.CLOSE和SET CNN=NOTHING语句，当修改数据源的数据后，再次执行SQL，得到的结果是修改前的数据，
请问有没有什么办法在不关闭工作簿的情况下，让再次执行SQL可以查询到最新数据。经测试，如果把工作簿关掉，再打开，执行SQL可以查询到前面修改的数据。

生活如水

在家用13版本的，可以更新了，谢谢！

冰狩

左手转弯 发表于 2016-6-14 18:57
谢谢老师!我上面的问题，我自己解决了！但是不知道我理解的是不是正确的！
下面是我之前的代码，每次只 ...

传一下文件看看可以吗，感兴趣