如何把word文档内每一行开头的第一个文字一次批量的改变颜色或字体？

413191246se · 发表于 2016-11-6 11:57

本帖最后由 413191246se 于 2016-11-6 13:04 编辑

.......................

413191246se · 发表于 2016-11-6 14:14

139：字体（Name）/字号（Size）/字形（Bold加粗/Italic斜体）/颜色（wdColorRed红色）这些参数可以通过录制宏得到，请试试下面的代码：

Sub aaaa段落首字符格式设置()
Dim i As Paragraph, x As Long, y As Long
For Each i In ActiveDocument.Paragraphs
i.Range.Select
Do
y = Selection.Paragraphs(1).Range.ComputeStatistics(statistic:=wdStatisticLines)
Selection.HomeKey Unit:=wdLine
Selection.MoveRight Unit:=wdCharacter, Count:=1, Extend:=wdExtend
With Selection.Font
.Name = "黑体" '（中文字体）
.Name = "Times New Roman" '（西文字体）
.Size = 16 '三号（字号）
.Bold = True '加粗（字形）
.Italic = True '斜体（字形）
.Color = wdColorRed '红色（颜色）
End With
Selection.MoveDown Unit:=wdLine, Count:=1
x = x + 1
Loop Until x = y
x = 0
Next
End Sub

复制代码

13907933959 · 发表于 2016-11-7 08:58

本帖最后由 13907933959 于 2016-11-7 10:24 编辑

413191246se 发表于 2016-11-6 14:14
139：字体（Name）/字号（Size）/字形（Bold加粗/Italic斜体）/颜色（wdColorRed红色）这些参数可以通过录 ...

师傅好！

好的。
代码刚测试了，精准无误。感谢师傅！！！

duquancai · 发表于 2016-11-9 15:32

13907933959 发表于 2016-11-7 08:58
师傅好！好的。
代码刚测试了，精准无误。感谢师傅！！！

Word 2003及其以后版本中，有“页”和“行”对象的：

Sub 行首一个字符设置格式()
Dim oPage As Page, oLine As Line
For Each oPage In ActiveDocument.ActiveWindow.ActivePane.Pages
For Each oLine In oPage.Rectangles(1).Lines
With ActiveDocument.Range(oLine.Range.Start, oLine.Range.Start + 1).Font
.Bold = True
.Italic = True
.Color = RGB(255, 0, 0)
End With
Next
Next
End Sub

复制代码

备注：引用守柔老大的原话：“Word 2003及其以后版本中，是有“页”和“行”对象的，即“Page"和“Line“，它们也可以与Range对象关联起来，但尽量不要使用这些对象，如果程序要通过页和行来解决问题时，应该检讨一下程序的设计思路是否存在问题，在使用“页”特别是“行”对象时，请慎用。”

duquancai · 发表于 2016-11-9 17:00

13907933959 发表于 2016-11-7 08:58
师傅好！好的。
代码刚测试了，精准无误。感谢师傅！！！

由于字号增大，可能会引起原文档中行数会增加，反之可能引起行数会减少，总之行数变化了，那么你设置的“原文档”的行首一个字符就会变化的。那么怎么保证设置的原来行首一个字符始终就是设置的同一个字字符呢？那么用下面的程序可以解决：

Sub 行首一个字符设置格式()
Dim c As New Collection
Dim oPage As Page, oLine As Line, rng As Range
For Each oPage In ActiveDocument.ActiveWindow.ActivePane.Pages
For Each oLine In oPage.Rectangles(1).Lines
n = n + 1
Set rng = ActiveDocument.Range(oLine.Range.Start, oLine.Range.Start + 1)
c.Add rng, CStr(n)
Next
Next
For i = 1 To c.Count
With c(i).Font
.Name = "黑体"
.Name = "Times New Roman"
.Size = 60 '设置的字号比较大，是为了改变原来文档的行数，以便观察！
.Bold = True
.Italic = True
.Color = wdColorRed
End With
Next
End Sub

复制代码

13907933959 · 发表于 2016-11-9 17:05

duquancai 发表于 2016-11-9 15:32
Word 2003及其以后版本中，有“页”和“行”对象的：
备注：引用守柔老大的原话：“Word 2003及其以后版 ...

前辈好！
感谢前辈多次出手相助！
经测试、可精准替换。
感谢前辈教诲！
谢谢！

duquancai · 发表于 2016-11-9 17:19

本帖最后由 duquancai 于 2016-11-9 17:23 编辑

13907933959 发表于 2016-11-7 08:58
师傅好！好的。
代码刚测试了，精准无误。感谢师傅！！！

当然也可以用字典法，程序如下：

Sub 行首一个字符设置格式()
Set d = CreateObject("Scripting.Dictionary")
Dim oPage As Page, oLine As Line, rng As Range
For Each oPage In ActiveDocument.ActiveWindow.ActivePane.Pages
For Each oLine In oPage.Rectangles(1).Lines
n = n + 1
Set d(n) = ActiveDocument.Range(oLine.Range.Start, oLine.Range.Start + 1)
Next
Next
For Each ite In d.items
With ite.Font
.Name = "黑体"
.Name = "Times New Roman"
.Size = 60 '设置的字号比较大，是为了改变原来文档的行数，以便观察！
.Bold = True
.Italic = True
.Color = wdColorRed
End With
Next
End Sub

复制代码

13907933959 · 发表于 2016-11-10 07:48

本帖最后由 13907933959 于 2016-11-10 07:55 编辑

duquancai 发表于 2016-11-9 17:00
由于字号增大，可能会引起原文档中行数会增加，反之可能引起行数会减少，总之行数变化了，那么你设置的“ ...

前辈好！

谢谢！谢谢！

前辈、您是论坛上大家公认的高手，给的东西总是简洁高效，令人望尘莫及！！！
前辈、能否再求您在上面的代码中，加一个可指定自左往右任意一字符位数的选项框，通过手工修改选项框的数字，如可指定替换文档内每一行的第1个字符、第2个字符、第3个字符、……直到满行的最后一个字的格式（字体、字号、字形、颜色）。

拜谢前辈！

duquancai · 发表于 2016-11-10 09:31

13907933959 发表于 2016-11-10 07:48
前辈好！谢谢！谢谢！前辈、您是论坛上大家公认的高手，给的东西总是简洁高效，令人望尘莫及！！！
前辈、 ...

Sub 字符设置格式()
Dim oPage As Page, oLine As Line, rng As Range, r%
Set d = CreateObject("Scripting.Dictionary")
On Error Resume Next
r = InputBox("请输入字符数")
For Each oPage In ActiveDocument.ActiveWindow.ActivePane.Pages
For Each oLine In oPage.Rectangles(1).Lines
n = n + 1
y = oLine.Range.Start
Set d(n) = ActiveDocument.Range(oLine.Range.Start, oLine.Range.Start + r)
Next
Next
For Each ite In d.items
With ite.Font
.Name = "黑体"
.Name = "Times New Roman"
.Bold = True
.Color = wdColorRed
End With
Next
End Sub

复制代码

13907933959 · 发表于 2016-11-10 10:26

本帖最后由 13907933959 于 2016-11-10 10:28 编辑

duquancai 发表于 2016-11-10 09:31

前辈好！
抱歉！抱歉！怪我描述不准、让您产生误判，请前辈原谅！

加一个可指定自左往右任意一字符位数的选项框，通过手工修改选项框的数字，如可指定替换文档内每一行的第1个字符、第2个字符、第3个字符、……直到满行的最后一个字的格式（字体、字号、字形、颜色）。

我的意思是：每行只改变一个字符的格式（字体、字号、字形、颜色）。假如在选项框内手工选定了8，即只替换文档内每一行的第8个字符的格式（字体、字号、字形、颜色）。

求前辈再帮忙！谢谢！

		自动登录	找回密码
密码			免费注册

[求助] 如何把word文档内每一行开头的第一个文字一次批量的改变颜色或字体？