如何删除图表中是0的值和它所对应的类别名称

fasdfasdfafd

附件中已把是0的值屏蔽掉了，能否同时屏蔽0值所对应的类别名称，例如：在图表中屏蔽掉 其他日常影响、日常冲突等类别名称，不用宏，我看不懂！！！

snood

自动筛选大于0

watership

single_star达人已经给出了解决的办法，但是我还没有理解，整个公式是怎么出来的，希望有人能指点。
附件是完成了的表格，部分公司不是很清楚。

原始标题数列list0和原始资料数列num0我明白
list0=Sheet1!$A$2:$A$9
num0=Sheet1!$B$2:$B$9

下面是存在疑问的公式,sn0,sn1,sn这几个数列是怎么得来的，公式没看明白。另外怎么在excel中显示出list0,sn0等定义了名称数列的值？
not_zero----资料非零次数
not_zero=COUNTIF(num0,">0")
资料非零次数not_zero是指num0中非0个数4么？

sn0----依标题数列列数N产生1,2,3~N的数列
sn0=ROW(list0)-ROW(OFFSET(list0,0,0,1,1))+1
这里的ROW(list0)已经是行号了，数列是{1；2；3；4；5；6；7；8}，ROW(OFFSET(list0,0,0,1,1))又是什么，为什么要这么计算

sn1---依非零次数n产生1,2,3~n的数列
sn1=ROW(OFFSET(list0,0,0,not_zero,1))-ROW(OFFSET(list0,0,0,1,1))+1

sn2---当原始资料num0为数字并且>0时赋予sn0值,否则赋予成Rows(num0)+1=N+1
sn2=IF(ISNUMBER(num0)*(num0>0),sn0,ROWS(num0)+1)
sn3---符合要求资料所在次序:依sn2数列依序找出第1小至第n小的数列
sn3=SMALL(sn2,sn1)

list1---筛选后标题数列:依符合要求资料所在次序(sn3)求出新的标题列
list1=LOOKUP(sn3,sn0,list0)

num1---筛选后资料数列:依符合要求资料所在次序(sn3)求出新的资料列
num1=LOOKUP(sn3,sn0,num0)

[ 本帖最后由 watership 于 2009-10-14 10:12 编辑 ]

fasdfasdfafd

没有想到更好的办法了，先凑合者用吧！！！！

single_star

用自定义名称重新赋予对应数列资料...
(2012/10/20修改简化定义名称数)

watership

谢谢sing_star老师，基本上能满足我的需求了。
用自定义名称重新赋予对应数列资料...，这个是什么意思，能不能简要说明下，明白下制作的过程。

single_star

副档使用名称定义公式作为图表新的数据源(类别:list1,值:num1)
**************************************************************************************
首先算出原始资料中非零的笔数(副档中为not_zero)后产生1~n的的数列(副档中为sn1),
然后依此产生符合要求资料的所在序列序(sn3),
最后依此序列序用lookup求出新的对应数列资料(list1,num1)并作为图表数据源参照

以上使用名称自定义公式做为动态图表的数据源用法也适用于自动排序,筛选
等特殊要求的动态图表用

[ 本帖最后由 single_star 于 2009-9-29 17:25 编辑 ]

fasdfasdfafd

还是看不懂！！！！！！！！！！1

watership

我也没看懂，是只用“=SERIES(,发布延迟统计表.xls!list1,发布延迟统计表.xls!num1,1)”这一行公式就搞定了，还是在其他地方有隐藏的中间表啥的？？

tjfx

呵呵，高手们想得太复杂，一般人哪看得懂，我的简单办法：
1、设置辅助数据，根据值判断 分类名称，if值＝0，则 分类名称＝“”
2、用辅助数据做饼图
3、饼图的数据标签格式设置为 0%;;;     ，会自动隐藏0的数据标签
效果图、源文件如下：