提取部分内容

357149088

我有很多个word文档，每个文档也有很多页，但我只想保留文档中偶数页面的学籍号及姓名，和注册码后面的小文本框（或者里面的数字更好）就是附件中的红色字体部分。谢谢

thunor

我给你说一个思路，没时间写代码了。
1.用代码实现到第一个偶数页
2.使用通配符的代码查到偶数页的全国学籍号：([G])([0-9]{13,14})【注：你所给的第二个学生的学籍号前后不统一】，在选中状态将其复制到文档最后（单独占一行）；或将其放入一个变量也可以。【不是all，是one】
3.再用使用通配符的代码查到学生的姓名：([姓][名][：])([ ]{1,2})([一-龥]{1,4})，在选中状态将其复制到文档最后；或将其放入一个变量也可以。【不是all，是one】
4.重复执行上述代码
5.从第一页开始查找shape,找到后看是否包含有16位数字，如果有，复制并将其放在文档结束处（单独占一行），如果没有执行下一个操作。
以下工作需要手动操作。
6.将其上的4过程得到的数据生成一个表格，【二列】。word中文字转表格很简单。
7.将6过程得到的数据生成一个表格，【一列】。
8.将7的表格拖到6的表格后面，合并成一张表格，全部工作完成。

357149088

感谢你的热心，但我实在是太菜，所以你提的思路没有办法，如果你能帮我写一下代码，那就太感谢你了。其实每个学生的学籍号是一统一的，而且所有人的学籍号都一样多位数。

413191246se

楼主，不要着急！其实我现在是搞不定文本框，要不早出手了。我对文字和表格还有会编一点点，大家都看到了你的问题。

413191246se

——楼主，你的问题我忙了很久，但因为这个“文本框”实在搞不定，总出错，作罢！看来帮不上你的忙了，等高手来解决了（文字和表格我还会编一点点，以后尽量少用文本框和图文框，能不用表格也不用表格，文字是最好办的）。

守柔

413191246se 发表于 2015-6-8 00:12
——楼主，你的问题我忙了很久，但因为这个“文本框”实在搞不定，总出错，作罢！看来帮不上你的忙了，等高 ...

感于413191246se兄的热情.
我随手写了一个,请413191246se兄和楼主测试一下.
特别说明:
请楼主千万不要问我如何运行宏代码,抱歉.

Private Sub OutputExaminees()
    Dim oShape As Word.Shape
    Dim myRange As Word.Range
    Dim astrExaminees() As String
    Dim astrSpliter() As String
    Dim strText As String
    Dim I As Integer
    Dim intPageNum As Integer
    I = 1    ''''初始化变量
    ReDim astrExaminees(1 To 3, 1 To I)    ''''动态定义一个数组,存储考生信息
    astrExaminees(1, I) = "全国学籍号"
    astrExaminees(2, I) = "姓名"
    astrExaminees(3, I) = "注册码"
    For Each oShape In ActiveDocument.Shapes    ''''遍历活动文档的图形
        With oShape
            If .Type = msoAutoShape Then    ''''为自选图形
                If .AutoShapeType = msoShapeRectangle Then    ''''为矩形
                    If .TextFrame.HasText Then    ''''具有文本内容时
                        strText = Replace$(.TextFrame.TextRange.Text, Chr$(13), Empty)   ''''删除段落标记
                        If strText Like String$(16, 35) Then    ''''为16位数字,即"################"
                            I = I + 1    ''''计数
                            ReDim Preserve astrExaminees(1 To 3, 1 To I)  ''''动态扩充数组
                            astrExaminees(3, I) = strText    ''''注册码
                            intPageNum = .Anchor.Information(wdActiveEndPageNumber)    ''''注册码所在矩形区域的页码
                            Set myRange = ActiveDocument.GoTo(What:=wdGoToPage, Which:=wdGoToAbsolute, Name:=CStr(intPageNum))    ''''定义到当前页
                            strText = Replace$(myRange.Paragraphs(1).Range.Text, Chr$(32), Empty, , , vbTextCompare)    ''''当前页面下第一个段落所在文本(全国学籍号/姓名)
                            astrSpliter = Split(strText, ChrW$(-230), , vbTextCompare)
                            If UBound(astrSpliter) = 2 Then
                                astrExaminees(1, I) = Replace$(astrSpliter(1), "姓名", Empty)    ''''Left$(astrSpliter(1), 14)   ''''全国学籍号,14位长度,发现示例文件中的蒋梦丹两页上的全国学籍号不一致!
                                astrExaminees(2, I) = Replace$(astrSpliter(2), Chr$(13), Empty)  ''''姓名,删除段落标记
                            End If
                        End If
                    End If
                End If
            End If
        End With
    Next
    If I > 1 Then
        ReDim astrSpliter(1 To I)    ''''动态定义一个一维数组,存储输出段落
        For I = 1 To UBound(astrExaminees, 2)
            astrSpliter(I) = astrExaminees(1, I) & vbTab & astrExaminees(2, I) & vbTab & astrExaminees(3, I)    ''''各字段之间使用TAB键分隔
        Next
        Application.Documents.Add.Content.InsertAfter Join(astrSpliter, Chr$(13))    ''''在新文档中输出提取结果
    End If
End Sub

413191246se

守版 代码，准确、干净！ 就是看不太懂。——承蒙 守版 抬举，不胜感激，我会录制宏很多年，但真正入门是 2011年6月的事，最近几年虽有进步，但与 守版 等高手无法相比，谢谢 守版！
楼主 朋友，代码测试通过，但在运行前，把 Private 字样删除吧，否则，在宏名里找不到，在 VBE 中可以找到，最终结果，全选——插入表格 即可（第2名 梦丹 的前后学籍号不一致！）。

闻启学

413191246se 发表于 2015-6-8 10:00
守版 代码，准确、干净！ 就是看不太懂。——承蒙 守版 抬举，不胜感激，我会录制宏很多年，但真正入门是 2 ...

413191246se兄

大家交流一下VBA的 吧  这个我都做过一个

守柔前辈 好久不见你露面；

szqhb

守柔 发表于 2015-6-8 06:50
感于413191246se兄的热情.
我随手写了一个,请413191246se兄和楼主测试一下.
特别说明:

前辈，我还要提取“基础信息表拍照上传号”，怎样补充修改代码？最好能把生成的数据显示在Word，或另存在Excel表格里

ammyc

好好学习，天天向上