如何计算一定区域内背景色为红色的单元格个数

叶子の秋

find函数只能查找数字吧?那么我想计算一个范围内所有背景色为红色的单元格的个数该怎么办?,只能用VBA吧?

0031126

1. Function SumInteriorColor(Rng As Range, X As Variant) '根据单元格底色求和
   
2.     Dim CorIndex As Integer, TempSum As Variant
   
3.     Dim Temp As Range, Rng1 As Range, Rng2 As Range
   
4.     Application.Volatile True
   
5. 
   
6.     If TypeName(X) = "Range" Then
   
7.         CorIndex = X.Interior.ColorIndex
   
8.     Else
   
9.         SumInteriorColor = "未知参数类型"
   
10.         Exit Function
    
11.     End If
    
12.    
    
13.     On Error Resume Next
    
14.     Set Rng = Intersect(Rng.Parent.UsedRange, Rng)
    
15.     On Error GoTo 0
    
16.    
    
17.     If Not Rng Is Nothing Then
    
18.         For Each Temp In Rng
    
19.             If Temp.Interior.ColorIndex = CorIndex Then
    
20.                 TempSum = TempSum + Val(Temp.Value)
    
21.             End If
    
22.         Next Temp
    
23.     Else
    
24.         TempSum = 0
    
25.     End If
    
26.     SumInteriorColor = TempSum
    
27. End Function
    
28. Function CountInteriorColor(Rng As Range, X As Variant) '根据单元格底色计数
    
29.     Dim CorIndex As Integer
    
30.     Dim Temp As Range, Rng1 As Range, Rng2 As Range
    
31.     Application.Volatile True
    
32. 
    
33.     If TypeName(X) = "Range" Then
    
34.         CorIndex = X.Interior.ColorIndex
    
35.     Else
    
36.         CountInteriorColor = "未知参数类型"
    
37.         Exit Function
    
38.     End If
    
39.    
    
40.     On Error Resume Next
    
41.     Set Rng = Intersect(Rng.Parent.UsedRange, Rng)
    
42.     On Error GoTo 0
    
43.    
    
44.     If Not Rng Is Nothing Then
    
45.         For Each Temp In Rng
    
46.             If Temp.Interior.ColorIndex = CorIndex Then
    
47.                 CountInteriorColor = CountInteriorColor + 1
    
48.             End If
    
49.         Next Temp
    
50.     Else
    
51.         CountInteriorColor = 0
    
52.     End If
    
53. End Function

复制代码

按单元格底色进行计数。

语法
CountInteriorColor(单元格区域,一个具有底色的单元格)
注意：单元格底色变换不会导致工作表重新计算！

yaozong

1. Private Sub CommandButton1_Click()
   
2.   Dim rng As Range, cel As Range, m&
   
3.   Set rng = ActiveSheet.UsedRange
   
4.   For Each cel In rng
   
5.     If cel.Interior.ColorIndex = 3 Then
   
6.        m = m + 1
   
7.     End If
   
8.   Next
   
9.   MsgBox "红色底纹格个数： " & m
   
10. End Sub

复制代码

561815084

Sub 颜色统计()
For Each Rng In [a1:c8] '循环的单元格，自己修改一下
If Rng.Interior.ColorIndex = 3 Then n = n + 1 '统计个数赋值给N----------Rng.Interior.ColorIndex = 3数字3为红色，想要查找其他颜色改一下数字
Next
MsgBox "红色底纹单元格" & n & "个"
End Sub

叶子の秋

0031126 发表于 2014-11-3 19:10
按单元格底色进行计数。

语法

1. xx = CountInteriorColor([C3:G33], "C6")
   
2. MsgBox xx

复制代码

为什么不行?

叶子の秋

yaozong 发表于 2014-11-3 19:19

多谢!                    

叶子の秋

561815084 发表于 2014-11-3 19:29
Sub 颜色统计()
For Each Rng In [a1:c8] '循环的单元格，自己修改一下
If Rng.Interior.ColorIndex = 3  ...

多谢 和上面的一样

0031126

叶子の秋 发表于 2014-11-3 19:34
为什么不行?

Sub a()
Dim xx
xx = CountInteriorColor([C3:G33], Range("C6"))
MsgBox xx
End Sub

叶子の秋

0031126 发表于 2014-11-3 19:43
Sub a()
Dim xx
xx = CountInteriorColor([C3:G33], Range("C6"))

哦 我第二个参数写错了  晕  

hai0625

0031126 发表于 2014-11-3 19:10
按单元格底色进行计数。

语法

有三个问题请教一下：
1、有办法让单元格底色变换导致工作表重新计算吗？
2、“单元格区域”，没法选择多个区域，比如CountInteriorColor(C6:C10,E6:E10,A1)
3、运行环境Excel2010，按Ctrl选择多个区域的时候，所有工作表都会在Excel内最小化，这个是怎么回事？

谢谢！