【学习并记录010】建立某文件夹下的动态工作簿目录

lgcmeli

问：建立某文件夹下的动态工作簿目录，文件夹的路径改变，超链仍然有效？

答：

在http://club.excelhome.net/thread-539087-1-1.html 里说到了【学习并记录005】建立工作表目录又一法[定义名称 复制 粘贴]

这里我们也可以借鉴下一点思路

方法一：路径已知，工作簿名已知（见附件中汇总表.XLS里的sheet1工作表）

1，B列从B3开始存放工作簿名，E1存放工作簿所在的路径

2，C3=HYPERLINK("["&$E$1&B3&".xls]",B3)




那么，可否假设路径未知呢，用函数取得当前工作簿即《汇总表.XLS》的路径？（见附件中汇总表.XLS里的sheet2工作表）

方法二：路径未知，用函数取得当前工作簿即《汇总表.XLS》的路径

1，B列从B3开始存放工作簿名

2，E1=LEFT(CELL("filename"),FIND("[",CELL("filename"))-1)，取得路径

3，C3公式没变，仍是=HYPERLINK("["&$E$1&B3&".xls]",B3)


那么，可否假设路径未知、工作簿名也未知呢？

方法三：路径未知、工作簿名也未知，用函数取得当前工作簿即《汇总表.XLS》的路径，用函数取得当前工作簿路径下的文件夹里的工作簿名称？（见附件中汇总表.XLS里的sheet3工作表）

1，定义名称
name =FILES(path&"*.*")&T(NOW())
path =LEFT(CELL("filename"),FIND("[",CELL("filename"))-1)

2，B3=IF(ROW()-2>COUNTA(name),"",HYPERLINK(path&INDEX(name,ROW()-2),INDEX(name,ROW()-2)))



方法四：路径未知、工作簿名也未知，并排除当前工作簿名称（即目录里没有当前工作簿）？（见附件中汇总表.XLS里的sheet4工作表）

1，定义名称

book        =LOOKUP(SMALL(IF(row<>MATCH(Sheet4!name,files,),row),ROW(INDIRECT("1:"&ROWS(row)-1))),row,files)
files        =FILES(path&"*.*")&T(NOW())
names        =GET.WORKBOOK(16)&T(NOW())
path        =LEFT(CELL("filename"),FIND("[",CELL("filename"))-1)
row        =ROW(INDIRECT("1:"&COLUMNS(files)))


2，B3=IF(ROW()-2>COUNTA(book),"",INDEX(book,ROW()-2))

[ 本帖最后由 lgcmeli 于 2010-3-3 15:04 编辑 ]

wangg913

这方面才疏学浅，招数挺高，还没看明白。。

lgcmeli

1，now()是一个易失性函数，随着Excel的一些动作比如编辑单元格等变化，产生当前时间（数值的一种）

2，T()函数对文本返回文本自身，对数值返回空。所以&T(now())相当于&""，只不过这个""会随时变化

3，这样连起来就使得我们得到的工作簿名称是一个可以随着Excel动作（如改变工作表名也是动作）而“实时”变化的工作簿名

wangg913

楼主大人，T(NOW())
啥意思？

lgcmeli

文本公式（计算的结果为文本） 刷新用 =公式&T(NOW())

计算公式（计算的结果为数值） 刷新用 =公式+NOW()*0



上面例子中应用的宏表4.0函数不会自动重新计算，所以需要加这个尾巴实现自动重算。

文本&""并不会改变文本的内容。

数值+0或者数值*1都不会改变数值的大小。

所以有：

=公式&T(now())

=公式+NOW()*0      （或者公式+rand()*0、或者公式*Now()^0、或者公式*Rand()^0）

wangg913

不错不错，不过还没看懂。。。

lgcmeli

方法四：路径未知、工作簿名也未知，并排除当前工作簿名称（即目录里没有当前工作簿）？（见附件中汇总表.XLS里的sheet4工作表）

1，定义名称

book        =LOOKUP(SMALL(IF(row<>MATCH(Sheet4!name,files,),row),ROW(INDIRECT("1:"&ROWS(row)-1))),row,files)
files        =FILES(path&"*.*")&T(NOW())
names        =GET.WORKBOOK(16)&T(NOW())
path        =LEFT(CELL("filename"),FIND("[",CELL("filename"))-1)
row        =ROW(INDIRECT("1:"&COLUMNS(files)))


2，B3=IF(ROW()-2>COUNTA(book),"",INDEX(book,ROW()-2))

zyh196712

学习了，慢慢看！

飞云楼主

Thanks for sharing

alwstr

收藏了 慢慢研究

辛苦了