[开_145-3]连号判断与显示[已总结]

delete_007

竞赛日期：2013-11-26至2013-12-20

---

这两天感冒了，开帖时间延迟至2013-12-27，请谅解。
目前最佳答案144字符！
题目说明：
  1.A3:G12为数据区域，可引用。数据区均为[1,9999]的正整数。
  2.每行按升序排列。
  3.寻找每行中的连号，并按要求显示结果：
    如一行中没有连号，则显示“无连号”；
    如只有一段连号，则显示“n连号”（n代表连号的数字个数）；
    如7个数字刚好组成顺子，则显示“7顺”；
    如有多段连号，则每段连号间用“+”连接。
      （详见数据区的底色标示及模拟结果）

答题要求：
  1.纯函数题，在H3录入公式，并下拉完成。禁止其它任何操作。
  2.通过2003版EXCEL验证。

评分：
  1.公式长度（含=）小于210个字符，得1分；
  2.公式长度（含=）小于170个字符，得2分；
  3.其余正确答案，给予适当财富奖励。

[开_145-3]连号判断与显示.rar (4.84 KB, 下载次数: 355)

2013-11-26 13:21 上传

点击文件名下载附件

该贴已经同步到 delete_007的微博

ff8feng

{:soso_e141:}
我先来捧个场
=TEXT(TEXT(SUBSTITUTE(SUM(TEXT(FREQUENCY(COLUMN(A:G),(B3:G3-A3:F3<>1)*COLUMN(A:F)),"[<2]!0")*10^(7-ROW($1:$7))),0,),"[=7]7顺;[<7]0连号;0;无连号"),"[>99]0连号+0连号+0连号;0连号+0连号")

补充内容 (2013-12-13 14:47):
缩减一下
=MID(SUBSTITUTE(TEXT(SUM(TEXT(FREQUENCY(ROW($1:$7),(B3:G3-A3:F3<>1)*COLUMN(A:F)),"[<2]!0")*10^(7-ROW($1:$7))),"[=7]+7顺;[=]+无连号;"&REPT("+0连号",6)),"+0连号",),2,99)

CheryBTL

先交答案，又是死在大门前，179字符：

1. =SUBSTITUTE(TEXT(SUBSTITUTE(SUM(TEXT(FREQUENCY(IF(A3:F3+1=B3:G3,COLUMN(A:F)),(A3:F3+1<>B3:G3)*COLUMN(A:F))+1,"[=1]!0;0")*10^(7-ROW($1:$7))),0,),"[=7]0顺;;0连号+0连号+0连号;无连号"),"0连号+",)

复制代码

原来可以省掉第一个TEXT,164字符：

1. =SUBSTITUTE(TEXT(SUBSTITUTE(SUM((FREQUENCY(IF(A3:F3+1=B3:G3,COLUMN(A:F)),(A3:F3+1<>B3:G3)*COLUMN(A:F))+1)*10^(7-ROW($1:$7))),1,),"[=7]0顺;;0连号+0连号+0连号;无连号"),"0连号+",)

复制代码

xgg2001

1. =MID(SUBSTITUTE(TEXT(SUM((FREQUENCY(IF(B3:G3-A3:F3=1,COLUMN(A:F)),SMALL((B3:G3-A3:F3=1)*7+COLUMN(A:F),ROW($1:$6)))+1)*10^(7-ROW($1:$7))),"[>7e6]17顺;[=1111111]1无连号;"&REPT("+0连号",7)),"+1连号",),2,99)

复制代码

195先占个位子，回头慢慢想

opqazxc

1. =SUBSTITUTE(TEXT(SUBSTITUTE(SUM((FREQUENCY(IF(A3:F3+1=B3:G3,B3:G3),(A3:F3+1<>B3:G3)*B3:G3)+1)*10^(7-ROW($1:$7))),1,),"[=7]7顺;;0连号+0连号+0连号;无连号"),"0连号+",)

复制代码

含等号152
``


补充内容 (2013-12-17 00:12):

1. =SUBSTITUTE(TEXT(SUBSTITUTE(SUM(FREQUENCY(B3:G3,(B3:G3-A3:F3<>1)*B3:G3)*10^(7-ROW($1:$7)))+1,1,),"[=7]7顺;;"&REPT("0连号+",6)&"0连号;无连号"),"0连号+",)

复制代码

含等号142``

补充内容 (2013-12-17 00:29):
142问题多多``

sharprain

1. =SUBSTITUTE(TEXT(SUBSTITUTE(MMULT(10^(7-COLUMN(A:G)),FREQUENCY(IF(B3:G3=A3:F3+1,B3:G3),IF(B3:G3<>A3:F3+1,B3:G3,))+1),1,),"[=7]7顺;;0连号"&REPT("+0连号",6)&";无连号"),"0连号+",)

复制代码

166字节，站位先

ykqrs

用最简单的思路撰写出最华丽的篇章
7版，穷举法，163字，和模拟结果等同

1. =SUBSTITUTE(TEXT(0&SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUM((A3:F3+1=B3:G3)*10^{6,5,4,3,2,1}),10,2),12,3),13,4),0,),"[=1114]7顺;[>]0连号+0连号+0连号;无连号"),"0连号+",)

复制代码

如果数据是1223456，或者1234556，就要改一下，任然穷举，179字

1. =SUBSTITUTE(TEXT(0&SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUM((A3:F3+1=B3:G3)*10^{6,5,4,3,2,1}),10,2),12,3),13,4),14,5),0,),"[=115]7顺;[>]0连号+0连号+0连号;无连号"),"0连号+",)

复制代码

这一行留着哪天想出不穷举的方法便于编辑

补充内容 (2013-12-19 18:13):
这道竞赛题自从来了个华丽篇章后就忘了还有这么一码事了，今天下午通过手机的提醒事项提醒才又看了一遍，还真发现问题了，1234569，返回错误，再套一层又超嵌套，弄了一下午，搜索了相关的帖子，从254到215，到现199

补充内容 (2013-12-19 18:16):
=SUBSTITUTE(TEXT(0&SUBSTITUTE(SUM((MMULT((MMULT(N((A3:F3+1)<>B3:G3),N(COLUMN(A:F)>ROW($1:$6)))=ROW($1:$6)-1)*(A3:F3+1=B3:G3),A$3:A$8^0)+1)*10^{5;4;3;2;1;0}),1,),"[=7]7顺;[=0]无连号;0连号+0连号+0连号"),"0连号+",)

补充内容 (2013-12-19 18:23):
原来补充还有字数限制，1分2分事小，华丽篇章的口号都喊出去了，这要是不能及时发现，让我情何以堪，这人就丢大发了。。。。。。。。

swyrlbq

1. =SUBSTITUTE(TEXT(SUBSTITUTE(SUM((FREQUENCY(IF(A3:F3=B3:G3-1,COLUMN(A:F)),(A3:F3<>B3:G3-1)*COLUMN(A:F))+1)*10^(7-ROW($1:$7))),1,),"[=7]0顺;[>]0连号+0连号+0连号;;无连号"),"0连号+",)

复制代码

cleverzhzhf

头都快炸了。。。还是得出低于字符数限制的。。。
233字符，普通公式，把所有可能出现的效果，得到1、0的数字，都列出来，然后BIN2DEC，转化为10进制来看，不过再增加数字，这个分析的复杂程度将几何倍增长：

1. =SUBSTITUTE(TEXT(LOOKUP(BIN2DEC(MID(SUMPRODUCT((B3:G3-A3:F3=1)*10^-COLUMN(A:F)),3,6)),ROW($1:$33)*2-3,{"无连号";2;3;22;4;22;23;32;5;22;23;222;24;32;33;24;6;22;23;222;24;222;223;232;25;32;33;322;34;42;43;52;"7顺"}),"0连号+0连号+0连号"),"0连号+",)

复制代码

329字符，兼容性更强，公式稍加修改，便可以接受最多出现“9连号”的结果。不过不能使用“定义名称”，这里即将超出嵌套，所以没处理“无连号”和“7顺”：

1. =TEXT(SUBSTITUTE(SUMPRODUCT(FREQUENCY(IF(A3:F3=B3:G3-1,{1,2,3,4,5,6}),IF(A3:F3<>B3:G3-1,{1,2,3,4,5,6}))+1,10^(ROW(INDIRECT("1:"&COUNT(FREQUENCY(IF(A3:F3=B3:G3-1,{1,2,3,4,5,6}),IF(A3:F3<>B3:G3-1,{1,2,3,4,5,6})))))-1)),1,),REPT("0连号+",SUM(--(FREQUENCY(IF(A3:F3=B3:G3-1,{1,2,3,4,5,6}),IF(A3:F3<>B3:G3-1,{1,2,3,4,5,6}))>0))-1)&"0连号")

复制代码

1. =SUBSTITUTE(TEXT(0&SUBSTITUTE(SUM(SMALL(IF(B3:G3-A3:F3=1,,COLUMN(A:F)),ROW($1:$6))*10^{5;4;3;2;1;0}*{10,-1})+7,1,),"[=]无连号;[=7]7顺;0连号+0连号+0连号"),"0连号+",)

复制代码

(开_145-3)连号判断与显示-小翟（思路过程）.zip (19.52 KB, 下载次数: 119)

2013-11-28 16:40 上传

点击文件名下载附件

补充内容 (2013-12-27 13:54):
调整一下细节，148字符
=SUBSTITUTE(TEXT(SUBSTITUTE(SUM(SMALL(IF(B3:G3-A3:F3=1,,COLUMN(A:F)),ROW($1:$6))*10^{5;4;3;2;1;0}*{10,-1})+7,1,),"[=7]7顺;;0连号+0连号+0连号;无连号"),"0连号+",)

wlc5201130

=SUBSTITUTE(TEXT(SUBSTITUTE(0&SUM((FREQUENCY(IF(B3:G3-A3:F3=1,COLUMN(A:F)),(B3:G3-A3:F3<>1)*COLUMN(A:F))+1)*10^(7-ROW($1:$7))),1,),"[=7]7顺;[=0]无连号;0连号+0连号+0连号"),"0连号+",)
数组