有什么办法在文字和数字之间加空格吗？？？？

风起尘飞扬 · 发表于 2024-3-6 21:24

有什么办法在文字和数字之间加空格吗？？？？先感谢大佬

miaojohn45 · 发表于 2024-3-6 21:36

本帖最后由 miaojohn45 于 2024-3-6 21:37 编辑

=TRIM(LET(x,TEXTSPLIT(A1,TEXTSPLIT(A1,ROW($1:$10)-1,,1),,1),SUBSTITUTE(A1,x," "&x&" ")))

复制代码

leepoison · 发表于 2024-3-6 22:25

=TRIM(TEXTBEFORE(A1,CONCAT(IFERROR(--MID(A1,ROW($1:$99),1),"")))&" "&CONCAT(IFERROR(--MID(A1,ROW($1:$99),1),""))&" "&TEXTAFTER(A1,CONCAT(IFERROR(--MID(A1,ROW($1:$99),1),""))))

cnmlgb9998 · 发表于 2024-3-6 23:36

PQ！！！！！！！！！！！！！！！！！！！！！！！！！！

cnmlgb9998 · 发表于 2024-3-6 23:37

我只发图片，没发代码，怎么也要审核？？？？？？？？？

痛痛痛痛 · 发表于 2024-3-7 00:19

本帖最后由痛痛痛痛于 2024-3-7 09:16 编辑

=trim(REDUCE(A1,TEXTSPLIT(A1,TEXTSPLIT(A1,ROW($1:$10)-1,,1),,1),LAMBDA(x,y,SUBSTITUTE(x,y," "&y&" "))))

公式适合有多个不连续的数字的情况，需要支持 reduce、textsplit的版本，office365 或 office2024版本

伊可赛二 · 发表于 2024-3-7 07:54

正则函数，环视。

zpy2 · 发表于 2024-3-7 08:13

=WEBSERVICE("https://e.anyoupin.cn/eh3/?regreplace~(?<=\D)(?=\d)|(?<=\d)(?=\D)~ ~" & A1)

菜狗一只 · 发表于 2024-3-7 09:32

本帖最后由菜狗一只于 2024-3-7 09:52 编辑

数据中有间断穿插数字的情况吗，比如 12你34好这种

象山海鲜 · 发表于 2024-3-7 10:01

本帖最后由象山海鲜于 2024-3-7 10:20 编辑

=TRIM(CONCAT(REPT(MID(" "&A1,ROW($2:$99)^{1,0},1),-1^MMULT(N(MID(A1,ROW($1:$98)+{0,1},1)>9&9),{1;1})<{2,0})))

复制代码

稍稍简化下

=TRIM(CONCAT(MID(A1,ROW($1:$98),1)&REPT(" ",MMULT(N(MID(A1,ROW($1:$98)+{0,1},1)>9&9),{1;1})=1)))

复制代码

		自动登录	找回密码
密码			免费注册

[已解决] 有什么办法在文字和数字之间加空格吗？？？？

评分