[开_145-2]计算根号2，比精度比速度[已总结]

lee1892 · 发表于 2013-11-26 08:26

本帖最后由 delete_007 于 2014-6-26 09:01 编辑

竞赛日期：2013-11-26至2013-12-20
题目内容：

根号 2 是个无理数，可以通过编程无限制的计算其小数点后面的数字。让我们来比一下谁能算得最精确，谁能算得最快 {:soso_e100:}

答题要求：

请按下述代码编写一个输出根号2的函数，返回数字文本：

Public Function SQRT2(ByVal Length As Long, Optional ByRef dTime As Double) As String
Dim t#: t = Timer
On Error GoTo RTE
' ......
END_FUNC:
t = Timer - t: dTime = t
Debug.Print " ID: " & "<YOUR ID>"
Debug.Print " Time Used: " & Format(t, "0.00s")
Debug.Print "Calculated: " & Length & " digits of square root 2."
Exit Function
RTE:
Err.Clear: On Error GoTo 0
dTime = -1
End Function

复制代码

可自行添加所需要的任何其它过程或函数，但请设置为Private。如有外部变量也请设置为Private。方便汇总。

评分规则：

1、能够正确计算根号2（根号2的计算算法正确），不限长度，得 1 分
2、理论上能正确计算任意长度（Long型），不限时间，得 1 分
3、能在 4 秒内计算小数点后一万个准确数字的，得 1 分
4、评分人会根据代码，建议追加优秀代码分
执行速度以评分人的机器为准，下面的代码在我机器上约需 4 秒（可多次执行，取中间值）：

Sub TimeCompare_4Secs()
Dim i&, s$, t#
t = Timer
For i = 1 To 83500
s = s & Chr(Int(Rnd * 10 + 48))
Next
s = ""
Debug.Print Timer - t
End Sub

复制代码

提示：

1、快速的根号 2 的计算方法
2、超大整数的四则运算的实现
3、用整数计算小数的办法

参考根号 2 小数点后100位：
1.41421356237309504880168872420969807856967187537694807317667973799073247846210703885038753432764157

是否参与评论：

可以参与

参考答案：

另加~

lee1892 · 发表于 2014-6-12 12:37

抱歉拖了这么长时间，不过相信大家都知道结果了

测试结果如下：

Testing length: 100
----------------------------
ID: Lee1892 - Origin Code
Time Used: 0.0000s
Calculated: 100 digits of square root 2.
----------------------------
ID: Lee1892 - Fast Code
Time Used: 0.0000s
Calculated: 100 digits of square root 2.
----------------------------
ID: 香川群子
Time Used: 0.00s
Calculated: 100 digits of square root 2.
----------------------------
ID: cleverzhzhf
Time Used: 0.00s
Calculated: 100 digits of square root 2.
楼03_cleverzhzhf is OUT for wrong digit too early.
The wrong digit from number 2
Right one is 1.41421356
The answer is 10.0000000
----------------------------
ID: jsxjd
Time Used: 0.00s
Calculated: 100 digits of square root 2.
----------------------------
ID: 苍海拾贝
Time Used: 0.34s
Calculated: 100 digits of square root 2.
----------------------------
ID: doryan
Time Used: 0.00s
Calculated: 100 digits of square root 2.
楼07_doryan is OUT for wrong digit too early.
The wrong digit from number 2
Right one is 1.41421356
The answer is 10.
============================
Testing length: 300
----------------------------
ID: Lee1892 - Origin Code
Time Used: 0.0156s
Calculated: 300 digits of square root 2.
----------------------------
ID: Lee1892 - Fast Code
Time Used: 0.0000s
Calculated: 300 digits of square root 2.
----------------------------
ID: 香川群子
Time Used: 0.03s
Calculated: 300 digits of square root 2.
----------------------------
楼03_cleverzhzhf is already OUT.
----------------------------
ID: jsxjd
Time Used: 0.00s
Calculated: 300 digits of square root 2.
----------------------------
ID: 苍海拾贝
Time Used: 7.72s
Calculated: 300 digits of square root 2.
楼06_苍海拾贝 is OUT for overtime using.
----------------------------
楼07_doryan is already OUT.
============================
Testing length: 1000
----------------------------
ID: Lee1892 - Origin Code
Time Used: 0.0156s
Calculated: 1000 digits of square root 2.
----------------------------
ID: Lee1892 - Fast Code
Time Used: 0.0156s
Calculated: 1000 digits of square root 2.
----------------------------
ID: 香川群子
Time Used: 0.48s
Calculated: 1000 digits of square root 2.
----------------------------
楼03_cleverzhzhf is already OUT.
----------------------------
ID: jsxjd
Time Used: 0.02s
Calculated: 1000 digits of square root 2.
----------------------------
楼06_苍海拾贝 is already OUT.
----------------------------
楼07_doryan is already OUT.
============================
Testing length: 3000
----------------------------
ID: Lee1892 - Origin Code
Time Used: 0.2031s
Calculated: 3000 digits of square root 2.
----------------------------
ID: Lee1892 - Fast Code
Time Used: 0.0469s
Calculated: 3000 digits of square root 2.
----------------------------
ID: 香川群子
Time Used: 9.05s
Calculated: 3000 digits of square root 2.
楼02_香川群子 is OUT for overtime using.
楼02_香川群子 is OUT for wrong digit too early.
The wrong digit from number 2708
Right one is 9314549999
The answer is 9314559999
----------------------------
楼03_cleverzhzhf is already OUT.
----------------------------
ID: jsxjd
Time Used: 0.05s
Calculated: 3000 digits of square root 2.
----------------------------
楼06_苍海拾贝 is already OUT.
----------------------------
楼07_doryan is already OUT.
============================
Testing length: 5000
----------------------------
ID: Lee1892 - Origin Code
Time Used: 0.5469s
Calculated: 5000 digits of square root 2.
----------------------------
ID: Lee1892 - Fast Code
Time Used: 0.1406s
Calculated: 5000 digits of square root 2.
----------------------------
楼02_香川群子 is already OUT.
----------------------------
楼03_cleverzhzhf is already OUT.
----------------------------
ID: jsxjd
Time Used: 0.13s
Calculated: 5000 digits of square root 2.
----------------------------
楼06_苍海拾贝 is already OUT.
----------------------------
楼07_doryan is already OUT.
============================
Testing length: 10000
----------------------------
ID: Lee1892 - Origin Code
Time Used: 2.2031s
Calculated: 10000 digits of square root 2.
----------------------------
ID: Lee1892 - Fast Code
Time Used: 0.5313s
Calculated: 10000 digits of square root 2.
----------------------------
楼02_香川群子 is already OUT.
----------------------------
楼03_cleverzhzhf is already OUT.
----------------------------
ID: jsxjd
Time Used: 0.47s
Calculated: 10000 digits of square root 2.
----------------------------
楼06_苍海拾贝 is already OUT.
----------------------------
楼07_doryan is already OUT.
============================

复制代码

ID	正确计算	计算任意长度	4秒计算万位	优秀代码	奖励合计
香川群子	√	√			2 技术分
cleverzhzhf					参与比赛财富奖励
jsxjd	√	√	√	√	4 技术分
苍海拾贝	√	√			2 技术分
doryan					参与比赛财富奖励

香川的代码在2708位会出现错误，不知是何原因

香川群子 · 发表于 2013-11-26 17:07

本帖最后由香川群子于 2013-12-10 09:24 编辑

图片为2450位的答案参考：

…………
我觉得找到好的正确的算法是主要的关键。写代码倒是其次。呵呵。

2开方_kagawa.rar (19.63 KB, 下载次数: 34)

一直没空……终于有空写了个简单的代码，先看结果是否正确，速度还来不及优化。

主代码倒是比较简单：

a$ = Left(2 ^ 0.5, 16)
N_2a$ = Left("0" & 1 / a, 17)
a_2$ = Left("0" & a / 2, 17)
'三个计算参数的初始化

Do Until Len(a) > Length
      a$ = PM_2(a, N_2a, a_2)
      N_2a$ = DV_2a(a, N_2a)
      a_2$ = DV_2(a, a_2)
Loop '循环计算直至达到长度要求
SQRT2 = Left(a, Length) '输出结果

结果不理想。
第一、速度慢，第二、计算到2708位时有错误了。

补充内容 (2013-12-10 20:09):
代码错误用检查乘积的方法解决了……现在的问题是速度太慢了。

cleverzhzhf · 发表于 2013-11-29 17:29

本帖最后由 cleverzhzhf 于 2013-12-2 12:44 编辑

超大整数的，暂时还实现不了，先弄一个，可以计算任意Long数字的，精度以Double为准：

Function SqrTwo(ByVal Length As Long) As String
Dim t#: t = Timer
Dim iCmp As Double, iLen As Integer
Dim strLength As String, strOri As String
iLen = Len(CStr(Length))
If iLen Mod 2 = 1 Then '判定数字长度是奇数还是偶数，对奇数位数字，前面加0，补成偶数位
strLength = 0 & Length
Else
strLength = Length
End If
iLen = Len(strLength)
iDotPosi = iLen / 2 '计算以整数计算，最终确定字符串插入小数点的位置
strOri = Left(strLength, 2)
iOri = CInt(strOri)
For i = 0 To 9 '先得到第一位数的结果
If i ^ 2 > iOri Then Exit For
Next
iCmp = iOri - (i - 1) ^ 2
' iCmp = Val(iCmp & "00")
strResult = (i - 1)
On Error GoTo Result '当超过Double的限制时跳出循环
Do
m = m + 1
If m * 2 < iLen Then '根据计算理论(10a+b)^2=(10a)^2+b*(20a+b)
iCmp = iCmp * 100 + Mid(strLength, m * 2 + 1, 2) '如果计算数字，还有数，则向后取两位
Else
iCmp = iCmp * 100 '如果计算数字已经没数，补两个0在最后，继续计算
End If
For j = 0 To 9
If (CDbl(strResult) * 20 + j) * j > iCmp Then Exit For
Next
iCmp = (iCmp - (CDbl(strResult) * 20 + j - 1) * (j - 1)) '下一个将要做减法的数字：=上一次遗留数-b*(20*已得结果+b)
strResult = strResult & j - 1
Loop Until Len(strResult) > 10000
Result:
SqrTwo = Application.Replace(strResult, iDotPosi + 1, 0, ".")
Debug.Print " ID: " & "cleverzhzhf"
Debug.Print " Time Used: " & Format(Timer - t, "0.00s")
Debug.Print "Calculated: " & Length & " digits of square root 2."
End Function

复制代码

liucqa · 发表于 2013-12-2 00:08

http://club.excelhome.net/thread-1076623-1-3.html

你的帖子以后可真不能跟了，先是封权限，后是无法访问，简直就是噩梦

jsxjd · 发表于 2013-12-7 22:01

本帖最后由 jsxjd 于 2013-12-9 21:18 编辑

根据楼主的100位示例代码，返回的位数是包括“1.”在内的“总位数”
10000 位本机执行0.34秒，最后100位为：
4644372856895928683197779778693464159846974513391774153790487788083002205833504674655532302858732583
20000 位本机执行1.34秒，最后100位为：
2299688266236189437975463431486940473705466022052365853522433491893414953731854617756390850630149805

Public Function SQRT2(ByVal Length As Long, Optional ByRef dTime As Double) As String
Dim t#: t = Timer
On Error GoTo RTE
' ......
Dim tempNominator&, Nominator&, Denominator&
Dim SqrtLen&, i&, kk&, Product&, Carry&
Dim NoneZero&, newNoneZero&, rank&, C0&, C1&
Dim Root&(30000), Rst&(1, 30000) '可适当修改
If Length < 1 Then Exit Function
SqrtLen = (Length + 120) \ 4
Const FirstDigit& = 10
Root(FirstDigit) = 1: Rst(0, FirstDigit) = 1: NoneZero = FirstDigit
tempNominator = -3: rank = 1
For kk = 1 To SqrtLen
tempNominator = tempNominator + 2
Nominator = Abs(tempNominator)
Product = 0
For i = SqrtLen To NoneZero - FirstDigit Step -1 ' *(2kk-3)
Product = Root(i) * Nominator + (Product \ 10000)
Root(i) = Product Mod 10000
Next
Product = 0
Denominator = tempNominator + 3
For i = NoneZero - FirstDigit To SqrtLen ' / 2kk
Product = 10000 * (Product Mod Denominator) + Root(i)
Root(i) = Product \ Denominator
Next
Product = 0
For i = NoneZero - FirstDigit To SqrtLen ' *65918161
Product = 10000 * (Product Mod 8119) + Root(i)
Root(i) = Product \ 8119
Next
Product = 0: rank = 1 - rank
For i = NoneZero - FirstDigit To SqrtLen ' *65918161
Product = 10000 * (Product Mod 8119) + Root(i)
Root(i) = Product \ 8119
Rst(rank, i) = Rst(rank, i) + Root(i)
Next
newNoneZero = SqrtLen + 1
For i = NoneZero To SqrtLen
If Root(i) > 0 Then
newNoneZero = i
Exit For
End If
Next
If newNoneZero > SqrtLen Then Exit For
NoneZero = newNoneZero
Next
For i = SqrtLen To 0 Step -1
C0 = (C0 \ 10000) + Rst(0, i)
Rst(0, i) = C0 Mod 10000
C1 = (C1 \ 10000) + Rst(1, i)
Rst(1, i) = C1 Mod 10000
Next
'''''''''''''''''''''''''''''''''
C0 = 0: Carry = 0
For i = SqrtLen To 0 Step -1
C0 = Int(C0 / 10000) + Rst(0, i) - Rst(1, i)
Product = 8119 * ((1000000 + C0) Mod 10000) + Carry
Root(i) = Product Mod 10000
Carry = Product \ 10000
Next
Carry = 0
For i = 0 To SqrtLen
Product = 10000 * Carry + Root(i)
Root(i) = Product \ 5741
Carry = Product Mod 5741
Next
SQRT2 = Root(FirstDigit) & "."
For i = FirstDigit + 1 To SqrtLen
SQRT2 = SQRT2 & Format(Root(i), "0000")
Next
SQRT2 = Left(SQRT2, Length)
' ......
END_FUNC:
t = Timer - t: dTime = t
Debug.Print " ID: " & "<jsxjd>"
Debug.Print " Time Used: " & Format(t, "0.00s")
Debug.Print "Calculated: " & Length & " digits of square root 2."
Exit Function
RTE:
Err.Clear: On Error GoTo 0
dTime = -1
End Function

复制代码

另外，楼主给的4秒代码耗时不太稳定，请帮忙测试一下以便改进。

苍海拾贝 · 发表于 2013-12-9 22:03

'大数加法
Private Sub BigintAdd(ByVal n As Integer, ByRef a() As Long, ByRef b() As Long, ByRef c() As Long, Optional ca As Integer = 1, Optional cb As Integer = 1)
Dim i As Integer
For i = 0 To n - 1
c(i) = ca * a(i) + cb * b(i)
Next
Progress n, c
End Sub
'大数除法
Private Sub BigintDiv(ByVal n As Integer, ByRef a() As Long, ByVal dv As Integer)
Dim i, k As Integer
For i = 0 To n - 2
k = a(i)
a(i) = Int(a(i) / dv)
a(i + 1) = a(i + 1) + 10 * (k Mod dv)
Next
a(n - 1) = Int(a(n - 1) / dv)
End Sub
'大数乘法
Private Sub BigintMul(ByVal n As Integer, ByRef a() As Long, ByRef b() As Long, ByRef c() As Long)
Dim i, j As Integer
For i = 0 To n - 1
c(i) = 0
Next
For i = 0 To n - 1
For j = 0 To n - i - 1
c(i + j) = c(i + j) + a(i) * b(j)
Next
Next
Progress n, c
End Sub
'大数进位
Private Sub Progress(ByVal n As Integer, ByRef a() As Long)
Dim i, na As Integer
na = 0
For i = 0 To n - 1
If a(i) > 0 Then
na = i
Exit For
End If
Next
For i = n - 1 To na + 1 Step -1
a(i - 1) = a(i - 1) + Int(a(i) / 10)
a(i) = a(i) Mod 10
Next
End Sub
Public Function SQRT2(ByVal Length As Long, Optional ByRef dTime As Double) As String
Dim t#: t = Timer
On Error GoTo RTE
' .....................................................................................
Dim a(0 To 10000) As Long
Dim b(0 To 10000) As Long
Dim c(0 To 10000) As Long
Dim d(0 To 10000) As Long
Dim result As String
Dim n, eps, i, ic As Integer
Dim l1 As Long
l1 = 2 '需要开方数据
eps = Length - 1 '精度,计算出的数字个数
n = Length + 5 '数组大小
a(0) = 0
b(0) = Int(Sqr(l1)) * 2
c(0) = Int(Sqr(l1))
Do While b(0) * b(0) / 4 <> l1
ic = 0
For i = 0 To eps - 1
ic = ic + Abs(b(i) - a(i))
Next
If ic = 0 Then Exit Do
BigintAdd n, a, b, c
BigintDiv n, c, 2
BigintMul n, c, c, d
If d(0) >= l1 Then
For i = 0 To n - 1
b(i) = c(i)
Next
Else
For i = 0 To n - 1
a(i) = c(i)
Next
End If
Loop
For i = 0 To eps - 1
result = result & c(i)
Next
SQRT2 = Left(result, Len(Trim(Int(Sqr(l1))))) & "." & Right(result, Len(result) - Len(Trim(Int(Sqr(l1)))))
END_FUNC:
t = Timer - t: dTime = t
Debug.Print "ID: " & "苍海拾贝"
Debug.Print "Time Used: " & Format(t, "0.00s")
Debug.Print "Calculated: " & Length & " digits of square root 2."
Exit Function
RTE:
err.Clear: On Error GoTo 0
dTime = -1
End Function

复制代码

位数越大，速度越慢，能力有限，继续学习

doryan · 发表于 2013-12-11 16:32

本帖最后由 doryan 于 2013-12-12 15:39 编辑

先发一份满足条件1和条件2的
手工开方的代码表现 LONG支持 double不支持
如楼主提示一般自己重写了字符串形式的四则运算来解决溢出问题
但由于算法优化不太懂太多的数组和字符串操作速度较慢 1000位都需要8秒建议只测试到100位

另外指出楼主给出的参考是小数点后98位 100位应该是
1.4142135623730950488016887242096980785696718753769480731766797379907324784621070388503875343276415727

Public Function SQRT2(ByVal Length As Long, Optional ByRef dTime As Double) As String
Dim t#: t = Timer
On Error GoTo RTE
SQRT2 = ss(Length, dTime)
END_FUNC:
t = Timer - t: dTime = t
Debug.Print " ID: " & "<doryan>"
Debug.Print " Time Used: " & Format(t, "0.00s")
Debug.Print "Calculated: " & Length & " digits of square root 2."
Exit Function
RTE:
Err.Clear: On Error GoTo 0
dTime = -1
End Function
Private Function ss(num, n) As String
Dim numstr As String
Dim yushu As String
Dim zhengshu As String, zsLen As Integer
Dim gen As Long
Dim kaifang As Long
kaifang = Application.WorksheetFunction.RoundDown((VBA.Sqr(num)), 0)
zhengshu = CStr(kaifang)
zsLen = Len(zhengshu)
gen = kaifang ^ 2
yushu = (num - gen)
' If Len(num) Mod 2 <> 0 Then
' numstr = "0" & num & Application.WorksheetFunction.Rept("0", n * 2)
' Else
' numstr = "" & num & Application.WorksheetFunction.Rept("0", n * 2)
' End If
Dim shishang As String
Dim bigger As Integer
Dim shiji As String
For i = 1 To n
yushu = yushu & "00"
shishang = ChengFa(zhengshu & "", "", True)
For j = CInt(chufa(yushu, shishang)) To 0 Step -1
shiji = ChengFa(JiaFa(shishang, j & ""), j & "")
bigger = CompareVal(yushu, shiji)
If bigger = 1 Then
zhengshu = zhengshu & j
yushu = JianFa(yushu, shiji)
Exit For
ElseIf bigger = -1 Then
Else
zhengshu = zhengshu & j
Exit For
End If
Next
Next
If n > 0 Then
ss = Left(zhengshu, Len(CStr(kaifang))) & "." & Mid(zhengshu, Len(CStr(kaifang)) + 1)
Else
ss = CStr(kaifang)
End If
End Function
Private Function chufa(a1 As String, a2 As String)
Dim l1 As Long, l2 As Long
Dim T1 As String, T2 As String
l1 = Len(a1)
l2 = Len(a2)
If CompareVal(a1, a2) = -1 Then
chufa = "0"
Else
T1 = Left(a1, l1 - (l2 - 1))
T2 = Left(a2, 1)
chufa = CInt(T1) / CInt(T2) + 1
If chufa > 9 Then chufa = 9
End If
End Function
Private Function ChengFa(a1 As String, a2 As String, Optional Twenty = False)
If Twenty Then
ChengFa = subChengFa(a1, 2) & "0"
Else
ChengFa = subChengFa(a1, a2)
End If
End Function
Private Function subChengFa(a1 As String, a2 As String)
Dim l1 As Long, l2 As Long, l3 As Long
l1 = Len(a1) + 1
l2 = Len(a2)
Dim arr()
ReDim arr(1 To l1)
arr(1) = "0"
For i = l1 To 2 Step -1
arr(i) = Mid(a1, i - 1, 1) * CInt(a2)
Next
For i = l1 To 2 Step -1
If Len(arr(i)) > 1 Then
arr(i - 1) = CInt(arr(i - 1)) + CInt(Left(arr(i), 1))
arr(i) = Right(arr(i), 1)
End If
Next
Dim pos As Integer
For i = 1 To l1
If arr(i) = 0 Then
pos = i
Else
Exit For
End If
Next
If pos = l1 Then
subChengFa = "0"
Else
subChengFa = Mid(Join(arr, ""), pos + 1)
End If
End Function
Private Function JianFa(a1 As String, a2 As String)
Dim l1 As Long, l2 As Long
l1 = Len(a1)
l2 = Len(a2)
a2 = Application.WorksheetFunction.Rept("0", l1 - l2) & a2
Dim arr()
ReDim arr(1 To l1)
For i = l1 To 1 Step -1
arr(i) = Mid(a1, i, 1) - Mid(a2, i, 1)
Next
For i = l1 To 1 Step -1
If arr(i) < 0 Then
arr(i - 1) = arr(i - 1) - 1
arr(i) = 10 + arr(i)
End If
Next
Dim pos As Integer
For i = 1 To l1
If arr(i) = 0 Then
pos = i
Else
Exit For
End If
Next
If pos = l1 Then
JianFa = "0"
Else
JianFa = Mid(Join(arr, ""), pos + 1)
End If
End Function
Private Function JiaFa(a1 As String, a2 As String)
Dim l1 As Long, l2 As Long
l1 = Len(a1) + 1
l2 = Len(a2)
a2 = Application.WorksheetFunction.Rept("0", l1 - l2 - 1) & a2
Dim arr()
ReDim arr(1 To l1)
arr(1) = "0"
For i = l1 To 2 Step -1
arr(i) = CInt(Mid(a1, i - 1, 1)) + CInt(Mid(a2, i - 1, 1))
Next
For i = l1 To 1 Step -1
If Len(arr(i)) > 1 Then
arr(i - 1) = arr(i - 1) + 1
arr(i) = arr(i) - 10
End If
Next
Dim pos As Integer
For i = 1 To l1
If arr(i) = 0 Then
pos = i
Else
Exit For
End If
Next
If pos = l1 Then
JiaFa = "0"
Else
JiaFa = Mid(Join(arr, ""), pos + 1)
End If
End Function
Private Function CompareVal(a1 As String, a2 As String)
Dim l1 As Long, l2 As Long
l1 = Len(a1)
l2 = Len(a2)
If l1 > l2 Then
CompareVal = 1
ElseIf l1 = l2 Then
Dim m1 As Integer, m2 As Integer
For i = 1 To l1
m1 = CInt(Mid(a1, i, 1))
m2 = CInt(Mid(a2, i, 1))
If m1 > m2 Then
CompareVal = 1
Exit Function
ElseIf m1 = m2 Then
GoTo NEXTLOOP
Else
CompareVal = -1
Exit Function
End If
NEXTLOOP:
Next
CompareVal = 1
Else
CompareVal = -1
End If
End Function
Private Sub TimeCompare_4Secs()
Dim i&, s$, t#
t = Timer
For i = 1 To 83500
s = s & Chr(Int(Rnd * 10 + 48))
Next
s = ""
Debug.Print Timer - t
End Sub

复制代码

delete_007 · 发表于 2013-12-23 16:05

答题截止日期已至，先开帖。
请楼主给出评分建议及总结。

lee1892 · 发表于 2013-12-23 20:59

最近非常忙，争取月内结。

delete_007 · 发表于 2013-12-23 21:38

好的，月底写总结没问题。
相信延迟几天大家也是可以谅解的。

		自动登录	找回密码
密码			免费注册

[Excel 程序开发] [开_145-2]计算根号2，比精度比速度[已总结]

评分

评分

评分

评分

评分

评分

点评

评分