小txt可以打开，行数多的为什么出现错误？

dreamweavemx

用以下代码，找开test2是可以的，但行数多的test1就出现错误。请问是什么原因。


Sub Open方法()
    Dim d, i, sr$, temp
    Dim filter As String
    Dim fileToOpen

    filter = "Text Files(*.txt),*.txt "
    fileToOpen = Application.GetOpenFilename(filefilter:=filter, FilterIndex:=2, Title:="请选择文件")       '打开文件

    Set d = CreateObject("scripting.dictionary")      '引用字典
    With Sheets("sheet2")
        .UsedRange.ClearContents            '清除原有的数据
        i = 1
        Open fileToOpen For Input As #1     '使用open语句输入
        Do While Not EOF(1)   '运行到文件的结尾结束
            Line Input #1, sr            '按行读取数据
            If Len(sr) Then
            d(i) = Split(sr, "_")        '以_分割字符串
            i = i + 1
            End If
        Loop
        Close #1              '关闭文本文件
        temp = Application.Transpose(d.Items)    '转置字典的项
        .Range("a1").Resize(d.Count, UBound(temp)) = Application.Transpose(temp)     '将数组写入单元格
    End With
    Set d = Nothing
End Sub

dreamweavemx

那位兄弟能帮忙看看。

xiaocake

Option Explicit
Sub mydiag()
    Application.FileDialog(msoFileDialogFilePicker).Show
End Sub

Sub Open方法()
    Dim d, ky, i, sr$, temp
    Dim filter As String
    Dim fileToOpen
    filter = "Text Files(*.txt),*.txt "
    fileToOpen = Application.GetOpenFilename(filefilter:=filter, FilterIndex:=2, Title:="请选择文件")       '打开文件
    Set d = CreateObject("scripting.dictionary")      '引用字典
    With Sheets("sheet2")
        .UsedRange.ClearContents            '清除原有的数据
        i = 1
        Open fileToOpen For Input As #1     '使用open语句输入
        Do While Not EOF(1)          '运行到文件的结尾结束
            Line Input #1, sr        '按行读取数据
            If Len(sr) > 0 Then
                ky = Split(sr, "_", 2)(0)
                d(ky) = Split(sr, "_")(1) & "," & Split(sr, "_")(2)   '以,连接服务器名称和人名
                'Debug.Print ky & " : " & d(ky)
                i = i + 1
            End If
        Loop
        Close #1   '关闭文本文件
        .Range("a1").Resize(d.Count, 1) = Application.Transpose(d.keys)     '将IP写入单元格
        i = 1
        For Each ky In d.keys  '将服务器名称及人名写入表格
            Cells(i, "B").Resize(1, 2) = Split(d(ky), ",")
            i = i + 1
        Next
    End With
    Set d = Nothing
End Sub

xiaocake

xiaocake 发表于 2018-3-23 13:18
Option Explicit
Sub mydiag()
    Application.FileDialog(msoFileDialogFilePicker).Show

Split可以直接指定将字符串分成几段，所以代码改写成下面这样，比上面代码少一个字符串连接的过程
    With Sheets("sheet2")
        .UsedRange.ClearContents            '清除原有的数据
        i = 1
        Open fileToOpen For Input As #1     '使用open语句输入
        Do While Not EOF(1)      '运行到文件的结尾结束
            Line Input #1, sr        '按行读取数据
            If Len(sr) > 0 Then
                ky = Split(sr, "_", 2)(0)      '将每一行用 _ 分为2段,第一段是IP
                d(ky) = Split(sr, "_", 2)(1)   '第二段是服务器名和人名
                'Debug.Print ky &  " : " & d(ky)
                i = i + 1
            End If
        Loop
        Close #1   '关闭文本文件
        .Range("a1").Resize(d.Count, 1) = Application.Transpose(d.keys)     '将IP写入单元格
        i = 1
        For Each ky In d.keys  '将服务器名称及姓名分离后写入表格
            Cells(i, "B").Resize(1, 2) = Split(d(ky), "_")
            i = i + 1
        Next
    End With