VBA中创建“MSScriptControl.ScriptControl”失败

梧叶沙沙 · 发表于 2019-1-13 15:14

yzxfelix 发表于 2018-1-30 08:12
应该不用创建，用with CreateObject("msscriptcontrol.scriptcontrol")

.Lan ...

那不和Set JS = CreateObject("msscriptcontrol.scriptcontrol")一样的效果吗？一样没法用

ivccav · 发表于 2019-1-13 16:18

不想说什么，在座的各位，需要使用64位的Office吗？64位不支持ActiveX控件。

不能因为网上资源是免费的，就用高版本，如果尊重版权，我不信这么多高版本的。

onERR · 发表于 2019-5-11 18:28

在x64 OFFICE中使用ScriptControl控件的方法
https://blog.csdn.net/dengnihuilaiwpl/article/details/72639705

补充内容 (2021-4-20 14:44):
Sub Test()
Dim oSC As Object
Set oSC = CreateObjectx86("MSScriptControl.ScriptControl") ' create ActiveX via x86 mshta host
Debug.Print TypeName(oSC) ' ScriptControl
With oSC
      '操作oSC
End With
CreateObjectx86 , True ' close mshta host window at the end
End Sub
Function CreateObjectx86(Optional sProgID, Optional bClose = False)
Static oWnd As Object
Dim bRunning As Boolean
#If Win64 Then
      bRunning = InStr(TypeName(oWnd), "HTMLWindow") > 0
      If bClose Then
         If bRunning Then oWnd.Close
         Exit Function
      End If
      If Not bRunning Then
         Set oWnd = CreateWindow()
         oWnd.execScript "Function CreateObjectx86(sProgID): Set CreateObjectx86 = CreateObject(sProgID): End Function", "VBScript"
      End If
      Set CreateObjectx86 = oWnd.CreateObjectx86(sProgID)
#Else
      Set CreateObjectx86 = CreateObject("MSScriptControl.ScriptControl")
#End If
End Function
Function CreateWindow()
Dim sSignature, oShellWnd, oProc
On Error Resume Next
sSignature = Left(CreateObject("Scriptlet.TypeLib").GUID, 38)
CreateObject("WScript.Shell").Run "%systemroot%\syswow64\mshta.exe about:""about:<head><script>moveTo(-32000,-32000);document.title='x86Host'</script><hta:application showintaskbar=no /><object id='shell' classid='clsid:8856F961-340A-11D0-A96B-00C04FD705A2'><param name=RegisterAsBrowser value=1></object><script>shell.putproperty('" & sSignature & "',document.parentWindow);</script></head>""", 0, False
Do
      For Each oShellWnd In CreateObject("Shell.Application").Windows
         Set CreateWindow = oShellWnd.GetProperty(sSignature)
         If Err.Number = 0 Then Exit Function
         Err.Clear
      Next
Loop
End Function

wangyihong99 · 发表于 2020-2-20 10:46

onERR 发表于 2019-5-11 18:28
在x64 OFFICE中使用ScriptControl控件的方法
https://blog.csdn.net/dengnihuilaiwpl/article/details/726 ...

亲测成功！感谢！

scbzyj · 发表于 2020-4-6 13:14

onERR 发表于 2019-5-11 18:28
在x64 OFFICE中使用ScriptControl控件的方法
https://blog.csdn.net/dengnihuilaiwpl/article/details/726 ...

学习了，谢谢

littlegwzh · 发表于 2020-4-6 15:38

onERR 发表于 2019-5-11 18:28
在x64 OFFICE中使用ScriptControl控件的方法
https://blog.csdn.net/dengnihuilaiwpl/article/details/726 ...

太强大了，学习了，感谢分享。

Allisonzhao · 发表于 2020-5-6 15:22

onERR 发表于 2019-5-11 18:28
在x64 OFFICE中使用ScriptControl控件的方法
https://blog.csdn.net/dengnihuilaiwpl/article/details/726 ...

终于解决了，很强大，感谢~

onERR · 发表于 2021-4-20 14:49

在x64 OFFICE中使用ScriptControl控件的方法
https://blog.csdn.net/dengnihuilaiwpl/article/details/72639705

Sub Test()
Dim oSC As Object
Set oSC = CreateObjectx86("MSScriptControl.ScriptControl") ' create ActiveX via x86 mshta host
Debug.Print TypeName(oSC) ' ScriptControl
With oSC
'操作oSC
End With
CreateObjectx86 , True ' close mshta host window at the end
End Sub
Function CreateObjectx86(Optional sProgID, Optional bClose = False)
Static oWnd As Object
Dim bRunning As Boolean
#If Win64 Then
bRunning = InStr(TypeName(oWnd), "HTMLWindow") > 0
If bClose Then
If bRunning Then oWnd.Close
Exit Function
End If
If Not bRunning Then
Set oWnd = CreateWindow()
oWnd.execScript "Function CreateObjectx86(sProgID): Set CreateObjectx86 = CreateObject(sProgID): End Function", "VBScript"
End If
Set CreateObjectx86 = oWnd.CreateObjectx86(sProgID)
#Else
Set CreateObjectx86 = CreateObject("MSScriptControl.ScriptControl")
#End If
End Function
Function CreateWindow()
Dim sSignature, oShellWnd, oProc
On Error Resume Next
sSignature = Left(CreateObject("Scriptlet.TypeLib").GUID, 38)
CreateObject("WScript.Shell").Run "%systemroot%\syswow64\mshta.exe about:""about:<head><script>moveTo(-32000,-32000);document.title='x86Host'</script><hta:application showintaskbar=no /><object id='shell' classid='clsid:8856F961-340A-11D0-A96B-00C04FD705A2'><param name=RegisterAsBrowser value=1></object><script>shell.putproperty('" & sSignature & "',document.parentWindow);</script></head>""", 0, False
Do
For Each oShellWnd In CreateObject("Shell.Application").Windows
Set CreateWindow = oShellWnd.GetProperty(sSignature)
If Err.Number = 0 Then Exit Function
Err.Clear
Next
Loop
End Function

复制代码

小羽凡 · 发表于 2021-11-18 14:23

onERR 发表于 2019-5-11 18:28
在x64 OFFICE中使用ScriptControl控件的方法
https://blog.csdn.net/dengnihuilaiwpl/article/details/726 ...

插个眼，日后学习一下

游乐缘 · 发表于 2022-1-11 09:58

onERR 发表于 2021-4-20 14:49
在x64 OFFICE中使用ScriptControl控件的方法
https://blog.csdn.net/dengnihuilaiwpl/article/details/7 ...

感谢大神分享，日后留用

		自动登录	找回密码
密码			免费注册

[求助] VBA中创建“MSScriptControl.ScriptControl”失败

评分