都来看看这个排序怎么实现，再来看看单位前面的量怎么提取

满坛皆为吾师 · 发表于 2015-1-4 15:16

rzqf 发表于 2015-1-4 15:09
你这个公式实现不了，有很多错误，而且要插入一行的话，就错了

啊哈哈哈,不够细致哈,感谢指正,再做修正....

满坛皆为吾师 · 发表于 2015-1-4 15:32

rzqf 发表于 2015-1-4 15:09
你这个公式实现不了，有很多错误，而且要插入一行的话，就错了

这下全对了，可以跟据最大-的数量来相应扩展公式中的常量数组和取数量
插入行的话要把范围改为=INDIRECT("A1:A"&COUNTA(A:A))的写法，纯属娱乐：D

排序.rar (30.87 KB, 下载次数: 22)

香川群子 · 发表于 2015-1-4 18:33

本帖最后由香川群子于 2015-1-4 18:52 编辑

aoe1981 发表于 2015-1-3 16:06
其实，我在一开始也想弄一个固定层数、固定最大编码的，因为完全可以预设为足够大，因为实际中往往用不了 ...

老老实实的代码：

Sub test()
Dim ar, i&, j&, m&, n&, s, t0$, t$, tms#
tms = Timer
m = [a1].End(4).Row 'A列最大行数m
ar = [a1].Resize(m) 'A列待排序数据读入数组ar
t0 = "s" & String(4 * 10, "0") '建立排序字符串模板= 4位数*10级
For i = 1 To m '遍历各行
s = Split(ar(i, 1), "-") '按[-]拆分
t = t0 '读取模板
For j = 0 To UBound(s) '遍历按[-]拆分后的各级
n = Len(s(j)) '该级位数n
Mid(t, j * 4 + 6 - n, n) = s(j) '模板更新为对应的排序结果字符串
Next
ar(i, 1) = t '写入排序结果字符串
Next
[b1].Resize(m) = ar '在B列写入排序结果字符串
[a1].Resize(m, 2).Sort [b1], 1, , , , , , 2 '使用工作表排序方法按B列结果排序
[b1].Resize(m) = "" '清空B列
MsgBox Format(Timer - tms, " 0.000s")
End Sub

复制代码

aoe1981 · 发表于 2015-1-4 18:45

香川群子发表于 2015-1-4 18:33
老老实实的代码：

一开始试了一下，快得不得了，一眨眼，咦，好了……给我惊讶的……

粗粗研究了下：
1.读取格式模板算是神来之笔，既巧妙又快速：
t0 = "s" & String(4 * 10, "0")
t = t0
Mid(t, j * 4 + 6 - n, n) = s(j)

2.利用了b列和工作表排序方法：
[a1].Resize(m, 2).Sort [b1], 1, , , , , , 2

香川群子 · 发表于 2015-1-4 18:57

aoe1981 发表于 2015-1-4 18:45
一开始试了一下，快得不得了，一眨眼，咦，好了……给我惊讶的……

粗粗研究了下：

速度还可以更快一些……不要使用Split，完全用自己的代码……用Instr……Do循环：

Sub test2()
Dim ar, i&, j&, l&, m&, n&, s$, t0$, t$, tms#
tms = Timer
m = [a1].End(4).Row
ar = [a1].Resize(m)
t0 = "s" & String(4 * 10, "0")
For i = 1 To m
t = t0
s = ar(i, 1)
j = 0: l = 1
Do
n = InStr(l, s, "-")
If n Then
Mid(t, j * 4 + 6 - n + l, n - l) = Mid(s, l, n - l)
j = j + 1: l = n + 1
End If
Loop Until n = 0
Mid(t, j * 4 + 5 - Len(s) + l, Len(s) + 1 - l) = Mid(s, l, Len(s) + 1 - l)
ar(i, 1) = t
Next
[b1].Resize(m) = ar
[a1].Resize(m, 2).Sort [b1], 1, , , , , , 2
[b1].Resize(m) = ""
MsgBox Format(Timer - tms, " 0.000s")
End Sub

复制代码

yuwd3 · 发表于 2015-1-4 19:07

这个帖子引出好多高手啊，慢慢学习。

张雄友 · 发表于 2015-1-4 19:11

香川群子发表于 2015-1-4 18:57
速度还可以更快一些……不要使用Split，完全用自己的代码……用Instr……Do循环：

http://club.excelhome.net/thread-1176723-1-2.html

大神出现了，等了很久了。

yuwd3 · 发表于 2015-1-4 19:20

没正规学习编程，请大神：下面这句语法是什么意思？
Mid(t, j * 4 + 6 - n, n) = s(j)

yuwd3 · 发表于 2015-1-4 19:22

原来是更改t的值

aoe1981 · 发表于 2015-1-4 20:10

香川群子发表于 2015-1-4 18:57
速度还可以更快一些……不要使用Split，完全用自己的代码……用Instr……Do循环：

能不能用您自己的语言介绍下instr与find函数的区别……

对instr一直认识不深入，很少使用……

感觉这二者有些共同点吧，似乎都能返回某字符在另一字符串中出现的位置……

希望有更深一些的认识……

		自动登录	找回密码
密码			免费注册

都来看看这个排序怎么实现，再来看看单位前面的量怎么提取

评分

点评