数组归并排序

cidanji

归并排序还是挺好的，在vba里写了一下，10万的乱序数组排下来速度还可以，略逊于快速排序 但特点是它本身类属稳定排序 相同值顺序不乱

1. '/// 归并排序 ///
   
2. '【说明】速度快，略逊于快速排序，但属稳定排序。不限数据类型支持数字/字符串/日期等
   
3. '【参数】arr:要排序的数组，x:排序开始行，UD:0升降(默认)1降序
   
4. Sub GBsort(arr, x&, Optional UD&)
   
5. Dim brr(), y&
   
6. y = UBound(arr)
   
7. ReDim brr(x To y)
   
8. toSort arr, brr, x, y
   
9. If UD <> 0 Then
   
10.     Dim i&, j&, crr
    
11.     ReDim crr(LBound(arr) To UBound(arr))
    
12.     For i = LBound(arr) To UBound(arr)
    
13.         If i < x Or i > y Then
    
14.             crr(i) = arr(i)
    
15.         Else
    
16.             crr(i) = arr(y + x - i)
    
17.         End If
    
18.     Next
    
19.     arr = crr
    
20. End If
    
21. End Sub
    
22. 
    
23. Private Sub toSort(a, b, x&, y&)
    
24. If y <= x Then Exit Sub
    
25. Dim m&
    
26. m = Int((y + x) / 2)
    
27. toSort a, b, x, m
    
28. toSort a, b, m + 1, y
    
29. merger a, b, x, m, y
    
30. End Sub
    
31. 
    
32. Private Sub merger(a, b, x&, m&, y&)
    
33. Dim i As Long
    
34. Dim j As Long
    
35. Dim k As Long
    
36. i = x
    
37. j = m + 1
    
38. For k = x To y
    
39.     b(k) = a(k)
    
40.     b(k) = a(k)
    
41. Next
    
42. For k = x To y
    
43.     If i > m Then
    
44.         a(k) = b(j)
    
45.         j = j + 1
    
46.     ElseIf j > y Then
    
47.         a(k) = b(i)
    
48.         i = i + 1
    
49.     ElseIf b(i) <= b(j) Then
    
50.         a(k) = b(i)
    
51.         i = i + 1
    
52.     Else
    
53.         a(k) = b(j)
    
54.         j = j + 1
    
55.     End If
    
56. Next
    
57. End Sub

复制代码