如何修改宏，实现已录入的行不执行自动填入，否则其它不变！

通tom

已有附件宏，可以自动按要求自动填入！但有个小要求不知如何修改实现？有劳老师、高手们帮忙看看，万分感谢！

Private Sub Worksheet_Change(ByVal Target As Range)

    If Target.Count > 1 Then Exit Sub
    If Target = "" Then Exit Sub
    Application.EnableEvents = False
    If Target.Column = 4 And Target.Row > 12 Then
        If Len(Target) = 13 Then

        Target.Value = "L" & Target
        Target.Offset(0, -3).Formula = "=no"
        Target.Offset(0, 2).Formula = "=ff"
        Target.Offset(0, 9).Formula = "=mm"
        Else
        Target.Offset(0, -3).Formula = "=no"
        Target.Offset(0, 2).Formula = "=ff"
        Target.Offset(0, 9).Formula = "=mm"
            End If
            End If
    Application.EnableEvents = True
    If Target > 10000099800# Then Exit Sub
Application.EnableEvents = False
    If Target.Column = 5 And Target.Row > 12 Then
        If IsNumeric(Target) Then
            Target = "10000" & Target
    End If
    End If
Application.EnableEvents = True
End Sub

山菊花

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Or Target.Row <= 12 Then Exit Sub
    If Target = "" Then Exit Sub
    Application.EnableEvents = False
    If Target.Column = 4 Then
        If Len(Target) = 13 Then Target.Value = "L" & Target
        If Not Target.Offset(0, -3).HasFormula Then
            Target.Offset(0, -3).Formula = "=no"
            Target.Offset(0, 2).Formula = "=ff"
            Target.Offset(0, 9).Formula = "=mm"
        End If
    ElseIf Target.Column = 5 Then
        If IsNumeric(Target) And Target < 1000000# Then
            Target = 10 ^ 10 + Target
        End If
    End If
    Application.EnableEvents = True
End Sub

通tom

山菊花 发表于 2020-1-6 21:53
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Or Target.Row

感谢感谢!
这是以判定A列是否为公式，来执行！若需判定是有内容如何改？

山菊花

有内容：
If Target.Offset(0, -3).Value <> "" Then
无内容：
If Target.Offset(0, -3).Value = "" Then

通tom

山菊花 发表于 2020-1-10 21:18
有内容：
If Target.Offset(0, -3).Value  "" Then
无内容：

茅塞顿开！学习了！