ExcelHome技术论坛

 找回密码
 免费注册

QQ登录

只需一步,快速开始

快捷登录

搜索
EH技术汇-专业的职场技能充电站 妙哉!函数段子手趣味讲函数 Excel服务器-会Excel,做管理系统 Excel Home精品图文教程库
HR薪酬管理数字化实战 Excel 2021函数公式学习大典 Excel数据透视表实战秘技 打造核心竞争力的职场宝典
300集Office 2010微视频教程 数据工作者的案头书 免费直播课集锦 ExcelHome出品 - VBA代码宝免费下载
用ChatGPT与VBA一键搞定Excel WPS表格从入门到精通 Excel VBA经典代码实践指南
查看: 1399|回复: 13

[分享] REDUCE函数双循环扩展和堆积套路

[复制链接]

TA的精华主题

TA的得分主题

发表于 2023-11-1 16:32 | 显示全部楼层 |阅读模式
[广告] VBA代码宝 - VBA编程加强工具 · VBA代码随查随用  · 内置多项VBA编程加强工具       ★ 免费下载 ★      ★使用手册
本帖已被收录到知识树中,索引项:LAMBDA
本帖最后由 shaowu459 于 2023-11-1 16:55 编辑

在有些涉及结构转换的题目中,经常需要将前一步的数组进行扩展,比如在查找上下级的时候,每一步都要查找当前人员的下级人员堆积在数组右侧。例如,张三有ABC三个下级,那么就张三这一个人就需要扩展成三行:
图片.png

往下循环,A可能还有A1和A2两个下属,B有B1一个下属,就需要继续扩展:
图片.png
这种情况下,需要遍历张三的下属ABC,将每个人的下属查到后堆积在数组右侧,结果数组的行数和列数都可能会增加。


这种情况下,使用REDUCE函数双循环可以轻松解决行列扩展问题。本帖以生成多列数据组合为例(非字符串解决方案),介绍双循环的方法。更多的例题,请在我的主题帖里查找,例如BOM展开相关的、上下级相关的。

REDUCE函数双循环示例.rar

11.73 KB, 下载次数: 117

评分

10

查看全部评分

TA的精华主题

TA的得分主题

 楼主| 发表于 2023-11-1 16:34 | 显示全部楼层
先看题目要求,左侧是不同系列对应的内容,要求生成右侧的结果,列举每个系列里的内容生成的所有组合。


图片.png

TA的精华主题

TA的得分主题

 楼主| 发表于 2023-11-1 16:45 | 显示全部楼层
本帖最后由 shaowu459 于 2023-11-1 16:49 编辑

接下来,先在辅助单元格区域介绍一下主要思路。

第一步,给REDUCE函数的初始值x赋值为第一个系列所有元素。
图片.png

第二步,要循环B~E列的每一列,以下以循环B列为例。提取B列所有非空元素:
图片.png

第三步,提取x中的每一行,与B列所有元素横向堆积:
图片.png
图片.png


使用IFNA函数屏蔽堆积产生的错误值,将#N/A填充为x中的行。
图片.png

上述遍历x中的每一行,就需要使用REDUCE函数逐行提取遍历,也就是双层REDUCE函数循环的内层REDUCE函数。循环一次就将已有结果和当前循环生成的结果用VSTACK函数纵向堆积起来。

第四步,循环完B列后,继续循环C列、D列、E列,内层REDUCE函数分别提取x中的每一行与后续系列元素堆积。循环完毕,则返回所有序列元素的全部组合。

TA的精华主题

TA的得分主题

 楼主| 发表于 2023-11-1 16:50 | 显示全部楼层
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助
解决问题的双循环参考公式如下:
  1. =VSTACK(A1:E1,REDUCE(A2:A3,B2:E2,LAMBDA(X,Y,DROP(REDUCE(0,SEQUENCE(ROWS(X)),LAMBDA(S,C,LET(Z,INDEX(X,C,),VSTACK(S,IFNA(HSTACK(Z,TOCOL(OFFSET(Y,,,7),1)),Z))))),1))))
复制代码
图片.png


TA的精华主题

TA的得分主题

 楼主| 发表于 2023-11-1 16:55 | 显示全部楼层
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助
上述公式简要说明如下:

=VSTACK(
    A1:E1,    堆积标题行
    REDUCE(   最外层循环,循环值是B~E列
        A2:A3,    外层循环x初始值设定为A系列元素
        B2:E2,    外层循环B~E列
        LAMBDA(X, Y,
            DROP(
                REDUCE(
                    0,
                    SEQUENCE(ROWS(X)),    生成从1到x行数的序列,逐行提取
                    LAMBDA(S, C,
                        LET(
                            Z, INDEX(X, C, ),    逐行提取出x的每一行
                            VSTACK(
                                S,      内层循环的x
                                IFNA(
                                    HSTACK(
                                        Z,     横向堆积x中的当前行和外层循环的系列元素
                                        TOCOL(OFFSET(Y, , , 7), 1)     获取外层循环的那一列非空值
                                    ),
                                    Z   横向堆积错误值屏蔽为x中的当前行
                                )
                            )
                        )
                    )
                ),
                1
            )
        )
    )
)



TA的精华主题

TA的得分主题

发表于 2023-11-1 19:20 | 显示全部楼层

TA的精华主题

TA的得分主题

发表于 2023-11-1 20:50 | 显示全部楼层

TA的精华主题

TA的得分主题

发表于 2023-11-1 20:54 | 显示全部楼层

TA的精华主题

TA的得分主题

发表于 2023-11-2 10:50 | 显示全部楼层

TA的精华主题

TA的得分主题

发表于 2023-11-2 12:48 | 显示全部楼层
[广告] VBA代码宝 - VBA编程加强工具 · VBA代码随查随用  · 内置多项VBA编程加强工具       ★ 免费下载 ★      ★使用手册
学习了,感谢超人老师!
您需要登录后才可以回帖 登录 | 免费注册

本版积分规则

手机版|关于我们|联系我们|ExcelHome

GMT+8, 2024-6-19 08:25 , Processed in 0.048661 second(s), 12 queries , Gzip On, MemCache On.

Powered by Discuz! X3.4

© 1999-2023 Wooffice Inc.

沪公网安备 31011702000001号 沪ICP备11019229号-2

本论坛言论纯属发表者个人意见,任何违反国家相关法律的言论,本站将协助国家相关部门追究发言者责任!     本站特聘法律顾问:李志群律师

快速回复 返回顶部 返回列表