出道函数题：统计营养早餐天数

aoe1981 · 发表于 2020-1-8 23:25

我走我流发表于 2020-1-8 21:10
=COUNT(0/SUBTOTAL(9,OFFSET(B3,,(ROW($1:$30)-1)*4,,4)))
数组下拉

写成这样和满版的一样长了：
=COUNT(0/SUBTOTAL(9,OFFSET(B3,,ROW($1:$30)*4-4,,4)))

附满版的：
=COUNT(0/SUBTOTAL(2,OFFSET(A3,,ROW($1:$30)*4-3,,4)))

基本差别是，2变做9。

mmlzh · 发表于 2020-1-8 23:29

aoe1981 发表于 2020-1-8 22:18
一个：
SUBTOTAL(2,数据区域)
把我唬了半天，原来相当于count，我把它叫做“分类汇总函数”，也不知道 ...

=COUNT(0/SUBTOTAL(9,INDIRECT("RC"&ROW($1:$31)*4-2&":C"&ROW($1:$31)*4+1,)))

aoe1981 · 发表于 2020-1-8 23:31

micch 发表于 2020-1-8 21:22
countif统计1的次数

花彻底送完了，您的offset第一参数为数组形式，让人大开眼界！

附上您的公式，以便对照：

=SUM(N(COUNTIF(OFFSET(B3:E3,,ROW($1:$31)*4-4),1)>0))

aoe1981 · 发表于 2020-1-8 23:43

solextrade 发表于 2020-1-8 21:37
刚刚吃酒回来，看大佬出题，老师们霸占思路了。参与一下
=COUNT(0/SUMIF(OFFSET(A3,,ROW($1:$30)*4-3,,4), ...

主流思路都使用了offset。

3楼dipperrrr使用了MATCH；

5楼sbdk007使用了FREQUENCY；

13楼Datous的公式看起来更朴素。

感谢各位大神，真牛人也！！！

mmlzh · 发表于 2020-1-8 23:44

aoe1981 发表于 2020-1-8 23:17
学习了。
FREQUENCY数据分布频率统计函数我备注下两个特点：
1.忽略数据区域中的逻辑值、文本、空单元 ...

这样不用按三键
=COUNT(0/FREQUENCY(COLUMN(A:DQ)*B3:DR3,B$1:DQ$1*4))-1

aoe1981 · 发表于 2020-1-8 23:57

本帖最后由 aoe1981 于 2020-1-9 00:09 编辑

Datous 发表于 2020-1-8 21:46
再减一个字，瞎凑，没拓展性

=COUNT((B5:DN5&C5:DO5&D5:DP5&E5:DQ5)/B$1:DN$1)

错位相加，有意义的只有每天的第一格，而这一格对应着日期序号，其他第2、3、4格却是空值，用空值作除数，把那些没有意义的错位相加结果（每连续4格）处理成错误值，然后利用count屏蔽错误值的特性，统计正确值。

真是服了！！！最生猛！！！

明日送花。

静看流年RSSQ · 发表于 2020-1-9 01:07

凑个总结凑的晕晕的。。
大佬们不写。我还想不到上面去，一写吧又觉得真的太简单、
水个大火车高版。证明我来过、、
=30-SUM(N(MID(CONCAT(IF(B3:DQ3,1,)),ROW($1:$30)*4-3,4)="0000"))

sbdk007 · 发表于 2020-1-9 07:04

mmlzh 发表于 2020-1-8 23:44
这样不用按三键
=COUNT(0/FREQUENCY(COLUMN(A:DQ)*B3:DR3,B$1:DQ$1*4))-1

我最初也是这样用的，可是当第一日为0时也会被统计到4，多了一个

mmlzh · 发表于 2020-1-9 08:09

sbdk007 发表于 2020-1-9 07:04
我最初也是这样用的，可是当第一日为0时也会被统计到4，多了一个

拉长1列就始终会多一个0,-1结果就不会出问题了，这是从海版那学来的

mmlzh · 发表于 2020-1-9 08:23

aoe1981 发表于 2020-1-8 23:57
错位相加，有意义的只有每天的第一格，而这一格对应着日期序号，其他第2、3、4格却是空值，用空值作除数 ...

只要有规律，没有台头也可以自行造
=COUNT((B3:DN3&C3:DO3&D3:DP3&E3:DQ3)/(MOD(COLUMN(B:DQ),4)=2))

		自动登录	找回密码
密码			免费注册

[讨论] 出道函数题：统计营养早餐天数