提取编号

hopeson2010 · 发表于 2018-6-8 00:23

=VLOOKUP("*-*-*-*-??",MID(A2,FIND("ZB",A2),ROW($1:$30)),1,)

复制代码

数组公式按 ctrl+shift+回车三键结束

ljxxw · 发表于 2018-6-9 21:55

hopeson2010 发表于 2018-6-8 00:23
数组公式按 ctrl+shift+回车三键结束

谢谢 hopeson2010 老师提示数组公式按 ctrl+shift+回车三键结束，难怪我前面试不出来！

ljxxw · 发表于 2018-6-9 22:21

本帖最后由 ljxxw 于 2018-6-9 22:23 编辑

micch 发表于 2018-6-7 22:53

谢谢 micch 老师，开始我不知道是数组公式，所以没测试成功，现在可以了。
您跟其他老师的公式有个更好特点，在第四个-后面，如果不止2位，比如ZB-FHJ-XS689-878804-07998，其他公式只能取到07，不能取出07998，您的就可以，能请教您公式的思路吗？
可能我示例文件第四个-后面都是2位，其他老师也没多考虑，但真实的数据有不止2位的！

micch · 发表于 2018-6-9 22:36

本帖最后由 micch 于 2018-6-9 22:39 编辑

ljxxw 发表于 2018-6-9 22:21
谢谢 micch 老师，开始我不知道是数组公式，所以没测试成功，现在可以了。
您跟其他老师的公式有个更好 ...

晕，我都忘了，还得自己再看一遍

主要是你的数据例子有什么特点老师就根据特点选最简单的公式，所以应该把特殊情况都列上。

我的公式也不一定通用，我是假设要提取的字符串都是在第一个左括号开始
定位第一个左括号，用mid取左括号右侧所有字符，然后用left取需要的字符串，left取多长，根据第一个汉字的位置来决定。用match(2,lenb(..........来查找字符串后面第一个汉字的位置。
其实核心就是定位要提取字符的开始位置和结束位置，需要根据数据的实际情况来设公式
如果没有左括号，或者左括号不是第一个，或者不挨着要提取的字符，这个公式也不适用。所以具体还是要看你数据的特点

ljxxw · 发表于 2018-6-9 22:43

micch 发表于 2018-6-9 22:36
晕，我都忘了，还得自己再看一遍

主要是你的数据例子有什么特点老师就根据特点选最简单的公式，所以应 ...

公式里的 +10,99 什么意思？
比如我改成 +2,99时，“公司开发票（ZB-FHJ-XS689-878804-07998波项目部）”提取出来是“ZB-FHJ-XS689-8788”了

micch · 发表于 2018-6-9 22:49

micch 发表于 2018-6-7 22:53

=MIDB(REPLACE(A2,MATCH(2,LENB(MID(A2,ROW($11:$99),1)),)+10,99,""),SEARCHB("?",A2),99)

复制代码

这个方法是学老师的

用replace把字符串右侧的所有字符替换为空，开始位置还是用MATCH(2.....定位；
然后剩下的字符串，searchb定位字符开始的位置，因为例子里字符串前面都是汉字，括号也是中文的括号。定位后用mid取到字符串

ljxxw · 发表于 2018-6-10 19:02

本帖最后由 ljxxw 于 2018-6-10 19:10 编辑

micch 发表于 2018-6-9 22:49
这个方法是学老师的

用replace把字符串右侧的所有字符替换为空，开始位置还是用MATCH(2.....定位 ...

再请教公式如何改，比如“西南河流治理疏浚设备有限公司（XB-AQGJ-QQ-201205-076）” 取数出来是空白，详见附件

ljxxw · 发表于 2018-6-10 19:15

laowuwyx 发表于 2018-6-7 22:23
由于查找最后一个数字不但繁琐，而且此题行不通，倒是可以查找第四个“-”的位置，再加上2就是需要提取的 ...

请教 laowuwyx 老师，如果第四个-后面不止2位有多位，比如“公司开发票（ZB-FHJ-XS689-878804-07998波项目部）”，提取出来是ZB-FHJ-XS689-878804-07不全，您的公式能改一下吗。

micch · 发表于 2018-6-10 19:20

ljxxw 发表于 2018-6-10 19:02
再请教公式如何改，比如“西南河流治理疏浚设备有限公司（XB-AQGJ-QQ-201205-076）” 取数出来是空白，详 ...

=LEFT(MID(A6,FIND("（",A6)+1,99),MATCH(2,LENB(MID(MID(A6,FIND("（",A6)+1,99)&"吖",ROW($1:$99),1)),)-1)

复制代码

所以还是这个公式通用一些

micch · 发表于 2018-6-10 19:25

=LEFT(MIDB(A6,SEARCHB("?",A6),99),MATCH(2,LENB(MID(MID(A6,FIND("（",A6)+1,99)&"吖",ROW($1:$99),1)),)-1)

复制代码

或者这个公式。公式先查找第一个英文字符，作为开始，以要提取的字符串后第一个非英文字符为结束来定位。

如果前面有英文字符，或者字符串后面不是非英文字符，那就出错了。

所以还是要看源字符串到底有什么共同的特点，然后设置公式

		自动登录	找回密码
密码			免费注册

[求助] 提取编号

浏览过的版块