怎么用VBA汇总多个工作簿的第一个工作表，万分感谢

小太阳CMJ · 发表于 2019-4-17 11:17

是一个新手，没有接触过VBA，在网上查了很多资料也没有解决，拜托各位了

附件里面有两个工作簿，需要汇总大概100这样的工作簿中的第一个sheet到一个新的excel中

万分感谢

考试加油站 · 发表于 2019-4-17 11:46

电子表格一键合并与拆分工具箱.zip (91.83 KB, 下载次数: 68)

小太阳CMJ · 发表于 2019-4-17 11:57

考试加油站发表于 2019-4-17 11:46

谢谢您，但是这个表格不适合我的需求
~谢谢哈

kuangben8 · 发表于 2019-4-17 14:15

楼主是打算怎么个汇总法？模拟一下数据看看啊。

小太阳CMJ · 发表于 2019-4-17 14:52

kuangben8 发表于 2019-4-17 14:15
楼主是打算怎么个汇总法？模拟一下数据看看啊。

一个工作簿里面有三个sheet，名字分别为签到表，本月汇总，sheet3。多个同类的工作簿放在同一个文件夹内，把每个工作簿中的本月汇总表格内的数据汇总到新的工作表内~

kuangben8 · 发表于 2019-4-17 15:13

小太阳CMJ 发表于 2019-4-17 14:52
一个工作簿里面有三个sheet，名字分别为签到表，本月汇总，sheet3。多个同类的工作簿放在同一个文件夹内 ...

是简单的复制粘贴，还是按照汇总表里的人名进行累加汇总？

小太阳CMJ · 发表于 2019-4-17 15:42

kuangben8 发表于 2019-4-17 15:13
是简单的复制粘贴，还是按照汇总表里的人名进行累加汇总？

你好，这个回复里面我没办法添加图片，那个表格的附件我上传了，不复制粘贴，直接利用VBA一键汇总多个工作簿内相同表名的数据

kuangben8 · 发表于 2019-4-17 21:40

不知道理解的对不对，仅供参考。

Sub 汇总()
Dim numb%, fil As String, filename As String, wb As Workbook, sht As Worksheet, t
Dim n%, m%, k%, j%, arr, brr, crr(), i%, num%
Dim dic1 As Object, dic2 As Object
t = Timer
Set dic1 = CreateObject("Scripting.Dictionary")
Set dic2 = CreateObject("Scripting.Dictionary")
With ThisWorkbook.Worksheets("汇总")
Application.ScreenUpdating = False
.Cells.Clear '全部清除
' .Range("A1") = "http://club.excelhome.net/thread-1472164-1-1.html" '原帖地址
filename = Dir(ThisWorkbook.Path & "\*.xls") '取得代码工作簿所在文件夹下的文件名
Do While filename <> ""
If filename <> ThisWorkbook.Name Then
' numb = .Range("A1").CurrentRegion.Rows.Count + 1
fil = ThisWorkbook.Path & "" & filename '获取对应路径下的文件
Set wb = GetObject(fil)
Set sht = wb.Worksheets("汇总")
If .Range("A2") = "" Then
arr = sht.Range("A4").CurrentRegion
.Range("A1").Resize(UBound(arr, 1), UBound(arr, 2)) = arr
Erase arr '清空数组
Else
n = .Cells(.Rows.Count, 2).End(3).Row '获取当前表中最后一行的行号
arr = .Range("A4:BB" & n)
m = sht.Cells(sht.Rows.Count, 2).End(3).Row '获取提取数据表中最后一行的行号
brr = sht.Range("A4:BB" & m)
For k = 1 To UBound(arr, 1) '先将汇总表人名写入字典中
dic1(arr(k, 2)) = k '将数组元素装入字典中，并将对应条目值取对应序号
Next
'For j = 1 To UBound(brr, 1) '再将待汇总表中的人名写入字典中
' dic2(brr(j, 2)) = ""
'Next
ReDim crr(1 To UBound(brr, 1), 1 To UBound(brr, 2))
For j = 1 To UBound(brr, 1)
If Not dic1.Exists(brr(j, 2)) Then
i = i + 1
For k = 1 To UBound(brr, 2)
crr(i, k) = brr(j, k)
Next
Else
num = dic1.Item(brr(j, 2))
For k = 4 To UBound(brr, 2)
arr(num, k) = arr(num, k) + brr(j, k)
Next
End If
Next
Rem 将数组重新写入单元格
.Range("A4").Resize(UBound(arr, 1), UBound(arr, 2)) = arr
.Range("A4").Offset(UBound(arr, 1)).Resize(UBound(crr, 1), UBound(crr, 2)) = crr
Erase brr '清空数组以备后续使用
End If
wb.Close False
End If
'Else
' filename = Dir '没有Else此句，运行到代码工作簿时进入无限循环而死机！
'End If '也可以将end if 写在wb.Close False后面，就可以少一句filename = Dir
dic1.RemoveAll
dic2.RemoveAll '清空字典后续重新使用
Erase arr
Erase crr '清空crr数组后续重新使用
i = 0 'i恢复0值后续重新使用
filename = Dir
Loop
Application.ScreenUpdating = True
End With
MsgBox Format(Timer - t, "0.000 s")
End Sub

复制代码

小太阳CMJ · 发表于 2019-4-18 11:48

kuangben8 发表于 2019-4-17 21:40
不知道理解的对不对，仅供参考。

您好，非常感谢您分享的代码，能麻烦您帮我再解决一个问题吗？万分感谢，代码在运行过程中出现错误了，运行到Set wb = GetObject(fil) 提示432自动化操作时文件名或类名未找到，我网上百度了也没能找到对应的解决办法，麻烦您了
·
·

kuangben8 · 发表于 2019-4-18 11:55

小太阳CMJ 发表于 2019-4-18 11:48
您好，非常感谢您分享的代码，能麻烦您帮我再解决一个问题吗？万分感谢，代码在运行过程中出现错误了，运 ...

fil = ThisWorkbook.Path & "\" & filename '获取对应路径下的文件
插入的代码这个符号弄丢了！！

		自动登录	找回密码
密码			免费注册