VBA SQL设置CursorLocation出现参数类型不正确，或不在可以接受的范围之...

rockmantom

请教各位一下，我想通过Public Sub TExecuteSQL（ByVal strSQL As String, Optional ByVal PathStr As String）函数来实现给定sql语句strSQL和文件全名PathStr自动进行sql查询并将结果输出为动态数组，本来已经实现运行了好几天都没问题，但是现在突然将代码复制到新的excel文件里面就报错了，错误信息：参数类型不正确，或不在可以接受的范围之内，或与其他参数冲突请帮忙看看到底是什么问题，谢谢

代码如下：（黄色部分为出现错误的位置）
Public Sub TExecuteSQL(ByVal strSQL As String, Optional ByVal PathStr As String) 'TEST
Dim Conn As Object, Rst As Object
Dim strConn As String
Dim i As Integer, j As Integer
On Error GoTo ExecuteSQL_Error
Set Conn = CreateObject("ADODB.Connection")
Set Rst = CreateObject("ADODB.Recordset")
If PathStr = "" Then PathStr = ThisWorkbook.FullName
Select Case Application.Version * 1
    Case Is <= 11
        strConn = "Provider=Microsoft.Jet.OLEDB.4.0;Extended Properties=Excel 8.0;Data Source=" & PathStr
    Case Is >= 12
        strConn = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & PathStr & ";Extended Properties=""Excel 12.0;HDR=YES"";"""
End Select
Conn.CursorLocation = adUseClient
Conn.Open strConn
Set Rst = Conn.Execute(strSQL)
ReDim aRst(1 To Rst.RecordCount + 1, 1 To Rst.Fields.Count)
For i = 1 To UBound(aRst, 2)
    aRst(1, i) = Rst.Fields(i - 1).Name
Next i
Rst.MoveFirst
For i = 2 To UBound(aRst, 1)
    For j = 1 To UBound(aRst, 2)
        aRst(i, j) = Rst.Fields(j - 1).Value
    Next j
    Rst.MoveNext
Next i
ExecuteSQL_Exit:
    Set Rst = Nothing
    Set Conn = Nothing
    Exit Sub
ExecuteSQL_Error:
    MsgBox "错误原因:" & Err.Description
    Resume ExecuteSQL_Exit
End Sub

opiona

删除此行代码试试！

xd3210

是带pathstr参数出现错误？还是不带出现错误？还是带与不带均出现错误？又不是真正的数据库，无所谓用户端和服务器端，删除此句不会影响运行结果的。

rockmantom

删除“Conn.CursorLocation = adUseClient”这一行代码，其他运行没问题，但是会在下面几行引用“Rst.RecordCount”这一项时会报错，不知道是什么情况

opiona

SQL在Excel VBA的使用，请参考我的帖子：http://club.excelhome.net/thread-859194-1-1.html

opiona

简单示例代码：

1.     Set SH1 = Sheets("Information")
   
2.     Set SH2 = Sheets("Search")
   
3.     SH2.Range("A1:F1048576").ClearContents
   
4.    
   
5.     Str_coon = "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties='Excel 12.0;HDR=yes';Data Source =" & ThisWorkbook.FullName     '//OFFICE2007
   
6.    
   
7.     StrSQL = "SELECT 设备名称,设备编号 FROM [" & SH1.Name & "$] "
   
8. 
   
9.     Dim CN, RS
   
10.     Set CN = CreateObject("Adodb.Connection") '//新建一个ADO连接
    
11.     Set RS = CreateObject("adodb.recordset")
    
12.     CN.Open Str_coon
    
13.     RS.Open StrSQL, CN, 1, 3
    
14.     For ICOL = 0 To RS.Fields.Count - 1 '循环所有查询结果的列
    
15.         SH2.Cells(1, ICOL + 1) = RS.Fields(ICOL).Name
    
16.     Next ICOL
    
17.     SH2.Range("A2").CopyFromRecordset RS
    
18.     CN.Close  '//关闭ADO连接
    
19.     Set RS = Nothing
    
20.     Set CN = Nothing  '//释放内存

复制代码

rockmantom

opiona 发表于 2016-5-10 21:22
简单示例代码：

但是不设置CursorLocation = adUseClient，就没法使用recordcount，没办法读取记录的条数，我想用recordcount读取记录条数，用于设置动态数组的上限

xd3210

rockmantom 发表于 2016-5-10 23:33
但是不设置CursorLocation = adUseClient，就没法使用recordcount，没办法读取记录的条数，我想用recordc ...

将这句Set Rst = Conn.Execute(strSQL)改成rst.open strsql,conn,1,3

rockmantom

xd3210 发表于 2016-5-11 08:41
将这句Set Rst = Conn.Execute(strSQL)改成rst.open strsql,conn,1,3

谢谢，改成rst.open strsql,conn,1,3是可以了，但是不知道原来的出错原因是什么

sylwg557

直接设置成
CursorLocation = 3
就OK了。