关于Recordset的GetRows的用法问题

zouyuejian

我的要求是在plan表的第二行开始获得三条记录放到数组a里。当运行到a = rec.GetRows(2, 3)时出错，
怎么回事呢？如何改正呢？代码和附件在下面。被GetRows的用法搞晕了。
——————
Public Sub TestClick1()
    Dim Con As ADODB.Connection
    Dim rec As ADODB.Recordset
    Dim sConStr As String, a
    '使用microsoft.ace.oledb.12.0可以链接accdb和mdb文件
    'microsoft.jet.oledb.4.0不支持链接accdb
    sConStr = "Provider=microsoft.ace.oledb.12.0;" _
            & "Persist Security Info=False;" _
            & "Data Source=" + ThisWorkbook.Path + "\ADOTest.mdb"
    Set Con = New ADODB.Connection
    Con.Open sConStr
    Set rec = New ADODB.Recordset
    rec.CursorLocation = adUseClient
    rec.Open "select * from plan", Con, adOpenDynamic, adLockPessimistic
    rec.MoveFirst
    a = rec.GetRows(2, 3)
    rec.Close: Con.Close
    Set rec = Nothing: Set Con = Nothing
End Sub

zouyuejian

自己顶自己，盼望高手热心人

zhw79

Public Sub TestClick1()
    Dim Con As ADODB.Connection
    Dim rec As ADODB.Recordset
    Dim sConStr As String
    Dim a '()
    '使用microsoft.ace.oledb.12.0可以链接accdb和mdb文件
    'microsoft.jet.oledb.4.0并不支持链接accdb
    sConStr = "Provider=microsoft.jet.oledb.4.0;" _
            & "Persist Security Info=False;" _
            & "Data Source=" + ThisWorkbook.Path + "\ADOTest.mdb"
    Set Con = New ADODB.Connection
    Con.Open sConStr
    Set rec = New ADODB.Recordset
    rec.CursorLocation = adUseClient
    rec.Open "select * from plan", Con, adOpenDynamic, adLockPessimistic
    Range("a1").CopyFromRecordset rec
    rec.Move 1, 1 '记录指针移动至第2行
    a = rec.GetRows(3, adBookmarkCurrent) '获取当前记录行起3条记录
    rec.Close: Con.Close
    Set rec = Nothing: Set Con = Nothing
End Sub

[ 本帖最后由 zhw79 于 2011-6-12 18:08 编辑 ]

zhw79

GetRows方法传回一个二维的阵列变数，每一行对应Recordset中的一笔记录，且每一列对应到记录中的栏位。此方法的语法如下： 　　varArray = rs.GetRows([Rows], [Start], [Fields]) 　　Rows是要读取记录的数量；如果想要取得Recordset所有记录，可用-1或省略此参数。Start 是指出第一个被读取记录的书签；也可以是下列列举常数中的一个：0-adBookmarkCurrent（目前记录）、1-adBookmarkFirst（第一笔记录）、或2-adBookmarkLast（最后记录）。

http://baike.baidu.com/view/970915.htm

zouyuejian

谢谢。满足要求，运行正常。又学了一招。
不知是我没有理解帮助文件还是别的原因。帮助文件貌似不是这样描述GetRows的用法

zouyuejian

我明白了。谢谢热心的zhw79 。
我把代码改为：
.......
dim bm
....
rec.Move 1, 1                      '记录指针设置在第二条记录
    bm = rec.Bookmark
    a = rec.GetRows(3, bm)    '从第二条记录开始获得三条记录
........
取得同样的效果。

蓝桥玄霜

1. Sub TestClick1()
   
2.     Dim cnn, mydata$, mytable$, Sql$, Arr, Brr, i&, j&
   
3.     mydata = ThisWorkbook.Path & "\ADOTest.mdb"
   
4.     mytable = "plan"
   
5.    
   
6.     Set cnn = CreateObject("Adodb.Connection")
   
7.     With cnn
   
8.         .Provider = "microsoft.jet.oledb.4.0"
   
9.         .Open mydata
   
10.     End With
    
11.     Sql = "select * from " & mytable
    
12.     Arr = cnn.Execute(Sql).GetRows
    
13.     ReDim Brr(1 To 3, 0 To 3)
    
14.     For i = 1 To 3
    
15.         For j = 0 To 3
    
16.             Brr(i, j) = Arr(j, i)
    
17.         Next
    
18.     Next
    
19.     [a20].Resize(UBound(Brr), UBound(Brr, 2) + 1) = Brr
    
20.     cnn.Close
    
21.     Set cnn = Nothing
    
22. End Sub
    

复制代码

zhw79

个人感觉“第二行开始获得三条记录”这样一个方法具有很大的不确定性。2~4行究竟本质上和其他行有什么区别！假设对数据库进行过排序，插入，删除记录等操作：操作前的2~4行与操作后的2~4行是完全不一样的结果。

zouyuejian

是的。我后来觉得可能用SQL语句处理会更好一些。但access不支持limite的用法。

yanxuqi

蓝桥玄霜 发表于 2011-6-12 19:20

为什么定义brr是3*3的呢？怎么确定的？