循环遍历文件夹并返回文件名到combobox1的下拉菜单中

Amos027

循环遍历文件夹并返回文件路径名到combobox下拉菜单中：
比如在combobox1控件中输入关键词"11",则combobox1的下拉菜单中显示“\1\111.xlsx”，“\2\211.xlsx”



求助.rar (43.62 KB, 下载次数: 13)

2015-5-30 10:31 上传

点击文件名下载附件

zhaogang1960

模块中

1. Public arr$(), m&
   
2. 
   
3. Sub Start()
   
4.     Dim Fso As Object, Folder As Object
   
5.     Set Fso = CreateObject("Scripting.FileSystemObject")
   
6.     Set Folder = Fso.GetFolder(ThisWorkbook.Path)
   
7.     Call GetFiles(Folder)
   
8.     Sheet1.ComboBox1.Clear
   
9.     m = 0
   
10.     Set Folder = Nothing
    
11.     Set Fso = Nothing
    
12. End Sub
    
13. 
    
14. Sub GetFiles(ByVal Folder As Object)
    
15.     Dim SubFolder As Object
    
16.     Dim File As Object
    
17.     For Each File In Folder.Files
    
18.         If File.Name Like "*.xlsx" Then
    
19.             If InStr(File.Name, ThisWorkbook.Name) = 0 Then
    
20.                 m = m + 1
    
21.                 ReDim Preserve arr(1 To m)
    
22.                 arr(m) = Replace(File, ThisWorkbook.Path, "")
    
23.             End If
    
24.         End If
    
25.     Next
    
26.     For Each SubFolder In Folder.SubFolders
    
27.         Call GetFiles(SubFolder)
    
28.     Next
    
29. End Sub
    

复制代码

Sheet1代码编辑区

1. Private Sub ComboBox1_Change()
   
2.     If ComboBox1.ListIndex = -1 Then
   
3.         Dim brr$(), i&, m&
   
4.         On Error Resume Next
   
5.         If UBound(arr) < 0 Then Call Start
   
6.         ReDim brr(1 To UBound(arr))
   
7.         For i = 1 To UBound(arr)
   
8.             If InStr(arr(i), ComboBox1.Value) Then
   
9.                 m = m + 1
   
10.                 brr(m) = arr(i)
    
11.             End If
    
12.         Next
    
13.         If m > 0 Then
    
14.             ReDim Preserve brr(1 To m)
    
15.             ComboBox1.List = brr
    
16.         Else
    
17.             ComboBox1.Clear
    
18.         End If
    
19.     End If
    
20. End Sub
    

复制代码

zhaogang1960

请测试附件
求助.rar (54.76 KB, 下载次数: 95)

2015-5-30 11:51 上传

点击文件名下载附件

Amos027

zhaogang1960 发表于 2015-5-30 11:51
请测试附件

赵老师，能否加一个判断，比如对我在COMBOBOX中输入“123”的关键词时因子文件夹中并不包含为123的文件，则下拉菜单为空，这样该如何改？

zhaogang1960

Amos027 发表于 2015-5-30 13:13
赵老师，能否加一个判断，比如对我在COMBOBOX中输入“123”的关键词时因子文件夹中并不包含为123的文件， ...

第17句就是
ComboBox1.Clear

HUA79100101

zhaogang1960 发表于 2015-5-30 11:51
请测试附件

谢谢老师。刚好用上。