[开_146]数值两两之差的乘积[已结]

delete_007

值此新春佳节之际，出个小题目，给大家助助兴。
题目说明、要求及评分规则见下图：

[开_146]数值两两之差的乘积.rar (3.98 KB, 下载次数: 184)

2014-1-28 10:47 上传

点击文件名下载附件

竞赛日期：2014-1-26至2014-2-10

该贴已经同步到 delete_007的微博

cleverzhzhf

占楼参与一下，第一思路，60字符：

1. =PRODUCT(IF(ROW(1:6)<=COLUMN(A:F),1,A2:A7-TRANSPOSE(A2:A7)))

复制代码

——————————————分割线————————————————————

其实呢。。。原理就是这个样子的。。。63字符：

1. =PRODUCT(A3:A7-A2:A6,A4:A7-A2:A5,A5:A7-A2:A4,A6:A7-A2:A3,A7-A2)

复制代码

————————————分割线——————————————

其实呢。。。也可以这样理解这个原理。。。51字符：

1. =PRODUCT(A7-A2:A6,A6-A2:A5,A5-A2:A4,A4-A2:A3,A3-A2)

复制代码

---

第一公式中的“1”多余了，可以再少几个字符（57字）：=PRODUCT(IF(ROW(1:6)>COLUMN(A:F),A2:A7-TRANSPOSE(A2:A7)))
第二、第三公式不满足扩展性。评30财富。
          ——delete_007

ldda

=PRODUCT(IF(ROW(2:6)>COLUMN(A:E),A3:A7-TRANSPOSE(A2:A6),1))

---

公式中的“1”也是多余的，（57字符）：=PRODUCT(IF(ROW(2:6)>COLUMN(A:E),A3:A7-TRANSPOSE(A2:A6)))
评30财富。
          ——delete_007

476363814

小于35个字符看样子我是完不成了，
但是不知道楼主给出的模拟答案是不是错误的，还是我理解错了：A4-A3:A2=11-(5+6)=0，所以不管其他数是多少乘积应该是0，为什么楼主算出来的是-4147200
下面是我理解的公式，有误的地方请指教：

1. =PRODUCT(A3:A7-MMULT(N(ROW(1:5)>=COLUMN(A:E)),A2:A6))

复制代码

---

题意理解有误，结果错误。评5财富，感谢参与。
          ——delete_007

pxiceplay

=PRODUCT(IF(ROW(1:6)>COLUMN(A:F),A2:A7-TRANSPOSE(A2:A7),1))
35字符得是有多精妙的公式啊……

---

与楼上一样，PRODUCT可忽略逻辑值，于是公式可变成57字符。=PRODUCT(IF(ROW(1:6)>COLUMN(A:F),A2:A7-TRANSPOSE(A2:A7)))
正确答案，评30财富。
          ——delete_007

CheryBTL

刚看到，来个57字符的，不知是否符合题意，算抢红包了：

1. =PRODUCT(IF(ROW(2:6)>COLUMN(A:E),A3:A7-TRANSPOSE(A2:A6)))

复制代码

---

此思路下的最简公式了，评30财富。感谢参与。
          ——delete_007

delete_007

=============答题截止=============
请楼上各位不要再编辑帖子，以免影响评分。

delete_007

我的答案（31字符）：

1. =MDETERM(A2:A7^(COLUMN(A:F)-1))

复制代码

实质上是运用了一个范德蒙德行列式（线性代数中的内容）。

楼上几位都是用的常规思路，感谢参与，评分立即送上。
这期题目较简单，我就不一一分析了。

另开个ID

delete_007 发表于 2014-2-11 09:04
我的答案（31字符）：实质上是运用了一个范德蒙德行列式（线性代数中的内容）。

楼上几位都是用的常规思 ...

问一下版主，如果是两列两行，MDETERM是怎么返回的？

delete_007

另开个ID 发表于 2014-2-17 09:14
问一下版主，如果是两列两行，MDETERM是怎么返回的？

MDETERM这个函数是计算行列式的。