根据单元格数值生成对应的单元格数量

zjh0462 · 发表于 2019-12-7 14:56

如题，现要根据D列单元格中的数值，在A列中生成对应的C列单元格的数量。如D1单元格的数值是8，那就要在A列中生成8个第一批，D3单元格的数值是6，那就要在A列中生成6个第一批。这个可以用复制粘贴，但数据多了复制工作量较大，能否利用函数自动生成呢？

solextrade · 发表于 2019-12-7 15:07

=LOOKUP(,0/FREQUENCY(ROW(),SUBTOTAL(9,OFFSET(D$1,,,ROW($1:$13)))),C$1:C$13)&""

624134745 · 发表于 2019-12-7 15:10

本帖最后由 624134745 于 2019-12-7 15:16 编辑

借助1个辅助列，用VLOOKUP.不要辅助列的A1=IFERROR(VLOOKUP(ROW(A1),IF({1,0},SUMIF(OFFSET($D$1,,,ROW($1:$100),),"<>"),$C$1:$C$13),2,),A2)

niko88819 · 发表于 2019-12-7 15:27

A1

{=LOOKUP(ROW(1:1)-1,MMULT(N(ROW($1:$13)>=COLUMN(B:N)),$D$1:$D$13),$C$1:$C$13)}

INaga2018 · 发表于 2019-12-7 16:03

来个不一样的：
=INDEX(EVALUATE("{"""&SUBSTITUTE(TEXTJOIN(""",""",1,REPT($C$1:$C$13,$D$1:$D$13)),"批第","批"",""第")&"""}"),ROW(A1))，数组三键

hcm19522 · 发表于 2019-12-7 16:56

本帖最后由 hcm19522 于 2019-12-7 17:01 编辑

{=OFFSET(C$1,SUM(N((ROW()>SUMIF(OFFSET(D$1,,,ROW($1:$13)),">0")))),)

zjh0462 · 发表于 2019-12-7 17:07

大神太多了，谢谢大家！

INaga2018 · 发表于 2019-12-7 17:53

zjh0462 发表于 2019-12-7 17:07
大神太多了，谢谢大家！

学习一个：
=OFFSET($C$1,SUM(N(ROW()>SUBTOTAL(9,OFFSET($D$1,,,ROW($1:$13))))),)，数组三键

kuangben8 · 发表于 2019-12-8 09:25

本帖最后由 kuangben8 于 2019-12-8 11:31 编辑

数据透视表
================看错了！尴尬。。。给你一个自定义函数

=mx($C$1:$D$13,ROW(A1))

复制代码

数据.zip (11.4 KB, 下载次数: 1)

		自动登录	找回密码
密码			免费注册

[求助] 根据单元格数值生成对应的单元格数量

评分

评分

评分

评分

评分

最新热点 /1