执行创建数据透视表，为什么有时报错

爱疯

'删除数据透视表
Sub DelPt(rng As Range)
    Dim pt As PivotTable
    For Each pt In rng.Parent.PivotTables
        pt.TableRange2.Delete
    Next
End Sub

Sub AddPt()
    Dim pc As PivotCache
    Dim pt As PivotTable
    Dim sou As Range, des As Range
    '
    Set sou = Sheets(1).[a1].CurrentRegion
    Set des = Sheets(2).[a1]
    Call DelPt(des)
    '1）数据透视表缓存对象
    Set pc = ThisWorkbook.PivotCaches.Create(xlDatabase, sou, xlPivotTableVersion14)
    '2）数据透视表对象
    Set pt = pc.CreatePivotTable(des)
    With pt
        .PivotFields("商品代码").Orientation = xlRowField    '行字段
        .PivotFields("品名").Orientation = xlRowField
        .PivotFields("客户名称").Orientation = xlColumnField    '列字段
        .PivotFields("数量").Orientation = xlDataField    '数据字段
        .PivotFields("商品代码").Subtotals(1) = False    '隐藏分类汇总
    End With
End Sub

Sub AddPt2()
    Dim sh As Worksheet
    Dim pt As PivotTable
    Dim sou As Range, des As Range
    '
    Set sou = Sheets(1).[a1].CurrentRegion
    Set des = Sheets(2).[a1]
    Call DelPt(des)
    '1）数据透视表对象
    Set pt = des.Parent.Parent.PivotTableWizard(xlDatabase, sou, des)
    With pt
        .PivotFields("商品代码").Orientation = xlRowField    '行字段
        .PivotFields("品名").Orientation = xlRowField
        .PivotFields("客户名称").Orientation = xlColumnField    '列字段
        .PivotFields("数量").Orientation = xlDataField    '数据字段
        .PivotFields("商品代码").Subtotals(1) = False    '隐藏分类汇总
    End With
End Sub

1.rar (20.65 KB, 下载次数: 12)

2019-1-31 09:33 上传

点击文件名下载附件

如题，请问需要怎样修改？谢谢

taller

删除透视表导致des对象不存在，所有产生错误

1. Sub AddPt2()
   
2.     Dim sh As Worksheet
   
3.     Dim pt As PivotTable
   
4.     Dim sou As Range, des As Range
   
5.     '
   
6.     Set sou = Sheets(1).[a1].CurrentRegion
   
7.     Call DelPt(Sheets(2).[a1])
   
8.     '1）数据透视表对象
   
9.     Set des = Sheets(2).[a1]
   
10.     Set pt = des.Parent.Parent.PivotTableWizard(xlDatabase, sou, des)
    
11.     With pt
    
12.         .PivotFields("商品代码").Orientation = xlRowField    '行字段
    
13.         .PivotFields("品名").Orientation = xlRowField
    
14.         .PivotFields("客户名称").Orientation = xlColumnField    '列字段
    
15.         .PivotFields("数量").Orientation = xlDataField    '数据字段
    
16.         .PivotFields("商品代码").Subtotals(1) = False    '隐藏分类汇总
    
17.     End With
    
18. End Sub

复制代码

爱疯

taller 发表于 2019-1-31 13:56
删除透视表导致des对象不存在，所有产生错误

2.rar (21.38 KB, 下载次数: 9)

2019-1-31 14:30 上传

点击文件名下载附件

谢谢 taller 版主！
2楼代码，没再报错了。


Debug.Print des Is Nothing
这么测，总返回false。即无论是删除时，还是创建时，des总是存在的。不知这么理解对吗？


“删除透视表导致des对象不存在”，请问怎样可证实这个解释。

taller

如果套用类的概念来解释的话，就是des对象的实例化的实体不存在了，所以无法继续访问这个对象。

单步执行代码，删除透视表后，在VBE的本地窗口中，你可以看到sou和des两个对象的区别

爱疯

taller 发表于 2019-1-31 15:42
如果套用类的概念来解释的话，就是des对象的实例化的实体不存在了，所以无法继续访问这个对象。

单步执 ...

Sub test3()
    Dim des As Range
    Debug.Print "引用前", VBA.IsEmpty(des) '指出变量是否已经初始化。
    Set des = Range("a1")
    Debug.Print "引用后", VBA.IsEmpty(des)
    des.Delete
    Debug.Print "删除后", VBA.IsEmpty(des)
    des = 1
End Sub



学习了，1楼和这例子的错误原因一样
对此，本题delete改为clear也行，从而确保des所引用的对象实例仍存在。
另外，判断方式 换成 isempty()可发现当删除对象后des的变化。
只是又看了下nothing的帮助，还是感觉nothing可以（当然已证明这个感觉是错的了）

taller

爱疯 发表于 2019-1-31 16:40
Sub test3()
    Dim des As Range
    Debug.Print "引用前", VBA.IsEmpty(des) '指出变量是否已经初 ...

似乎没法用VBA提供的Isxxx函数判断这个状态，只能用错误捕获推测

爱疯

taller 发表于 2019-2-1 01:04
似乎没法用VBA提供的Isxxx函数判断这个状态，只能用错误捕获推测

Sub test4()
    Dim des As Range
    Set des = Range("a1")
    des.Delete
    If VBA.IsEmpty(des) Then des = 1
End Sub


如果目的只是为判断使用delete方法后对象变量的引用，这样判断有什么不妥吗？