ON ERROR GOTO在一个过程里只能用一次吗？

alstar

我写的这个代码判断了两次错误，第一次错误可以跳转，第二次错误跳转不了了。

请问有是没办法能实现多次错误跳转吗？

huang1314wei

看你要跳转什么

alstar

huang1314wei 发表于 2018-7-18 17:32
看你要跳转什么

就是跳转到一个msgbox
第一次错误跳转到一个msgbox提示，
之后继续往下运行，如果第二次错误在跳转到第二个msgbox

huang1314wei

alstar 发表于 2018-7-18 17:40
就是跳转到一个msgbox
第一次错误跳转到一个msgbox提示，
之后继续往下运行，如果第二次错误在跳转到第 ...

你能把你的代码发上来或者发个附件吗，你这样描述没有实际意义啊

alstar

huang1314wei 发表于 2018-7-18 17:59
你能把你的代码发上来或者发个附件吗，你这样描述没有实际意义啊

Sub 新建工作表()
star1:
    Dim gzb As Worksheet
    Dim i As Integer
    Sheets("隐藏模板").Visible = True
    Sheets("隐藏模板").Copy BEFORE:=Sheet5
    Set gzb = ActiveSheet
    On Error GoTo 99
    gzb.Name = Application.Text(Now, "M月")
    gzb.Range("A3") = "日期： " & Application.Text(Now, "YYYY年M月")
    Sheets("隐藏模板").Visible = 2
    On Error GoTo 98
    Sheets(Month(Now()) - 1 & "月").Range("F40:V40").Copy Sheets(Month(Now()) & "月").Range("F8")
    MsgBox Application.Text(Now, "M月") & "创建完毕"
    End
99
   Application.DisplayAlerts = False
   ActiveSheet.Delete
   Application.DisplayAlerts = True
   Sheets("隐藏模板").Visible = 2
      y = MsgBox(Application.Text(Now, "M月") & "工作表已存在,是否删除重新创建工作表", 4)
    If y = 6 Then
        Application.DisplayAlerts = False
        Sheets(Application.Text(Now, "M月")).Delete
        Application.DisplayAlerts = True
        GoTo star1
    End If
98
    MsgBox Sheets(Month(Now()) - 1 & "月") & "工作表不存在"
End Sub

大佬，我刚学VBA没几天，逻辑思维没有那么强，或许我写的太绕了。。

chis3

用 on error resume next 配合
if err.number > 0
後再err.clear

alstar

chis3 发表于 2018-7-18 22:54
用 on error resume next 配合
if err.number > 0
後再err.clear

大佬，能举个栗子不，我试了一下，夭折了。。不知道是语法有问题还是哪的问题。。

jiangxiaoyun

if判断一下工作表是否存在，然后执行对应的操作就可以了吧。尽量不要用这个跳转语句啊。
该函数接收一个参数（工作表名称）。如果活动工作簿包含这个工作表，则返回True
Private Function SheetExists(sname) As Boolean
'   Returns TRUE if sheet exists in the active workbook
    Dim x As Object
    On Error Resume Next
    Set x = ActiveWorkbook.Sheets(sname)
    If Err = 0 Then SheetExists = True _
        Else SheetExists = False
End Function
该函数接收一个参数（工作簿名称）。如果打开了这个工作簿，则返回True
Private Function WorkbookIsOpen(wbname) As Boolean
'   Returns TRUE if the workbook is open
    Dim x As Workbook
    On Error Resume Next
    Set x = Workbooks(wbname)
    If Err = 0 Then WorkbookIsOpen = True _
        Else WorkbookIsOpen = False
End Function

zopey

Sub 按钮1_Click() On Error GoTo err1 For i = 1 To 5    a = 1 / (i - 3) Next Exit Sub err1:     MsgBox i     Resume Next End Sub

zopey

Sub Sheet2_按钮1_Click()

On Error GoTo err1
For i = 1 To 5
   a = 1 / (i - 3)
Next

On Error GoTo err2
For i = 1 To 5
   a = 1 / (i - 3)
Next

Exit Sub

err1:
    MsgBox i
    Resume Next
   
err2:
    MsgBox i + 100
    Resume Next
End Sub