WORD中利用VBA替换选中区空格

yjwdjfqb

WORD中利用VBA替换选中区半角空格

只是替换选中区域中半角空格

将选中区域的半角空格，替换成，红色的＃号。

当没有选中任何内容情况下，执行代码，弹出提示，“当前没有选择区域”；
当选择内容中，没有空格时，弹出提示，“当前选择内容中无空格”
如果选择内容中有，5个空格，替换完成后，弹出提示，“当前选中内容中有5个空格”

请老师们帮帮忙，谢谢大家了！
WORD利用VBA替换选中区空格.rar (4 KB, 下载次数: 49)

2015-9-25 20:28 上传

点击文件名下载附件

duquancai

用word自带的查找替换，用后台vba来实现，何必呢？

413191246se

Sub test()
'i=计数器，j=选定区域字长，k=循环变量
    Dim i As Long, j As Long, k As Long
    j = Len(Selection)
    If Selection.Type = wdSelectionIP Then
        MsgBox "未选定区域！", vbOKOnly + vbCritical, "替换选定区域空格为#号"
    Else
        If Selection Like "* *" Then
            '计算选定区域空格数目
            For k = 1 To j
                If Selection.Characters(k).Text = " " Then i = i + 1
            Next k
            '替换选定区域空格为红色#号
            With Selection.Find
                .ClearFormatting
                With .Replacement
                    .ClearFormatting '清除格式
                    .Font.Bold = True '加粗
                    .Font.Color = wdColorRed '红色
                End With
                .Execute FindText:=" ", replacewith:="#", Format:=True, Replace:=wdReplaceAll
            End With
            
            MsgBox "处理完毕！选定区域共有 " & i & " 个空格被替换为红色#号！", vbOKOnly + vbExclamation, "替换选定区域空格为#号"
        Else
            MsgBox "选定区域没有空格！", vbOKOnly + vbExclamation, "替换选定区域空格为#号"
        End If
    End If
End Sub

yjwdjfqb

413191246se 发表于 2015-9-26 14:42
Sub test()
'i=计数器，j=选定区域字长，k=循环变量
    Dim i As Long, j As Long, k As Long

谢谢老师的帮助，很好用！

yjwdjfqb

413191246se 发表于 2015-9-26 14:42
Sub test()
'i=计数器，j=选定区域字长，k=循环变量
    Dim i As Long, j As Long, k As Long

老师你好，麻烦你再帮我看看这个地址，14楼问题好吗，谢谢你了老师！
http://club.excelhome.net/thread-1230614-1-1.html

413191246se

Sub 突出显示中文数字()
'（从文尾）反向查找
    Selection.EndKey unit:=wdStory
    Do
        Selection.Find.ClearFormatting
        Selection.Find.Execute findtext:="、", Forward:=False
        Do
            Selection.MoveStart unit:=wdCharacter, Count:=-1
            If Selection.Characters.First Like "[!一二三四五六七八九十百零]" Then
                Selection.MoveStart unit:=wdCharacter, Count:=1
                If Len(Selection) >= 2 Then
                    Selection.Range.HighlightColorIndex = wdRed '红色/突出显示
                    Selection.Font.Name = "黑体" '黑体
                    Selection.Font.Bold = True '加粗
                    Selection.Font.Color = wdColorYellow '黄色
                    Selection.InsertBefore Text:=vbCr '选定内容前面插入回车符
                End If
                Exit Do
            End If
        Loop
        Selection.MoveLeft unit:=wdCharacter, Count:=1
    Loop Until Selection.Find.Found = False
    MsgBox "处理完毕！！！", vbOKOnly + vbExclamation, "突出显示中文数字"
End Sub

yjwdjfqb

413191246se 发表于 2015-9-26 21:34
Sub 突出显示中文数字()
'（从文尾）反向查找
    Selection.EndKey unit:=wdStory

谢谢老师的帮助！
祝你中秋节快乐！

413191246se

老师不敢当，仅会一点点 VBA 皮毛而已。——也祝你 及 你的全家 中秋节快乐！

tuhp01

413191246se 发表于 2015-9-26 14:42
Sub test()
'i=计数器，j=选定区域字长，k=循环变量
    Dim i As Long, j As Long, k As Long

请问我有 两个以上不同字符需要类似这样的操作怎么做呢