如何复制一个未知文件名的表格数据到另外一个表格

kaiwozhe

请教各位老师一个问题如何在一个表格实现其他表格的VBA程序，
想把文件的数据复制到旁边这个表格，要复制的表格文件名是不固定，而且不存放VBA代码的

gbgbxgb

试试下列代码（话说：你的这个意图实际应用中究竟有多大意义，若出于学习VBA，倒不失为一“敢想敢做”）：

1. Sub theCopyNextBook()
   
2.     Dim wb As Workbook, theWindowIndex&, MyWindowIndex&
   
3.     '
   
4.     MyWindowIndex = Windows(ThisWorkbook.Name).Index
   
5.     For Each wb In Application.Workbooks
   
6.         If Windows(wb.Name).Visible Then
   
7.             theWindowIndex = Windows(wb.Name).Index
   
8.             If Abs(theWindowIndex - MyWindowIndex) = 1 Then
   
9.                 wb.Worksheets(1).Columns(1).Copy
   
10.                 ThisWorkbook.Worksheets(1).Cells(1).PasteSpecial Paste:=xlPasteValues
    
11.                 Exit For
    
12.             End If
    
13.         End If
    
14.     Next wb
    
15. End Sub

复制代码

kaiwozhe

gbgbxgb 发表于 2020-2-22 16:56
试试下列代码（话说：你的这个意图实际应用中究竟有多大意义，若出于学习VBA，倒不失为一“敢想敢做”）：
...

谢谢老师，主要是想学习一下，老师可以讲解一下吗，假如要复制某个单元格过去要修改哪些

gbgbxgb

kaiwozhe 发表于 2020-2-22 17:10
谢谢老师，主要是想学习一下，老师可以讲解一下吗，假如要复制某个单元格过去要修改哪些

消磨时间，给你授课：

1. Sub theCopyNextBook()
   
2.     Dim wb As Workbook, theWindowIndex&, MyWindowIndex&
   
3.     Dim theFinalRow&, arr As Variant
   
4.     '
   
5.     MyWindowIndex = Windows(ThisWorkbook.Name).Index '当前代码所在工作簿窗口的索引号（后文简述为序号）
   
6.     For Each wb In Application.Workbooks '遍历循环已打开的所有工作簿
   
7.         If Windows(wb.Name).Visible Then '防止有窗口被隐藏的工作簿被当作目标工作簿（譬如存在个人宏工作簿等）
   
8.             theWindowIndex = Windows(wb.Name).Index '该可见工作簿窗口的序号
   
9.             If Abs(theWindowIndex - MyWindowIndex) = 1 Then '若窗口序号紧挨，判断为找到了目标工作簿
   
10.                 '下方楼主所谓的粘贴（事实上，后文代码不再是粘贴，而写入了）操作作了大的变更
    
11.                 With wb '用With结构限定下方的所有属性操作针对的都是wb这一目标工作簿，初学者要尽量掌握这种写法
    
12.                     With .Worksheets(1) '再来个With结构限定下方的所有属性操作针对的都是Wb工作簿的第一个工作表
    
13.                         theFinalRow = .Cells(.Rows.Count, 1).End(xlUp).Row '取得A列最靠后的存在数据的数据行号
    
14.                         '把第1列从第1行起始到上文所说的theFinalRow行止的单元格区域一次性读入arr变量（显然，此时arr变量是一个二维数组了）
    
15.                         arr = .Range(.Cells(1, 1), .Cells(theFinalRow, 1))
    
16.                     End With
    
17.                 End With
    
18.                 '
    
19.                 '把arr数组写入当前代码所在工作簿的第1个工作表的A1单元格起始的A列
    
20.                 '注：Resize方法允许Range对象（此例Range对象为.Cells(1)，即工作表的第1个单元格，用大白话说，就是A1单元格）在新区域内调整大小
    
21.                 '再说白点吧：Resize后的新区域的数量行为Ubound(arr)行，数量列为1列。事实上，
    
22.                 '也可写为.Resize(Ubound(arr))，即把列数省略，省略列数的情况下扩展的区域的列数大小默认为与Range的列数数量是一样的
    
23.                 '补：Ubound()函数是取得数组的维数，其用法自己花时间去帮助文件中查询，你没付费^_^，教你的已经过多了
    
24.                 ThisWorkbook.Worksheets(1).Cells(1).Resize(UBound(arr), 1) = arr '把数组内容写入工作表
    
25.                 Exit For '显然目的达成了，不用再往后循环了吧
    
26.             End If
    
27.         End If
    
28.     Next wb
    
29. End Sub

复制代码

kaiwozhe

gbgbxgb 发表于 2020-2-22 18:19
消磨时间，给你授课：

谢谢老师，已经学会自己需要实现的效果了，感谢你愿意空出时间教我，谢谢