查找每一段 在标识符前插入递增序号

pipiludaxian

运行前

那只敏捷的棕毛狐狸跃过那只懒狗。

那只敏捷的棕毛【毛狐狸】狐狸跃【懒狗】

过那只懒狗。那只棕毛【毛狐狸】那只懒狗【懒狗】敏捷狸【懒狗】跃过。

希望运行后

那只敏捷的棕毛狐狸跃过那只懒狗。

那只敏捷的棕毛1【毛狐狸】狐狸跃2【懒狗】

过那只懒狗。那只棕毛1【毛狐狸】那只懒狗2【懒狗】敏捷狸3【懒狗】跃过。

代码如下   运行不理解  问题出在哪

Sub test001()

Dim n As Integer

Dim myrange As Range

Dim i As Integer

Dim k As Integer

Application.ScreenUpdating = False

n = ActiveDocument.Paragraphs.Count

For i = n To 1 Step -1

k = 1

Set myrange = ActiveDocument.Paragraphs(i).Range

With myrange.Find

            .Text = "【"

            .Forward = True

            .Wrap = wdFindStop

            Do While .Execute = True

            myrange.Collapse

            myrange.InsertAfter k

            myrange.MoveUntil "】"

            k = k + 1

            Loop

    End With

Next

    Application.ScreenUpdating = True

End Sub

守柔

楼主混淆了Selection对象与Range对象在Find时的不同.
参考:
Sub test001()
    Dim oPara As Word.Paragraph
    Dim myRange As Word.Range
    Dim K As Integer
    Application.ScreenUpdating = False    ''''关闭屏幕更新
    For Each oPara In ActiveDocument.Paragraphs    ''''遍历段落
        Set myRange = oPara.Range
        K = 1    ''''初始化变量
        With myRange.Find
            .Text = "【"
            .Forward = True
            .Wrap = wdFindStop
            Do While .Execute = True
                Set myRange = .Parent    ''''重置Range对象,为查找到的目标区域
                myRange.InsertBefore K    ''''在目标字符之前插入序号
                K = K + 1    ''''计数
                myRange.SetRange myRange.End, oPara.Range.End    ''''重置Range对象,为剩余段落区域
            Loop
        End With
    Next
    Application.ScreenUpdating = True    ''''恢复屏幕更新
End Sub

实际上,如果可以考虑使用SEQ域的话,则可以为每一个段落的指定字符替换为SEQ域和查找字符.即将SEQ域复制到剪贴板上,这样可以批量替换,而不需要为每一个位置计数.

pipiludaxian

老大出手  小弟拜服