excel数据怎样导入access

暮烟批

附件上传，您看一下能实现吗，谢谢。

zhaogang1960

暮烟批 发表于 2015-1-21 18:53
附件上传，您看一下能实现吗，谢谢。

1. Sub 根据序号更新记录()
   
2.     Dim cnn As New ADODB.Connection
   
3.     Dim strTemp As String
   
4.     Dim SQL As String
   
5.     Dim arr As Variant
   
6.     Dim i As Integer
   
7.     cnn.Open "Provider=Microsoft.Ace.OLEDB.12.0;Data Source=" & ThisWorkbook.Path & "\肯纳金属模具查询系统-.accdb"
   
8.     arr = Intersect(Range("A1").CurrentRegion, Rows(1))
   
9.     For i = 2 To UBound(arr, 2)
   
10.         strTemp = strTemp & ",A.[" & arr(1, i) & "]=B.[" & arr(1, i) & "]"
    
11.     Next
    
12.     SQL = "UPDATE 模具库 A,[Excel 12.0;Imex=0;Database=" & ThisWorkbook.FullName & ";].[" & ActiveSheet.Name & "$" _
    
13.         & Range("A1").CurrentRegion.Address(0, 0) & "] B SET " & Mid(strTemp, 2) & " WHERE A.序号=B.序号"
    
14.     cnn.Execute SQL
    
15.     MsgBox "数据修改成功。", vbInformation, "数据修改"
    
16.     cnn.Close
    
17.     Set cnn = Nothing
    
18. End Sub
    

复制代码

zhaogang1960

请测试附件
新建文件夹 (2).rar (139.3 KB, 下载次数: 29)

2015-1-21 19:11 上传

点击文件名下载附件

暮烟批

zhaogang1960 发表于 2015-1-21 19:12
请测试附件

就是这种效果，麻烦您了，希望以后能得到您的更多帮助，谢谢。

29151429

关注学习                              

暮烟批

zhaogang1960 发表于 2015-1-21 19:12
请测试附件

老师，又来麻烦您了excel附件里的信息更改添加都没有问题，可是一添加完新纪录后Access数据重复，能否取消重复，请您指导。
详情请看附件，谢谢。

zhaogang1960

暮烟批 发表于 2015-1-22 15:09
老师，又来麻烦您了excel附件里的信息更改添加都没有问题，可是一添加完新纪录后Access数据重复，能否取消 ...

1. Sub 从工作表中向数据表添加纪录()
   
2. '引用Microsoft ActiveX Data Objects 2.x Library
   
3.     Dim cnn As New ADODB.Connection
   
4.     Dim rs As New ADODB.Recordset
   
5.     Dim SQL As String
   
6.     Dim myTable As String
   
7.     If ActiveSheet.Name = "模具" Then
   
8.         myTable = "模具出库"
   
9.     Else
   
10.         myTable = "模具库"
    
11.     End If
    
12.     cnn.Open "Provider=Microsoft.Ace.OLEDB.12.0;Data Source=" & ThisWorkbook.Path & "\肯纳金属模具查询系统-.accdb"
    
13.     SQL = " SELECT A.* FROM [Excel 12.0;Database=" & ThisWorkbook.FullName & ";].[" & ActiveSheet.Name & "$" & Range("A1").CurrentRegion.Resize(Range("d" & Rows.Count).End(xlUp).Row).Address(0, 0) _
    
14.         & "] A LEFT JOIN " & myTable & " B ON A.序号=B.序号 WHERE B.序号 IS NULL"
    
15.     rs.Open SQL, cnn, adOpenKeyset, adLockOptimistic
    
16.     If rs.RecordCount > 0 Then
    
17.         SQL = "INSERT INTO " & myTable & SQL
    
18.         cnn.Execute SQL
    
19.         MsgBox rs.RecordCount & "条记录已添加到数据库" & myTable & "数据表！", vbInformation, "添加纪录"
    
20.     Else
    
21.         MsgBox "没有发现可插入的纪录。", vbInformation, "添加纪录"
    
22.     End If
    
23.     rs.Close
    
24.     cnn.Close
    
25.     Set rs = Nothing
    
26.     Set cnn = Nothing
    
27. End Sub

复制代码

zhaogang1960

请测试附件
新建文件夹 (2) - 副本.rar (220.57 KB, 下载次数: 36)

2015-1-22 19:21 上传

点击文件名下载附件

暮烟批

zhaogang1960 发表于 2015-1-22 19:21
请测试附件

回复您晚了表格搞定了，谢谢老师。

周立

zhaogang1960 发表于 2015-1-21 19:11

如果数据在其他工作薄中，怎样在不打开其他工作薄的情况下，将其他工作薄的数据导入access。