[第100期]按三角形面积的大小排列[已总结]

fangjianp · 发表于 2013-9-26 12:57

本帖最后由 delete_007 于 2013-11-27 19:56 编辑

本题已总结，见28楼

题目：

班上有22名学生(A2:A23,可能更多),每人找回4根长短不一的木条,选择长度为中间2根

木条,如学生风清扬,选择木条2和木条4,长度分别为7和8,组成直角三角形的的两条直角边,

这样组成的三角形面积为28.按每人的三角形面积大小从大到小排列,如模拟答案G2:H23,

如果面积相同,则按A2:A23名单的先后次序排列.

答题要求：

1.不修改原数据，不使用辅助列,定义名称,VBA等.

2.在J2:K23输入多单元数组公式得出结果.

3.除输入在答题区输入公式外不得进行任何形式的其他操作.

4.2003版excel能通过

评分：

1.结果正确,公式长度(含=)小于300个字符,得1分.

2.公式长度(含=)小于215个字符,得2分.

3.公式长度(含=)小于180个字符,得3分.

竞赛开始日期：20131026，截止日期：20131125。
覅多占楼层，否则取消评分

delete_007 · 发表于 2013-10-31 09:31

=INDEX(IF({1,0},A1:A999,ROW(1:999)/2),MID(10^9+LARGE((1+10^MMULT(LOG(MOD(SMALL(B2:E23+ROW()/1%,ROW()*4-{6,5}),100)),{1;1}))/1%%%-ROW()*99,ROW()-1),{9,2},3),{1,2})

复制代码

162字符。

CheryBTL · 发表于 2013-10-31 12:53

本帖最后由 CheryBTL 于 2013-11-11 02:04 编辑

正常233字符：

=IF({1,0},INDEX(A:A,MOD(SMALL(ROW(2:23)-10^MMULT(LOG(SMALL(B2:E23+ROW(2:23)/1%,ROW(1:22)*4-{2,1})-ROW(2:23)/1%),{1;1})/1%,ROW()-1),100)),LARGE(10^MMULT(LOG(SMALL(B2:E23+ROW(2:23)/1%,ROW(1:22)*4-{2,1})-ROW(2:23)/1%),{1;1}),ROW()-1)/2)

复制代码

借用上期思路，用INDIRECT的R1C1相对引用，205字符：

=IF({1,0},INDEX(A:A,MOD(SMALL(ROW(2:23)-10^MMULT(LOG(SMALL(B2:E23+ROW(2:23)/1%,ROW(1:22)*4-{2,1})-ROW(2:23)/1%),{1;1})/1%,ROW()-1),100)),PRODUCT(SMALL(VLOOKUP(INDIRECT("RC[-1]",),A:E,{2,3,4,5},),{2,3}))/2)

复制代码

有空再想想吧
启用迭代运算1次后，190字符：

=IF({1,0},INDEX(A:A,MOD(SMALL(ROW(2:23)%-10^MMULT(LOG(SMALL(B2:E23%+ROW(2:23),ROW(1:22)*4-{2,1})-ROW(2:23)),{1;1})/1%%,ROW()-1),1)/1%),PRODUCT(SMALL(VLOOKUP(J2:J23,A:E,{2,3,4,5},),{2,3}))/2)

复制代码

把IF({1,0}）放在INDEX内部175字符，为什么不行，{:soso_e118:}{:soso_e118:}{:soso_e118:}

=INDEX(IF({1,0},A:A,PRODUCT(SMALL(VLOOKUP(J2:J23,A:E,{2,3,4,5},),{2,3}))/2),MOD(SMALL(ROW()%-10^MMULT(LOG(SMALL(B2:E23%+ROW(),ROW()*4-{6,5})-ROW()),{1;1})/1%%,ROW()-1),1)/1%,)

复制代码

补充内容 (2013-11-25 10:04):
188 字符=IF({1,0},INDEX(A:A,MOD(SMALL(ROW(2:23)%-10^MMULT(2+LOG(SMALL(B2:E23%+ROW(2:23),ROW(1:22)*4-{2,1})-ROW(2:23)),{1;1}),ROW()-1),1)/1%),PRODUCT(SMALL(VLOOKUP(J2:J23,A:E,{2,3,4,5},),{2,3}))/2)

sharprain · 发表于 2013-11-1 15:30

本帖最后由 delete_007 于 2013-11-16 17:33 编辑

=IF({1,0},INDEX(A:A,100-RIGHT(LARGE(SUBTOTAL(6,OFFSET(B1:E1,ROW(1:22),))/SUBTOTAL(4,OFFSET(B1:E1,ROW(1:22),))/SUBTOTAL(5,OFFSET(B1:E1,ROW(1:22),))/1%%-ROW(2:23),ROW(1:22)),2)),EXP(LARGE(MMULT(LN(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),))),{1;-1;-1}),ROW(1:22)))/2)

复制代码

很长时间没有参加竞赛了，占个位吧，慢慢简化,264
又想到了一种方法：

=IF({1,0},INDEX(A:A,MMULT(LARGE(10^MMULT(LOG10(SMALL(ROW(1:22)/1%+B2:E23,ROW(1:22)*4-{1,2})-ROW(1:22)/1%),{1;1})/1%%-ROW(2:23)/1%+ROW(2:23)*{0,1},ROW(1:22)*2-{0,1}),{-1;1})),EXP(LARGE(MMULT(LN(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),))),{1;-1;-1}),ROW(1:22)))/2)

复制代码

262字节

=IF({1,0},INDEX(A:A,MMULT(LARGE(10^MMULT(LOG10(SMALL(ROW(1:22)/1%+B2:E23,ROW(1:22)*4-{1,2})-ROW(1:22)/1%),{1;1})/1%%-{99,100}*ROW(2:23),ROW(1:22)*2-{1,0}),{1;-1})),EXP(LARGE(MMULT(LN(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),))),{1;-1;-1}),ROW(1:22)))/2)

复制代码

当然可以简化为以上的公式 252字节
208字：

=INDEX(IF({1,0},A2:A23,EXP(MMULT(LN(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),))),{1;-1;-1}))/2),MOD(LARGE(10^MMULT(LOG10(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),))),{1;-1;-1})/1%%-99*ROW(1:22),ROW(1:22)),100))

复制代码

CLL1998 · 发表于 2013-11-1 23:16

J2:J23{=INDEX(A2:A23,23-MOD(100*LARGE(RIGHT(LARGE(B2:E23+(23-ROW(1:22))*1000,2+(ROW(1:22)-1)*4)*LARGE(B2:E23+(23-ROW(1:22))*1000,3+(ROW(1:22)-1)*4),3)+(23-ROW(1:22))%,ROW(1:22)),100))}

175个字符

K2:K23{=INT(LARGE(RIGHT(LARGE(B2:E23+(23-ROW(1:22))*1000,2+(ROW(1:22)-1)*4)*LARGE(B2:E23+(23-ROW(1:22))*1000,3+(ROW(1:22)-1)*4),3)+(23-ROW(1:22))%,ROW(1:22)))/2}

152个字符

huahua2005 · 发表于 2013-11-2 22:45

本帖最后由 huahua2005 于 2013-11-3 14:40 编辑

刚从函数与公式1班毕业，来实践下{:soso_e121:}263个字符
J2:K23

=INDEX(IF({1,0},EXP(MMULT(LN(RIGHT(SMALL(B2:E23+ROW(1:22)*1000,ROW(1:22)*4-{2,1}),2)),{1;1}))/2,A2:A23),22-RIGHT(TEXT(LARGE(RIGHT(SMALL(B2:E23+ROW(1:22)*1000,ROW(1:22)*4-2)*SMALL(B2:E23+ROW(1:22)*1000,ROW(1:22)*4-1),3)+(22-ROW(1:22))*0.01,ROW()-1),".00"),2),{2,1})

复制代码

kuangben8 · 发表于 2013-11-3 14:51

本帖最后由 kuangben8 于 2013-11-15 17:17 编辑

含=号：227字符。不完全符合题意的！有个关键的技术难点不知道怎么突破！先交答案，然后学习。J2:K23输入多单元数组公式

=IF({1,0},INDIRECT("A"&RIGHT(INT(LARGE(10^MMULT(LOG10(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),))),{1;-1;-1})/2%%+ROW(2:23),ROW(1:22))),2)),LARGE(EXP(MMULT(LN(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),))),{1;-1;-1}))/2,ROW(1:22)))

复制代码

今天发现了一个可以实现要求排序的方法，但是公式好长。。。。。。。。。。。。。。。。。含=号：333字符。

=IF({1,0},OFFSET(A1,MOD(SMALL(MMULT(N(TRANSPOSE(INT(10^MMULT(LOG10(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),))),{1;-1;-1})))>INT(10^MMULT(LOG10(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),))),{1;-1;-1}))),ROW(1:22)^0)*100+ROW(1:22),ROW(1:22)),100),),LARGE(EXP(MMULT(LN(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),))),{1;-1;-1}))/2,ROW(1:22)))

复制代码

含=号，321字符，也许我需要换个什么。。。。

=IF({1,0},OFFSET(A1,MOD(SMALL(MMULT(N(TRANSPOSE(2^MMULT(LOG(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),)),2),{1;-1;-1}))>2^MMULT(LOG(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),)),2),{1;-1;-1})),ROW(1:22)^0)*100+ROW(1:22),ROW(1:22)),100),),LARGE(EXP(MMULT(LN(SUBTOTAL({6,4,5},OFFSET(B1:E1,ROW(1:22),))),{1;-1;-1}))/2,ROW(1:22)))

复制代码

cleverzhzhf · 发表于 2013-11-4 09:50

本帖最后由 cleverzhzhf 于 2013-11-4 09:52 编辑

总算碰到一道会做的了，解答过程就是一部人类进化史呀：
第一版，470字符，就是按照正常思路，一步步的凑出来的：

=IF(COLUMN()=10,INDEX(A2:A23,MATCH(LARGE((SMALL(B2:E23+ROW(2:23)*100,ROW(2:23)*4-6)-ROW(2:23)*100)*(SMALL(B2:E23+ROW(2:23)*100,ROW(2:23)*4-5)-ROW(2:23)*100)/2+1%/ROW(2:23),ROW()-1),(SMALL(B2:E23+ROW(2:23)*100,ROW(2:23)*4-6)-ROW(2:23)*100)*(SMALL(B2:E23+ROW(2:23)*100,ROW(2:23)*4-5)-ROW(2:23)*100)/2+1%/ROW(2:23),)),ROUND(LARGE((SMALL(B2:E23+ROW(2:23)*100,ROW(2:23)*4-6)-ROW(2:23)*100)*(SMALL(B2:E23+ROW(2:23)*100,ROW(2:23)*4-5)-ROW(2:23)*100)/2+1%/ROW(2:23),ROW()-1),1))

复制代码

第二版，346字符，用数据扩大倍数加行号的数字匹配大小，之后用Right取得行号：

=IF(COLUMN()=10,INDEX(A2:A23,23-RIGHT(LARGE((SMALL(B2:E23+ROW(2:23)*100,ROW(2:23)*4-6)-ROW(2:23)*100)*(SMALL(B2:E23+ROW(2:23)*100,ROW(2:23)*4-5)-ROW(2:23)*100)*500+24-ROW(2:23),ROW()-1),2)),ROUND(LARGE((SMALL(B2:E23+ROW(2:23)*100,ROW(2:23)*4-6)-ROW(2:23)*100)*(SMALL(B2:E23+ROW(2:23)*100,ROW(2:23)*4-5)-ROW(2:23)*100)/2+1%/ROW(2:23),ROW()-1),1))

复制代码

第三版，299字符，源数据缩小万倍加行号的和相乘，再提取小数最尾4位，同样得到面积大小。同时缩减了部分可以省略的2:23：

=IF(COLUMN()=10,INDEX(A2:A23,99-RIGHT(LARGE(RIGHT(SMALL(B2:E23%%+ROW(2:23),ROW(2:23)*4-6)*SMALL(B2:E23%%+ROW(2:23),ROW(2:23)*4-5)*10^8,4)/1%-ROW(2:23),ROW()-1),2)),INT(LARGE(RIGHT(SMALL(B2:E23%%+ROW(2:23),ROW(2:23)*4-6)*SMALL(B2:E23%%+ROW(2:23),ROW(2:23)*4-5)*10^8,4)/1%-ROW(2:23),ROW()-1)/100+1)/2)

复制代码

先捞一分，以后再想想怎样可以把那部分重复的，缩减掉。

袁勇 · 发表于 2013-11-5 14:20

本帖最后由袁勇于 2013-11-5 17:24 编辑

J2:K23区域数组：
=CHOOSE(COLUMN(A1:B1),INDEX(A1:A23,RIGHT(LARGE(MOD(SMALL(ROW(1:22)/1%+B2:E23,ROW(1:22)*4-1),100)*MOD(SMALL(ROW(1:22)/1%+B2:E23,ROW(1:22)*4-2),100)*10^9+(24-ROW(2:23))*10000+ROW(2:23),ROW(1:22)),2)),LARGE(MOD(SMALL(ROW(1:22)/1%+B2:E23,ROW(1:22)*4-1),100)*MOD(SMALL(ROW(1:22)/1%+B2:E23,ROW(1:22)*4-2),100),ROW(1:22))/2)
分开写：
J2:J23区域数组：
=INDEX(A1:A23,RIGHT(LARGE(MOD(SMALL(ROW(1:22)/1%+B2:E23,ROW(1:22)*4-1),100)*MOD(SMALL(ROW(1:22)/1%+B2:E23,ROW(1:22)*4-2),100)*10^9+(24-ROW(2:23))*10000+ROW(2:23),ROW(1:22)),2))

K2:K23区域数组：
LARGE(MOD(SMALL(ROW(1:22)/1%+B2:E23,ROW(1:22)*4-1),100)*MOD(SMALL(ROW(1:22)/1%+B2:E23,ROW(1:22)*4-2),100),ROW(1:22))/2

476363814 · 发表于 2013-11-5 14:24

本帖最后由 476363814 于 2013-11-5 14:47 编辑

294个字符：

=IF({1,0},INDEX(A2:A23,LEFT(RIGHT(LARGE(RIGHT(SMALL(ROW(1:22)/1%%%+B2:E23,ROW(1:22)*4-2)*SMALL(ROW(1:22)/1%%%+B2:E23,ROW(1:22)*4-1),4)/1%%-99*ROW(1:22)/100+0.001,ROW(1:22)),3),2)),LARGE(RIGHT(SMALL(ROW(1:22)/1%%%+B2:E23,ROW(1:22)*4-2)*SMALL(ROW(1:22)/1%%%+B2:E23,ROW(1:22)*4-1),4)/2,ROW(1:22)))

复制代码

补充内容 (2013-11-24 19:27):
其实有想到用：LOG10 ab=LOG10 a+LOG10 b公式，但是不知道怎么去简化了。。。我觉得LOG10会简单很多吧，

		自动登录	找回密码
密码			免费注册

[Excel 函数与公式] [第100期]按三角形面积的大小排列[已总结]

本帖子中包含更多资源

评分

点评

评分

评分

评分

本帖子中包含更多资源

点评

评分

点评

评分

点评

评分

点评

评分

本帖子中包含更多资源

评分

94

评分