根据三个已知条件，从数据库中查找对应的最后50条信息显示在下方

ym21ht

根据三个已知条件，从数据库中查找对应的最后50条信息显示在下方，小弟想麻烦下各位大神

NadrsSaber

根据B1、E1、F1单元格的三个条件, 这里应是根据 B1,D1,F1吧...
没60秒刷新一次, 是啥意思?
数据库也就 30行内容啊...

ym21ht

NadrsSaber 发表于 2019-12-17 11:35
根据B1、E1、F1单元格的三个条件, 这里应是根据 B1,D1,F1吧...
没60秒刷新一次, 是啥意思?
数据库也就 30 ...

不好意思 写错了  是B1 D1 F1三个单元格   
每60秒刷新一次 是想要这段代码每60秒从数据库查找并显示一次。
目前只是试验，数据量很少，正式建立后数据量很大的  

NadrsSaber

Private Sub JianSuoBt_Click() '检索目前订单

    Select Case myDengRcount
        Case Is = 1
        Case Is = 0
            myUserF.Show
            Exit Sub
    End Select
   
'////////////////////////////////////////////////////
    Dim cxStr As String
    Dim cxSql As String
   
    With Worksheets("订单保存")
        If Not IsEmpty(.Cells(1, 9)) Then
            cxStr = .Cells(1, 9)
        Else
            cxStr = .Cells(2, 9)
        End If
    End With
   
    If cxStr = "" Then MsgBox "月份/流水号 未填写!": Exit Sub
   
    cxSql = FunSql(cxStr)
   
'////////////////////////////////////////////////////查询语句
    Dim myCnn As Object 'ADO连接点
    Dim myStrCnn As String 'ADO连接字符
    Dim myPath As String '文件地址
    Dim myRs As Object 'ADO记录集
   
    Set myCnn = CreateObject("ADODB.Connection")
    myPath = ThisWorkbook.Path & "\金桔订单.accdb"
   
    On Error GoTo Err1 '错误处理

    Select Case Application.Version * 1 '判断系统Excel版本
        Case Is <= 11
            myStrCnn = "Provider=Microsoft.JET.OLEDB.4.0;Data Source=" & myPath
        Case Is >= 12
            myStrCnn = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & myPath
    End Select
   
    myCnn.Open myStrCnn
   
    Set myRs = myCnn.Execute(cxSql)
   
    If myRs.EOF = True Then MsgBox "无此数据!": Exit Sub
   
    Dim myRow As Long '行数
    If Not IsEmpty(Worksheets("订单保存").Cells(6, 1)) Then '判断单元格是否为空值
        myRow = Worksheets("订单保存").Cells(5, 1).End(xlDown).Row '导入行数
        With Worksheets("订单保存")
            .Range("A6:I" & myRow).ClearContents
            .[A6].CopyFromRecordset myRs
        End With
    Else
        With Worksheets("订单保存")
            .[A6].CopyFromRecordset myRs
        End With
    End If
   
'SELECT sum(订单明细.供货数* 订单明细.备件单价) as sumHeji FROM 订单明细
    Dim jeHeji As Double
    Dim jxRange As Range
    myRow = Worksheets("订单保存").Cells(5, 1).End(xlDown).Row '重新计算行数
    With Worksheets("订单保存")
        For Each jxRange In .Range("F6:F" & myRow)
            jeHeji = jeHeji + jxRange * jxRange.Offset(0, -2) '合计金额
        Next
        .[I3] = 0
        .[I3] = jeHeji
    End With
   
    myCnn.Close
    Set myRs = Nothing
    Set myCnn = Nothing
    Exit Sub
   
Err1:
    MsgBox Err.Description
   
End Sub

Private Function FunSql(str As String) '查询语句

    Select Case Len(str)
        Case Is = 4
            FunSql = "SELECT * FROM 订单明细 WHERE 备注 LIKE '" & CStr(str) & "%'"
        Case Is = 6
            FunSql = "SELECT * FROM 订单明细 WHERE 备注 LIKE '" & CStr(str) & "%'"
        Case Is = 10
            FunSql = "SELECT * FROM 订单明细 WHERE 备注 ='" & CStr(str) & "'"
        Case Else
            MsgBox "无有效查询条件, 请检查后在执行!"
            FunSql = ""
    End Select
   
End Function

NadrsSaber

之前做过类似的, 你可以看着改改...

ym21ht

NadrsSaber 发表于 2019-12-17 11:57
之前做过类似的, 你可以看着改改...

一头雾水

NadrsSaber

ym21ht 发表于 2019-12-17 13:33
一头雾水

也是根据条件, 提取数据.

魂断蓝桥

Sub 开始()
Dim bt$, CNN, RS, SQL$, TJ$, i%, NewTime
bt = " [WRN#],班次,录入员,生产线,品种,取样时间,吸碘值,吸油值,[325#水洗],[200#水洗],[100#水洗],[35#水洗],[10#粒子],最大颗粒强度,平均颗粒强度,最小颗粒强度,水分,倾注密度,罐号,温度"
For i = 2 To 4 Step 2
    TJ = TJ & Cells(1, i - 1) & "='" & Cells(1, i) & "' and "
Next
TJ = Left(TJ, Len(TJ) - 4)
NewTime = Now + TimeValue("00:00:03") '为了测试方便写3秒，根据你的需要自己更改
Set CNN = CreateObject("ADODB.Connection")
Set RS = CreateObject("adodb.Recordset")
CNN.Open "provider=microsoft.ace.oledb.12.0;data source=" & ThisWorkbook.Path & "\数据库.accdb"
SQL = "select top " & [f1] & bt & " from 生产命令单 where " & TJ & " order by id desc"
[a5:t999] = ""
Range("A5").CopyFromRecordset CNN.Execute(SQL)
[f5:f999].NumberFormatLocal = "hh:mm:ss"
Set RS = Nothing
Set CNN = Nothing
Application.OnTime NewTime, "开始"
End Sub

Sub 结束()
Application.OnTime EarliestTime:=Now + TimeValue("00:00:01"), Procedure:="开始", Schedule:=False
End Sub

ym21ht

魂断蓝桥 发表于 2019-12-17 14:26
Sub 开始()
Dim bt$, CNN, RS, SQL$, TJ$, i%, NewTime
bt = " [WRN#],班次,录入员,生产线,品种,取样时间 ...

大神，第一次可以运行，3秒后提示这个 然后不自动运行了

魂断蓝桥

ym21ht 发表于 2019-12-17 15:25
大神，第一次可以运行，3秒后提示这个 然后不自动运行了

Option Explicit
Dim m As Boolean
Sub 开始()
Dim bt$, CNN, RS, SQL$, TJ$, i%, NewTime
bt = " [WRN#],班次,录入员,生产线,品种,取样时间,吸碘值,吸油值,[325#水洗],[200#水洗],[100#水洗],[35#水洗],[10#粒子],最大颗粒强度,平均颗粒强度,最小颗粒强度,水分,倾注密度,罐号,温度"
If m = True Then m = False: Exit Sub
For i = 2 To 4 Step 2
    TJ = TJ & Cells(1, i - 1) & "='" & Cells(1, i) & "' and "
Next
TJ = Left(TJ, Len(TJ) - 4)
NewTime = Now + TimeValue("00:00:03")
Set CNN = CreateObject("ADODB.Connection")
Set RS = CreateObject("adodb.Recordset")
CNN.Open "provider=microsoft.ace.oledb.12.0;data source=" & ThisWorkbook.Path & "\数据库.accdb"
SQL = "select top " & [f1] & bt & " from 生产命令单 where " & TJ & " order by id desc"
[a5:t999] = ""
Range("A5").CopyFromRecordset CNN.Execute(SQL)
[f5:f999].NumberFormatLocal = "hh:mm:ss"
Set RS = Nothing
Set CNN = Nothing
Application.OnTime NewTime, "开始"
End Sub

Sub 结束()
m = True
End Sub