如何将word文件进行批量打印（用VB或其它方法都行）

Madafly

如下图所示，我要将里面文件一一打印出来，我只会常规方法，将每个文件打开来，然后逐一按word中打印按钮，重复操作，要是几百个文件，那就非常头痛。请问如何进行批量打印，谢谢！已上传附件。

[attach]1744859[/attach

Madafly

上传附件不成功，重新上传

413191246se

Sub 循环遍历文件夹_doc_txt()
    Dim t As Long, a As String, b As Long, c As Long, s As Section, j As Long
    If MsgBox("是否处理 Word 文档(*.doc)？  （否则处理文本文档(*.txt)）", vbYesNo + vbExclamation, "循环遍历文件夹") = vbYes Then t = 1 Else t = 0
    a = MsgBox("请选择——是：批量打印    否：批量合并    取消：批量转换", vbYesNoCancel + vbExclamation, "循环遍历文件夹")
    If a = vbYes Then
        b = 1
    ElseIf a = vbNo Then
        b = 2
        If MsgBox("文档之间是否插入分页符？", vbYesNo + vbExclamation, "循环遍历文件夹") = vbYes Then c = 1 Else c = 0
        Documents.Add
    Else
        b = 3
    End If

    On Error Resume Next
    Dim fd As FileDialog, i As Long, doc As Document, p As String
    Set fd = Application.FileDialog(msoFileDialogFolderPicker)
    If fd.Show = -1 Then p = fd.SelectedItems(1) Else Exit Sub
    Set fd = Nothing
    If MsgBox("Are you sure to process the folder " & p & " ?" & vbCr & "是否处理文件夹 " & p & " ？", vbYesNo + vbExclamation, "循环遍历文件夹") = vbNo Then Exit Sub
    With Application.FileSearch
'        .NewSearch
        .LookIn = p
        .SearchSubFolders = True
        If t = 1 Then .FileName = "*.doc" Else .FileName = "*.txt"
'        .FileType = msoFileTypeAllFiles
        If .Execute > 0 Then
'            MsgBox "There were " & .FoundFiles.Count & " file(s) found."
'            For i = 1 To .FoundFiles.Count '逆序
            For i = .FoundFiles.Count To 1 Step -1 '顺序
'                MsgBox .FoundFiles(i)
                If t = 1 Then Set doc = Documents.Open(FileName:=.FoundFiles(i)) Else Set doc = Documents.Open(FileName:=.FoundFiles(i), Encoding:=936)
                If b = 1 Then
                    If t = 1 Then
                        For Each s In doc.Sections
                            With s.PageSetup
                                If .Orientation = wdOrientLandscape Then j = 1 Else j = 0
                                If .PaperSize <> wdPaperA4 Then .PaperSize = wdPaperA4: If j = 1 Then .Orientation = wdOrientLandscape
                            End With
                        Next
                        doc.PrintOut
                        doc.Close savechanges:=wdDoNotSaveChanges
                    ElseIf t = 0 Then
                        doc.PrintOut
                        doc.Close savechanges:=wdDoNotSaveChanges
                    End If
                ElseIf b = 2 Then
                    doc.Content.Copy
                    doc.Close
                    ActiveDocument.Content.Paste
                    If c = 1 Then ActiveDocument.Content.InsertBreak Type:=wdPageBreak
                Else
                    If t = 1 Then doc.SaveAs FileName:=Left(doc.FullName, Len(doc.FullName) - 4) & ".txt", FileFormat:=wdFormatText Else doc.SaveAs FileName:=Left(doc.FullName, Len(doc.FullName) - 4) & ".doc", FileFormat:=wdFormatDocument
                    doc.Close
                End If
            Next i
            If b = 2 Then
                Selection.HomeKey Unit:=wdStory
                If c = 1 Then Selection.Delete Unit:=wdCharacter, Count:=1
                MsgBox "合并完毕！共合并 " & .FoundFiles.Count & " 个文件！请自行保存！", vbOKOnly + vbExclamation, "循环遍历文件夹"
                Exit Sub
            End If
            MsgBox "Complete! There were " & .FoundFiles.Count & " file(s) processed." & vbCr & "处理完毕！共处理 " & .FoundFiles.Count & " 个文件！", vbOKOnly + vbExclamation, "循环遍历文件夹"
        Else
            MsgBox "There were no files found." & vbCr & "未发现文件！", vbOKOnly + vbCritical, "循环遍历文件夹"
        End If
    End With
End Sub

413191246se

请楼主备份要打印的文件夹后，应用以上的宏。。。（找到要打印的文件夹，确认是否是这个文件夹）

Madafly

非常感谢！ 大侠神一样的人。

Madafly

413191246se 发表于 2015-3-31 23:44
Sub 循环遍历文件夹_doc_txt()
    Dim t As Long, a As String, b As Long, c As Long, s As Section, j  ...

大侠，我把你的代码保存在文件中的第一个Word文档，然后运行，选择“批量打印”，然后选择“曲线测试”这个文件夹，但是打印机只打印第一个Word文档，其余的都不打印。试了几遍都这样。

413191246se

楼主，我建议你把我的宏保存在通用空白模板 Normal.dot 中后，再应用之，不要保存到文档中！（至于怎么确定是模板 Normal.dot，其实只须打开 Word 后，录制一个新宏，然后，工具菜单——宏——宏——刚刚你录制的宏——编辑，再把我的代码拷贝到你这个宏后面，应用之就可以了！）