word插入表格、图片适应2个问题

sukigrape · 发表于 2015-1-22 16:41

问题1:WORD插入表格，分2列列宽为8.5…..1行高为5cm. 1行0.8CM。。交叉进行，如何用VBA实现.然后每新插入,自动生成2行，都是按照这个模式增加。。

问题2:

选中表格,插入图片,图片自动适应设定的表格大小。如何用VBA实现。

csnAlex · 发表于 2015-1-23 17:01

如果你把行高改为“固定值”，图片插入后也应该是自适应的。

把你里面的代码改了，看里面的说明吧。

word插入表格、图片适应2个问题（回复）.zip (692.52 KB, 下载次数: 62)

sukigrape · 发表于 2015-1-24 12:11

csnAlex 发表于 2015-1-23 17:01
如果你把行高改为“固定值”，图片插入后也应该是自适应的。

把你里面的代码改了，看里面的说明吧。

你好，谢谢了。有些疑问。就是原来WORD是空白的，运行宏不会自动插入表格的吗？我的是07WORD版。然后图片插入表格，只适应了高，宽没有相应的填满单元格，或我想实现图片在适应单元格的时候，上下左右都留一点空白，请问这个能实现吗》？谢谢高手了。

sukigrape · 发表于 2015-1-24 12:13

csnAlex 发表于 2015-1-23 17:01
如果你把行高改为“固定值”，图片插入后也应该是自适应的。

把你里面的代码改了，看里面的说明吧。

哦，空白点时插入是要单独运行插入空表格的，谢谢。这个问题已经解决，烦请高手解决其他一点疑问

csnAlex · 发表于 2015-1-26 14:28

Sub 插入空表格()
'
' 插入空表格 Macro
' 宏在 2015/1/23 Friday 由刘小军录制
'
Dim mytb As Table, sH As Single, i As Integer, mr As Range
'判断光标位置
If Selection.Information(wdStartOfRangeRowNumber) = -1 Then
'不在表格内
Set mytb = ActiveDocument.Tables.Add(Selection.Range, 2, 2)
With mytb
.Columns.PreferredWidth = CentimetersToPoints(8.5)
.Style = "网格型"
.Rows.Alignment = wdAlignRowCenter '表格居中
.Rows.HeightRule = wdRowHeightExactly '行高固定
.Rows(1).Height = CentimetersToPoints(5) '第一行高5厘米
.Rows(2).Height = CentimetersToPoints(0.8) '第二行高0.8厘米
.Range.ParagraphFormat.DisableLineHeightGrid = True '取消网格对齐（不取消有时候图片上边有空白，下边一截看不到）
.Range.ParagraphFormat.Alignment = wdAlignParagraphCenter '单元格内容水平居中
.Range.Cells.VerticalAlignment = wdCellAlignVerticalCenter '单元格内容垂直居中
'需要图片离开边框有一定空白增加下面几句------
.TopPadding = 2 '如果觉得空白不够，把2改为3、4试试
.LeftPadding = 2
.RightPadding = 2
.BottomPadding = 2
'此时所有行都会稍微增加点高度，如果要重新改为确定的5厘米、0.8厘米，可以把上面的两行改为
'.Rows(1).Height = CentimetersToPoints(5)-2 '第一行高5厘米
'.Rows(2).Height = CentimetersToPoints(0.8)-2 '第二行高0.8厘米
'下面在表格内的部分也要做相应修改
'--------------------------------------------
End With
Set mytb = Nothing
Else
'在表格内
Set mr = Selection.Range
Selection.InsertRowsBelow 2
Set mytb = Selection.Tables(1)
With mytb
i = Selection.Information(wdStartOfRangeRowNumber)
sH = .Rows(i).Height
If sH > 140 Then
.Rows(i).HeightRule = wdRowHeightExactly
.Rows(i).Height = CentimetersToPoints(0.8)
.Rows(i + 1).HeightRule = wdRowHeightExactly
.Rows(i + 1).Height = CentimetersToPoints(5)
Else
.Rows(i).HeightRule = wdRowHeightExactly
.Rows(i).Height = CentimetersToPoints(5)
.Rows(i + 1).HeightRule = wdRowHeightExactly
.Rows(i + 1).Height = CentimetersToPoints(0.8)
End If
End With
Set mytb = Nothing
mr.Select
End If
End Sub

复制代码

sukigrape · 发表于 2015-1-26 17:13

csnAlex 发表于 2015-1-26 14:28

复制了这个代码后。运行插入表格。然后继续运行之前的插入图片代码，但图片还是没有实现左右两边离表格空一点点距离。比如说拿一寸的相片。左右会有比较大的空白部分。不知道原因。右边的效果才对，不要左边的效果。

csnAlex · 发表于 2015-1-28 10:04

选择图片后，增加了一个插入方式选择，你自己测试一下填充方式的效果。

word插入表格、图片适应2个问题（回复）.zip (149.7 KB, 下载次数: 98)

sukigrape · 发表于 2015-1-28 11:37

csnAlex 发表于 2015-1-28 10:04
选择图片后，增加了一个插入方式选择，你自己测试一下填充方式的效果。

除了感谢还是感谢，实在是太厉害了。！谢谢

sukigrape · 发表于 2015-1-29 16:41

csnAlex 发表于 2015-1-28 10:04
选择图片后，增加了一个插入方式选择，你自己测试一下填充方式的效果。

大神，问题又来了，静等指教：当文档行距设定为固定值时，插入图片适应表格的话图片会显示不全；行距为单倍，1.5.多倍的时候，图片显示就没有问题，请问这个有办法解决吗？请看2个附图的不同效果。

csnAlex · 发表于 2015-2-3 11:32

sukigrape 发表于 2015-1-29 16:41
大神，问题又来了，静等指教：当文档行距设定为固定值时，插入图片适应表格的话图片会显示不全；行距为单 ...

.Range.ParagraphFormat.DisableLineHeightGrid = True '取消网格对齐（不取消有时候图片上边有空白，下边一截看不到）
在 Sub 插入空表格() 中上一句的下面加入下面一句
.Range.ParagraphFormat.LineSpacingRule = wdLineSpaceSingle '设为单倍行高

		自动登录	找回密码
密码			免费注册

[求助] word插入表格、图片适应2个问题

评分

评分