怎样用VBA将A列不重复的数据到粘贴到C列，并将相同A列数据相应的B列数据之和对应到D列

zhangred

怎样用VBA将A列不重复的数据到粘贴到C列，并将相同A列数据相应的B列数据之和对应到D列？

谁能解读一下下面的代码吗？？？


'代码如下，我假设你有1000个不重复的项，当然如果更多，可更改数组定义。

Sub 统计()
Dim I, J, N, lngR As Long
Dim A(1000) As String
Dim B(1000) As Long
Dim Flag As Boolean

lngR = Range("A65536").End(xlUp).Row
A(0) = Cells(1, 1)
B(0) = Cells(1, 2)
N = 0
For I = 2 To lngR
Flag = False
For J = 0 To N
    If Cells(I, 1) = A(J) Then
        B(J) = B(J) + Cells(I, 2)
        Flag = True
    End If
Next J
    If Flag = False Then
        N = N + 1
        A(N) = Cells(I, 1)
        B(N) = Cells(I, 2)
    End If
Next I

For I = 0 To N
    Cells(I + 1, 3) = A(I)
    Cells(I + 1, 4) = B(I)
Next I
End Sub

李兴德

非V不行? 函数也方便的.

smhf_6

Sub xx()
    Dim dc As Object
    Dim arr, ir, i
    Set dc = CreateObject("Scripting.Dictionary")
    ir = Range("a1").End(xlDown).Row
    arr = Range("a1:b" & ir)
    For i = 1 To ir
    dc(arr(i, 1)) = dc(arr(i, 1)) + arr(i, 2)
    Next
    Cells(1, 3).Resize(dc.Count, 1) = Application.WorksheetFunction.Transpose(dc.keys)
    Cells(1, 4).Resize(dc.Count, 1) = Application.WorksheetFunction.Transpose(dc.items)
    Set dc = Nothing
End Sub