请大师帮我一下完善下面代码 这个代码是搬别人的

psliwei

Public Sub PicName()
Dim Pth As String
Dim Pic As String
ActiveSheet.Range("A3").Select  '选中激活窗口的A3
Pth = "G:\照片重命名最简单的方法xin\学籍照片" '路径，系统自带图片的地方
Pic = Dir(Pth & "\*.jpg")   '查看JPG格式的图片名称
Do While Pic <> ""
        Selection = Pic         '赋值
        Pic = Dir
        Selection.Offset(1, 0).Select
Loop
End Sub


这个代码可以提取固定文件夹中的图片名字，

我的要求是 1、提取的文件夹可以自己随意选（就是弹出一这个选择的窗口，
                 2、提取的图片名字不要带扩展名（后缀）  
谢谢名位大师了!!!

liulang0808

Set fd = Application.FileDialog(msoFileDialogFolderPicker)
弹出窗体选择文件夹
Selection = split(Pic,".")(0)  

山菊花

Option Compare Text
Public Sub PicName()
    Dim Pth As String
    Dim Pic As String
    Dim myDialog As FileDialog, Arr(1 To 1000, 0), m%
    Set myDialog = Application.FileDialog(4)
    If myDialog.Show <> -1 Then Exit Sub
    Pth = myDialog.SelectedItems(1)
    Pic = Dir(Pth & "\*.jpg")   '查看JPG格式的图片名称
    Do While Pic <> ""
        m = m + 1
        Arr(m, 0) = Split(Pic, ".jpg")(0)
        Pic = Dir
    Loop
    ActiveSheet.Range("A3").Resize(m, 1).Value = Arr
End Sub

psliwei

liulang0808 发表于 2020-1-20 08:08
Set fd = Application.FileDialog(msoFileDialogFolderPicker)
弹出窗体选择文件夹
Selection = split(Pi ...

谢谢老大了！！

psliwei

山菊花 发表于 2020-1-20 08:14
Option Compare Text
Public Sub PicName()
    Dim Pth As String

总版主 谢谢了  非常好用！！！太感谢了！！！