何实现一个表格的内容自动追加到另外一个表格？

hpy2015

如图所示，要实现如下功能：
1、点击新增合同后把合同内容自动追加到台账最后一行。
2、点击添加付款后根据合同编号及年月把付款金额及发《he》票《xie》金额添加到相应的地方。



单位合同非常的多，付款也比较复杂，搞这个表很久了，由于VBA只是略知一二，望高手帮忙实现此功能，非常感谢！

excel使用中

工作簿中的台账工作表设计不合理啊，才有现在的难题

背对镜

可以添加宏指令来实现啊   

lfmllm

Sub 按钮1_Click()
    Dim lastRow As Integer
    Dim monthCol As Integer
    lastRow = IIf(Sheet1.Range("B65535").End(xlUp).Row + 1 = 3, 4, Sheet1.Range("B65535").End(xlUp).Row + 1)
    Application.EnableEvents = False
    Sheet1.Range("A" & lastRow) = lastRow - 3
    Sheet2.Range("A3:F3").Copy
    Sheet1.Range("B" & lastRow).PasteSpecial xlPasteValues
    monthCol = findMonth(Sheet2.Range("G3").Text)
    If monthCol <> 0 Then
            Sheet1.Cells(lastRow, monthCol) = Sheet2.Range("H3")
            Sheet1.Cells(lastRow, monthCol + 1) = Sheet2.Range("I3")
        Else
            MsgBox "无对应时间，数据错误!"
    End If
Application.EnableEvents = True
End Sub

Private Function findMonth(mon As String) As Integer

    Dim i As Integer
    For i = 8 To 56 Step 2
        If Sheet1.Cells(2, i).Text = mon Then
            findMonth = i
            Exit Function
        End If
    Next
    findMonth = 0
End Function
Sub 按钮2_Click()
    Dim lastRow As Integer
    Dim i As Integer
    Dim contractRow As Integer
    Dim got As Boolean
    Dim monthCol As Integer
    lastRow = Sheet1.Range("B65535").End(xlUp).Row + 1
    got = False
    For i = 4 To lastRow
        If Sheet1.Range("B" & i) = Sheet2.Range("A7") Then
            got = True
            contractRow = i
            Exit For
        End If
    Next
    If Not got Then
        MsgBox "没有对应的合同号!"
        Exit Sub
    End If
    Application.EnableEvents = False
    monthCol = findMonth(Sheet2.Range("G7").Text)
      If monthCol <> 0 Then
            Sheet1.Cells(contractRow, monthCol) = Sheet2.Range("H7")
            Sheet1.Cells(contractRow, monthCol + 1) = Sheet2.Range("I7")
        Else
            MsgBox "无对应时间，数据错误!"
    End If
    Application.EnableEvents = True
End Sub

淡淡的邪

回到你另一个帖子里了http://club.excelhome.net/forum. ... p;extra=#pid9730240