[第114期]根据需要提取字符.

满坛皆为吾师

开启迭代50次
C1公式

1. MOD(C1,50)+1

复制代码

C2公式 03版63字符

1. =IF(C$1-1,C2,)&MID(A2,C$1,MATCH(MID(A2,C$1,1),{"";"A";"吖"})=B2)

复制代码

满坛皆为吾师

开启迭代50次
C1公式

1. =MOD(C1,50)+1

复制代码

C2公式 03版58字符

1. =IF(C$1-1,C2,)&MID(A2,C$1,LENB(TEXT(MID(A2,C$1,1),))=B2-1)

复制代码

horselyq

开启迭代，默认100

C1公式：  =MOD(C1,100)+1

C2公式：  =IF(C$1>1,C2&REPT(MID(A2,C$1-1,1),MATCH(MID(A2,C$1-1,1)&1,{0,99,"吖"}&0)=B2),"")

笨笨四

开启迭代，100次：
C1=MOD(C1,100)+1
C2=REPT(C2&MID(1&A2,C$1,SUM(1,N(MID(1&A2,C$1,1)>{"9","z"}))=B2),C$1>1)
数组下拉C2

bl5062

=TEXT(CHOOSE(COLUMN()-3,INDEX(A:A,MATCH(,COUNTIF(D$1:D1,A$1:A18),)),IFERROR(INDEX(A:A,MIN(IF(SUMIFS(B:B,$A:$A,C2,A:A,A$2:A18)=--E2,ROW($2:18)))),),MAX(SUMIFS(A:A,$A:$A,B2,$B:$B,$B$2:$B99))),"0;;;@")

delete_007

只能想到用迭代计算了。
启用迭代计算，设置迭代次数为50
C1公式：

1. =MOD(C1,50)+1

复制代码

C2公式（78字）向下复制：

1. =IF(C$1>1,C2&IF(MATCH(MID(A2,C$1-1,1),{"","A","吖"})=B2,MID(A2,C$1-1,1),""),"")

复制代码

CLL1998

需启用迭代运算

太阳之子

C1=MOD(C1+1,201), 迭代200次

1. =REPLACE(IF(C$1,C2,A2),MATCH(1=1,MATCH(MID(IF(C$1,C2,A2)&"0A吖",ROW($1:99),1),{"0","A","吖"})<>B2,),1,)

复制代码

bajifeng

这题出的好，很实用，但感觉好难。
新人第一次参加竞赛，花了一个星期研究，最后终于算出结果来了。
>>>>>>>>>>>>>>>>>>>>

第1版公式：
345字符
C2:

1. =IF($C$1=1,A2,IF(OR(C2="",C2=0),"",IF(MIN(CODE(MID(C2,ROW(INDIRECT("1:"&LEN(C2))),1)))<MAX((B2={2;3})*{58;123}),SUBSTITUTE(C2,CHAR(MIN(CODE(MID(C2,ROW(INDIRECT("1:"&LEN(C2))),1)))),),IF(MAX(CODE(MID(C2,ROW(INDIRECT("1:"&LEN(C2))),1)))>MAX((B2={1;2;3})*{58;123;99999}),SUBSTITUTE(C2,CHAR(MAX(CODE(MID(C2,ROW(INDIRECT("1:"&LEN(C2))),1)))),),C2))))

复制代码

辅助单元格 C1: 0、1

公式使用 说明：

1、C1为辅助单元格，其值输入1时刷新数据，其值输入0后并连续按F9迭代运算得到结果。

2、C2输入公式并按Ctrl+Shift+Enter结束，下拉至C31;

3、A列、B列数据变化或答案区域C列为空时，在C1先输入1刷新数据后再输入0，连续按F9到最后出现结果。

4、此公式为数组公式并需要开启迭代计算。

第1版公式详见附件。
>>>>>>>>>>>>>>>>>>>>

第2版公式：
159字符
C2:

1. =IF(C$1=0,"",IF(C$1>LEN(A2),C2,C2&IF(AND(CODE(MID(A2,C$1,1))<SUM((B2={1;2;3})*{58;123;99999}),CODE(MID(A2,C$1,1))>SUM((B2={2;3})*{58;123})),MID(A2,C$1,1),"")))

复制代码

辅助单元格 C1:
=IF(B2>0,IF(C1>99,C1,C1+1),0)
第2版公式详见附件。
>>>>>>>>>>>>>>>>>>>>

第3版公式：
157字符
C2:

1. =IF(B$2,IF(C$1>LEN(A2),C2,C2&IF(AND(CODE(MID(A2,C$1,1))<SUM((B2={1;2;3})*{58;123;99999}),CODE(MID(A2,C$1,1))>SUM((B2={2;3})*{58;123})),MID(A2,C$1,1),"")),"")

复制代码

辅助单元格 C1:
=IF(B2,IF(C1>99,C1,C1+1),0)
第3版公式详见附件。
>>>>>>>>>>>>>>>>>>>>

xzk235

C2

1. =IF(C$1,C2&IF(MATCH(MID(A2&REPT("a",99),C$1,1),{"0","A","吖"})=B2,MID(A2,C$1,1),""),"")

复制代码

C1

1. =IF(C1=99,0,C1+1)

复制代码

为了实现C1迭代从0-99循环，先将迭代次数设为99，输入C1公式，此时应该是显示99，再次迭代次数设为100，这样每样重新计算C1的值最终都是99
这一步整的有点麻烦了，不能这么处理的话，那C1的值要放到C2公式处理，C2公式会超出88字符。