用数组导出一列满足条件的数据的VBA.我试着改成可以导出几列的

king260815796

我以前在论坛求助过，有大神做了一个用数组导出一列满足条件的数据的VBA.我试着改成可以导出几列的。但由于水平有限，各种问题。有大神帮帮不？

下面是原代码：  

Sub 提取选定的科目发生额()

Dim arr As Variant '写导出条件那一列

Dim arr1 As Variant '提取出的结果

Dim arr2 As Variant '数据源

Dim m As Integer

Dim k As Integer

Dim x As Integer

Dim y As Integer

arr = Sheets("分录").Range("w12:w10011")

m = Application.CountIf(Sheets("分录").Range("w12:w10011"), Range("f2"))

ReDim arr1(1 To m, 1 To 1) As Variant

arr2 = Sheets("分录").Range("r12:r10011")

For x = 1 To 10000 '如果范围大于，会出现下标越界

If arr(x, 1) = Range("f2") Then

k = k + 1

arr1(k, 1) = arr2(x, 1)

End If

Next

Range("b6").Resize(m, 1) = arr1

End Sub

是将表格“分录”中的数据。将“分录”表格中W列中，是“账簿”表格中F2单元格中的数据提取出来。 原代码只能提取一列，即将“分录”中R列满足条件的放“账簿”表格中的B列。请改成可以将“分录”中R列到Y列满足条件的放“账簿”表格中的B列到I列

一把小刀闯天下

Option Explicit

Sub test()
  Dim arr, i, j, s, m
  With Sheets("分录")
    arr = .Range("r12:y" & .Cells(Rows.Count, "r").End(xlUp).Row)
  End With
  With Sheets("账簿")
    s = .[f2].Value
    For i = 1 To UBound(arr, 1)
      If arr(i, 6) = s Then
        m = m + 1
        For j = 1 To UBound(arr, 2)
          arr(m, j) = arr(i, j)
        Next
      End If
    Next
    With .[b6]
      .Resize(UBound(arr, 1), UBound(arr, 2)).ClearContents
      If m > 0 Then .Resize(m, UBound(arr, 2)) = arr
    End With
  End With
End Sub

shenjianrong163

Sub 提取选定的科目发生额()
    Dim i, j, k, r, s$, arr, brr()
    With Worksheets("分录")
        r = .Cells(.Rows.Count, 18).End(xlUp).Row
        arr = .Range("R12:Y" & r)
        ReDim brr(1 To UBound(arr), 1 To UBound(arr, 2))
    End With
    With Worksheets("账簿")
        s = Replace(.Cells(2, 6), " ", "")
        For i = 1 To UBound(arr)
            If Replace(arr(i, 6), " ", "") = s Then
                k = k + 1
                For j = 1 To UBound(arr, 2)
                    brr(k, j) = arr(i, j)
                Next
            End If
        Next
        .Range("B6:I" & .Cells(.Rows.Count, 2).End(xlUp).Row + 6).ClearContents
        .[B6].Resize(UBound(brr), UBound(brr, 2)) = brr
    End With
End Sub

网海遨游

Sub 提取选定的科目发生额()
  Dim arr1() As Variant '提取出的结果
  Dim arr As Variant '数据源
  Dim k, x, j
  Application.DisplayAlerts = False: Application.ScreenUpdating = False
  r = Sheets("分录").Cells(Rows.Count, "w").End(3).Row
  arr = Sheets("分录").Range("r12:y" & r)
  For x = 1 To UBound(arr)
    If arr(x, 6) = Sheets("账簿").Range("f2") Then
      k = k + 1
      ReDim Preserve arr1(1 To 8, 1 To k) As Variant
      For j = 1 To UBound(arr, 2)
        arr1(j, k) = arr(x, j)
      Next j
    End If
  Next
  Sheets("账簿").Range("b6").Resize(UBound(arr1, 2), UBound(arr1)).ClearContents
  Sheets("账簿").Range("b6").Resize(UBound(arr1, 2), UBound(arr1)) = Application.Transpose(arr1)
  MsgBox "OK，完成！！！", 48, "温馨提示……"
  Application.DisplayAlerts = True: Application.ScreenUpdating = True
End Sub

king260815796

相互学习，共同进步。
送人玫瑰，手留余香！
答对了，鲜花激励下，更让人奋进！！！