VBA常用技巧代码解析

hupo0823

袁老师端午节快乐！

云淡天高

谢谢，祝您端午节快乐

zhjl230

非常感谢~~找了1天多，你的这个教程最仔细了~~不过，让我也鼓捣了半天才全部下完~~5555555~~~

haowan888

感谢！！好人不常有啊

ortega123

太感谢了。太难得拉。感激得可以为你跳脱衣舞！！谢谢

yvhgydn

正在打印WORD版 1-8部分，感谢袁祝平老师

trydui

增加了Word文档~找起来更方便了~
再支持一下~

yuanzhuping

技巧165         判断工作表是否为空表
       VBA中没有专门的属性或函数可以判断工作表是否为空白工作表，可以使用自定义函数返回指定工作表是否为空工作表，如下面的代码所示。

1. #001  Function IsBlankSht(Sh As Variant) As Boolean
   
2. #002      If TypeName(Sh) = "String" Then Set Sh = Worksheets(Sh)
   
3. #003      If Application.CountA(Sh.UsedRange.Cells) = 0 Then
   
4. #004          IsBlankSht = True
   
5. #005      End If
   
6. #006  End Function

复制代码

代码解析：
       自定义IsBlankSht函数包含一个Variant变量类型的参数，代表工作表名称或者对象名称。如果指定的工作表为空工作表，则该函数返回True。
       第2行代码使用TypeName函数判断参数Sh是否为字符串类型（“String”），如果是字符串，则将以该字符串作为名称的工作表赋值给变量Sh。
       第3行代码通过工作表函数CountA统计工作表已使用区域的非空单元格个数，如果统计结果为0，则表示该工作表为空工作表。
       现在就可以像使用VBA函数一样使用自定义的IsBlankSht函数，如下面的代码所示。

1. #001  Sub DelBlankSht()
   
2. #002      Dim Sh As Worksheet
   
3. #003      Application.DisplayAlerts = False
   
4. #004      For Each Sh In ThisWorkbook.Sheets
   
5. #005          If IsBlankSht(Sh) Then Sh.Delete
   
6. #006      Next
   
7. #007      Application.DisplayAlerts = True
   
8. #008  End Sub

复制代码

代码解析：
       使用自定义的IsBlankSht函数删除工作簿中所有空工作表。
       第3行代码将Application对象的DisplayAlerts属性设置为False，使删除时不显示系统警告对话框。
       第4行到第6行代码，使用For Each...Next语句遍历所有工作表，使用自定义的IsBlankSht函数判断是否为空表，如果为空表则使用Delete方法删除。
       注意 自定义IsBlankSht函数仅仅判断工作表单元格区域内容是否为空，如果工作表中存在其它对象（如图形对象、数据有效性、单元格批注等），还需要再进一步判断。

zhouagun

好好学习、天天向上

yuanzhuping

技巧166         查找指定工作表
       判断工作簿中是否存在指定名称的工作表，除了使用遍历工作簿中所有工作表的方法外，还可以使用自定义函数，如下面的代码所示。

1. #001  Function ExistSh(Sh As String) As Boolean
   
2. #002      Dim Sht As Object
   
3. #003      On Error Resume Next
   
4. #004      Set Sht = Sheets(Sh)
   
5. #005      If Err.Number = 0 Then ExistSh = True
   
6. #006      Set Sht = Nothing
   
7. #007  End Function

复制代码

代码解析：
       自定义ExistSh函数包含一个String类型的参数，代表需要判断的工作表名称。如果该工作表存在，则返回True。
       第5行代码判断前面的代码是否出错，如果前面的代码存在错误，则表示不存在指定名称的表。
       使用自定义ExistSheet函数判断工作簿中是否存在指定名称的工作表，如下面的代码所示。

1. #001  Sub NotSht()
   
2. #002      Dim Sh As String
   
3. #003      Sh = InputBox("请输入工作表名称：")
   
4. #004      If Len(Sh) > 0 Then
   
5. #005          If Not ExistSh(Sh) Then
   
6. #006              MsgBox "对不起," & Sh & "表不存在!"
   
7. #007          Else
   
8. #008              Sheets(Sh).Select
   
9. #009          End If
   
10. #010      End If
    
11. #011  End Sub

复制代码

代码解析：
       NotSht过程使用自定义的ExistSh函数判断工作簿中是否存在指定名称的工作表，如果不存在则使用消息框进行提示，如图所示。