如何删除IE缓存中的文件

91708x

原帖由 secowu 于 2010-8-19 13:44 发表
传不了wmv
看gif

你在C:\Documents and Settings\Administrator\Local Settings\Temporary Internet Files\里面找个文件试一下就知道不行了

91708x

原帖由 kevinchengcw 于 2010-8-19 13:48 发表
使用中的文件是删除不了的

你在命令行下试一下/c后面的内容就知道了，会提示访问被拒绝，然后跳到下一个文件继续执行了

应该不是正在使用的问题，我是用VBA调用的，窗口没打开
Open "GET", "http://*************.aspx", False
我就是要把该网站产生的cookie清除掉，下次再调用的时候，网站数据就刷新了，没清除掉的话下载的数据就是上次调用的

[ 本帖最后由 91708x 于 2010-8-19 14:01 编辑 ]

kevinchengcw

使用并不一定是打开，有时仅仅是关连到某个程序上了，如果重启后还不能删除才能说明问题，不过dos命令都删除不掉的文件一定有特殊原因，我基本都是用这种方式来删除临时文件的，那个批处理就行了

ideal77

复制个别人的代码,(记不清哪来的了,原作者末怪啊.)可以删除所有的cookie信息,供参考:(调试通过)
Option Explicit
Private Const ERROR_CACHE_FIND_FAIL As Long = 0
Private Const ERROR_CACHE_FIND_SUCCESS As Long = 1
Private Const ERROR_FILE_NOT_FOUND As Long = 2
Private Const ERROR_ACCESS_DENIED As Long = 5
Private Const ERROR_INSUFFICIENT_BUFFER As Long = 122
Private Const MAX_PATH As Long = 260
Private Const MAX_CACHE_ENTRY_INFO_SIZE As Long = 4096
Private Const LMEM_FIXED As Long = &H0
Private Const LMEM_ZEROINIT As Long = &H40
Private Const LPTR As Long = (LMEM_FIXED Or LMEM_ZEROINIT)
Private Const NORMAL_CACHE_ENTRY As Long = &H1
Private Const EDITED_CACHE_ENTRY As Long = &H8
Private Const TRACK_OFFLINE_CACHE_ENTRY As Long = &H10
Private Const TRACK_ONLINE_CACHE_ENTRY As Long = &H20
Private Const STICKY_CACHE_ENTRY As Long = &H40
Private Const SPARSE_CACHE_ENTRY As Long = &H10000
Private Const COOKIE_CACHE_ENTRY As Long = &H100000
Private Const URLHISTORY_CACHE_ENTRY As Long = &H200000
Private Const URLCACHE_FIND_DEFAULT_FILTER As Long = NORMAL_CACHE_ENTRY Or _
                                                     COOKIE_CACHE_ENTRY Or _
                                                     URLHISTORY_CACHE_ENTRY Or _
                                                     TRACK_OFFLINE_CACHE_ENTRY Or _
                                                     TRACK_ONLINE_CACHE_ENTRY Or _
                                                     STICKY_CACHE_ENTRY
Private Type FILETIME
    dwLowDateTime As Long
    dwHighDateTime As Long
End Type

Private Type INTERNET_CACHE_ENTRY_INFO
    dwStructSize As Long
    lpszSourceUrlName As Long
    lpszLocalFileName As Long
    CacheEntryType   As Long
    dwUseCount As Long
    dwHitRate As Long
    dwSizeLow As Long
    dwSizeHigh As Long
    LastModifiedTime As FILETIME
    ExpireTime As FILETIME
    LastAccessTime As FILETIME
    LastSyncTime As FILETIME
    lpHeaderInfo As Long
    dwHeaderInfoSize As Long
    lpszFileExtension As Long
    dwExemptDelta   As Long
End Type

Private Declare Function FindFirstUrlCacheEntry Lib "wininet" _
    Alias "FindFirstUrlCacheEntryA" _
   (ByVal lpszUrlSearchPattern As String, _
    lpFirstCacheEntryInfo As Any, _
    lpdwFirstCacheEntryInfoBufferSize As Long) As Long

Private Declare Function FindNextUrlCacheEntry Lib "wininet" _
    Alias "FindNextUrlCacheEntryA" _
   (ByVal hEnumHandle As Long, _
    lpNextCacheEntryInfo As Any, _
    lpdwNextCacheEntryInfoBufferSize As Long) As Long

Private Declare Function FindCloseUrlCache Lib "wininet" _
    (ByVal hEnumHandle As Long) As Long

Private Declare Function DeleteUrlCacheEntry Lib "wininet" _
    Alias "DeleteUrlCacheEntryA" _
   (ByVal lpszUrlName As String) As Long
  
Private Declare Sub CopyMemory Lib "kernel32" _
    Alias "RtlMoveMemory" _
    (pDest As Any, _
     pSource As Any, _
     ByVal dwLength As Long)

Private Declare Function lstrcpyA Lib "kernel32" _
   (ByVal RetVal As String, ByVal Ptr As Long) As Long
                       
Private Declare Function lstrlenA Lib "kernel32" _
   (ByVal Ptr As Any) As Long

Private Declare Function LocalAlloc Lib "kernel32" _
    (ByVal uFlags As Long, _
     ByVal uBytes As Long) As Long
   
Private Declare Function LocalFree Lib "kernel32" _
    (ByVal hMem As Long) As Long
      



Public Sub DeleteCacheURLList()
   
    Dim icei As INTERNET_CACHE_ENTRY_INFO
    Dim hFile As Long
    Dim cachefile As String
    Dim posUrl As Long
    Dim posEnd As Long
    Dim dwBuffer As Long
    Dim pntrICE As Long


    hFile = FindFirstUrlCacheEntry(0&, ByVal 0, dwBuffer)

    If (hFile = ERROR_CACHE_FIND_FAIL) And _
       (Err.LastDllError = ERROR_INSUFFICIENT_BUFFER) Then

       pntrICE = LocalAlloc(LMEM_FIXED, dwBuffer)

       If pntrICE <> 0 Then

          CopyMemory ByVal pntrICE, dwBuffer, 4

          hFile = FindFirstUrlCacheEntry(vbNullString, _
                                         ByVal pntrICE, _
                                         dwBuffer)
     

          If hFile <> ERROR_CACHE_FIND_FAIL Then

             Do
           
                CopyMemory icei, ByVal pntrICE, Len(icei)
         

                If (icei.CacheEntryType And _
                    NORMAL_CACHE_ENTRY) = NORMAL_CACHE_ENTRY Then

                   cachefile = GetStrFromPtrA(icei.lpszSourceUrlName)
                   Call DeleteUrlCacheEntry(cachefile)

                End If
              
                Call LocalFree(pntrICE)
              
                dwBuffer = 0
                Call FindNextUrlCacheEntry(hFile, ByVal 0, dwBuffer)
              
               'allocate and assign the memory to the pointer
                pntrICE = LocalAlloc(LMEM_FIXED, dwBuffer)
                CopyMemory ByVal pntrICE, dwBuffer, 4
              
                DoEvents
              
             Loop While FindNextUrlCacheEntry(hFile, ByVal pntrICE, dwBuffer)

          End If 'hFile
        
       End If 'pntrICE
  
    End If 'hFile
  
    Call LocalFree(pntrICE)
    Call FindCloseUrlCache(hFile)
  
End Sub


Private Function GetStrFromPtrA(ByVal lpszA As Long) As String

    GetStrFromPtrA = String$(lstrlenA(ByVal lpszA), 0)
    Call lstrcpyA(ByVal GetStrFromPtrA, ByVal lpszA)
  
End Function

[ 本帖最后由 ideal77 于 2010-8-19 14:44 编辑 ]

91708x

谢谢楼上，学习中

引子玄

我的办法是点：IE浏览器的“安全”——“删除历史记录”
应该来说，是最正宗的办法，来自IE鼻祖自带的系统设置。

VBA万岁

ideal77 发表于 2010-8-19 14:37
复制个别人的代码,(记不清哪来的了,原作者末怪啊.)可以删除所有的cookie信息,供参考:(调试通过)
Option Ex ...

学习了，多谢分享！

huangzhijie

清空ie缓存，没那么容易，14楼的代码，膜拜