关于递归遍历子文件夹

he577

如下从论坛中找到的遍历子文件夹下所有文件名.如果我只想要 所有的 *.ppt 文件名在A列显示,要怎样改才行.自己试了用 like 不行.
Sub ListFilesTest()
    Dim mypath$
    mypath = ThisWorkbook.Path & "\"
    If Right(mypath, 1) <> "" Then mypath = mypath & ""

    [a:a] = ""                    '清空A列
    Call ListAllFso(mypath)   '调用FSO遍历子文件夹的递归过程

End Sub

Function ListAllFso(mypath$) '用FSO方法遍历并列出所有文件和文件夹名的【递归过程】
    Set fld = CreateObject("Scripting.FileSystemObject").GetFolder(mypath)
    '用FSO方法得到当前路径的文件夹对象实例 注意这里的【当前路径myPath是个递归变量】

    For Each f In fld.Files  '遍历当前文件夹内所有【文件.Files】
        [a65536].End(3).Offset(1) = f.Name '在A列逐个列出文件名
    Next

    For Each fd In fld.SubFolders  '遍历当前文件夹内所有【子文件夹.SubFolders】
        [a65536].End(3).Offset(1) = " " & fd.Name & ""  '在A列逐个列出子文件夹名
        Call ListAllFso(fd.Path)       '注意此时的路径变量已经改变为【子文件夹的路径fd.Path】
        '注意重点在这里： 继续向下调用递归过程【遍历子文件夹内所有文件文件夹对象】
    Next
End Function

一把小刀闯天下

'不用递归来个，递归的这论坛自己找一下多得是，，，

Option Explicit

Sub test()
  Dim filename(), i
  If Not getfilename(filename, ThisWorkbook.Path, ".ppt") Then MsgBox "!": Exit Sub
  For i = 1 To UBound(filename)
    Debug.Print filename(i)
  Next
End Sub

Function getfilename(filename, pth As String, mark As String) As Boolean
  Dim f, n As Long, cnt As Long, p(10 ^ 5) As String
  If Right(pth, 1) <> "\" Then pth = pth & "\"
  Do
    f = Dir(pth, vbDirectory)
    Do While Len(f) > 0
      If f <> "." And f <> ".." Then
        If (GetAttr(pth & f) And vbDirectory) = vbDirectory Then
          cnt = cnt + 1: p(cnt) = pth & f & "\"
        Else
          If LCase(Right(f, Len(mark))) = LCase(mark) Then
            n = n + 1: ReDim Preserve filename(1 To n)
            filename(n) = pth & f
          End If
        End If
      End If
      f = Dir
    Loop
    If cnt = 0 Then Exit Do
    pth = p(cnt): cnt = cnt - 1
  Loop
  If n > 0 Then getfilename = True
End Function

opel-wong

一把小刀闯天下 发表于 2019-10-17 12:16
'不用递归来个，递归的这论坛自己找一下多得是，，，

Option Explicit

这个貌似不支持通配符，比如：xls*

一把小刀闯天下

opel-wong 发表于 2019-10-17 14:38
这个貌似不支持通配符，比如：xls*

是的

但mark可以定义为一个数组，这样可以支持更多的文件类型（再加个循环使用instr判断就可以）的，，，