197页实例彻底看崩溃，请高手点拨一下！谢谢！

何时再见你

Sub HzWb()
    Dim bt As Range, r As Long, c As Long
    r = 1    '1 是表头的行数
    c = 8    '8 是表头的列数
    Range(Cells(r + 1, "A"), Cells(65536, c)).ClearContents    ' 清除汇总表中原表数据
    Application.ScreenUpdating = False
    Dim FileName As String, wb As Workbook, Erow As Long, fn As String, arr As Variant
    FileName = Dir(ThisWorkbook.Path & "\*.xls")
    Do While FileName <> ""
        If FileName <> ThisWorkbook.Name Then    ' 判断文件是否是本工作簿
            Erow = Range("A1").CurrentRegion.Rows.Count + 1    ' 取得汇总表中第一条空行行号
            fn = ThisWorkbook.Path & "\" & FileName
            Set wb = GetObject(fn)    ' 将fn 代表的工作簿对象赋给变量
            Set sht = wb.Worksheets(1)    ' 汇总的是第1 张工作表
            ' 将数据表中的记录保存在arr 数组里
            arr = sht.Range(sht.Cells(r + 1, "A"), sht.Cells(65536, "B").End(xlUp).Offset(0, 8))
            ' 将数组arr 中的数据写入工作表
            Cells(Erow, "A").Resize(UBound(arr, 1), UBound(arr, 2)) = arr
            wb.Close False
        End If
        FileName = Dir    ' 用Dir 函数取得其他文件名，并赋给变量
    Loop
    Application.ScreenUpdating = True
End Sub

请高手帮我详细解释一下，我刚刚读到这页，新手一只，彻底崩溃，我请教如下句法：
1、 FileName = Dir(ThisWorkbook.Path & "\*.xls") 这句里后面那个*.xlls究竟代表把什么赋值给了FileName变量？？？Dir这个命令返回的是什么，我用msgbox Dir（...）为什么看到的是空白？
2、Do循环结尾处的 FileName=Dir是什么意思，是不是跟前面我问题1里面的*有搭配使用的关系？是不是可以指示FileName挨个换文件并取得路径？
3、将数据写入工作表的那句 Resize(UBound(arr, 1), UBound(arr, 2)， 这里面Ubound(arr,1)代表什么意思？

谢谢！

时光鸟

1、查找当前工作蔳所在目录下的第一个文件扩展名为.xls的文件名，并把该名称连带扩展名一起赋值给FileaName;
2、如果查找到的.xls不符合do循环的条件，就继续找下一个，并赋值给FileaName;
3、关于Ubound(arr,1)，这是个多维数组问题，具体是取得arr这个多维数组中第一维的最大可用下标。

hehex

问题1,2 查帮助是最好的，以下是相关一些解释，来自vba 帮助
Dir 函数
   
返回一个 String，用以表示一个文件名、目录名或文件夹名称，它必须与指定的模式或文件属性、或磁盘卷标相匹配。
语法
Dir[(pathname[, attributes])]
在 Microsoft Windows 中， Dir 支持多字符 (*) 和单字符 (?) 的通配符来指定多重文件。
在第一次调用 Dir 函数时，必须指定 pathname，否则会产生错误。如果也指定了文件属性，那么就必须包括 pathname。
Dir 会返回匹配 pathname 的第一个文件名。若想得到其它匹配 pathname 的文件名，再一次调用 Dir，且不要使用参数。如果已没有合乎条件的文件，则 Dir 会返回一个零长度字符串 ("")。一旦返回值为零长度字符串，并要再次调用 Dir 时，就必须指定 pathname，否则会产生错误。

第3个问题，Ubound(arr,1) 返回的是二维数组arr的第一列最上限的数组下标，比如某二维数组从arr(1,1)-arr(1,10)，arr(1,2)-arr(3,2),UBound(arr,1) 则返回10，第一列的数组下标上限。

何时再见你

谢谢二位，了解了！Ubund我记得我看到过，以为在后面部分，翻半天书没找到，今天找到了，在第65页。非常感谢！这程序简直太复杂了，难以想象人类能搞出这么复杂的逻辑东西。