如何求三列数据中某数字的行间隔最大值，均值和中位值？

urmylove

多列单元格内均为自然数或空值，怎么求ABC列（DEF也一样）中，数字0的行间隔的最大值，均值和中位值？举例：
A  B  C
1  0  2
4  6  1
2  2  3
3  1  2
0  3  4
5  2  3
2  1  1
4  3  0
如以上数据中，0的行间隔值3，2。
请教大神，数字0行间隔的最大值，均值和中位值的公式该如何实现？
更具体事例请见附件的图片，原始数据请见附件表格。

solextrade

都是数组公式：

B250 =LARGE(FREQUENCY(ROW(A:A),(B$2:D$247=0)*ROW(B$500:B$745))-1,3)

B251 =MEDIAN(FREQUENCY(ROW(B$2:D$247),IF(B$2:D$247=0,ROW(B$2:B$247))))

B252 =AVERAGE(FREQUENCY(ROW(B$2:D$247),IF(B$2:D$247=0,ROW(B$2:B$247))))

urmylove

solextrade 发表于 2019-8-17 17:44
都是数组公式：

B250 =LARGE(FREQUENCY(ROW(A:A),(B$2:D$247=0)*ROW(B$500:B$745))-1,3)

第一个为什么要用Large函数，我就是想求一个最大的，用Max更合适吧？

solextrade

urmylove 发表于 2019-8-17 17:58
第一个为什么要用Large函数，我就是想求一个最大的，用Max更合适吧？

B251 公式修改下：
=MEDIAN(FREQUENCY(ROW(A:A),IF(MMULT(--(B$2:D$247=0),{1;1;1}),ROW(B$500:B$745)))-1)

用MAX不对！
比如我们现在共有246行数据，再比如我们只有 第240行 和 第 245行有 0 （这里是假设，只是为说明问题），那么我们知道最大间隔应该是4对吧，但公式结果会是  239！

B252公式我再想想该怎么改。

urmylove

solextrade 发表于 2019-8-17 18:09
B251 公式修改下：
=MEDIAN(FREQUENCY(ROW(A:A),IF(MMULT(--(B$2:D$247=0),{1;1;1}),ROW(B$500:B$745))) ...

按照我的原意，最大间隔就是239，所以应该用Max，图示中之所以举例两个0中间的数值只是为了说明问题，实际上是可以理解成，从第一行开始，一直无0的行数值。麻烦用Max再写个公式吧

solextrade

B250 =MAX(FREQUENCY(ROW(B$2:D$247),IF(B$2:D$247=0,ROW(B$2:B$247)))-1)
B251 =MEDIAN(FREQUENCY(ROW(B$2:D$247),IF(B$2:D$247=0,ROW(B$2:B$247)))-1)
B252 =AVERAGE(FREQUENCY(ROW(B$2:D$247),IF(B$2:D$247=0,ROW(B$2:B$247)))-1)

urmylove

solextrade 发表于 2019-8-17 18:34
B250 =MAX(FREQUENCY(ROW(B$2:D$247),IF(B$2:D$247=0,ROW(B$2:B$247)))-1)
B251 =MEDIAN(FREQUENCY(ROW(B$ ...

基本解决问题，多谢大神！