查找指定颜色的某字符替换为另外指定颜色的某字符

13907933959 · 发表于 2017-2-21 13:05

本帖最后由 13907933959 于 2017-2-25 10:35 编辑

1、只把红色突出显示的▲，替换为蓝色突出显示的★。

2、只把红色、黄色突出显示的▲，替换为粉红色突出显示的★。

求前辈们赐教，谢谢！

模拟附件：

413191246se · 发表于 2017-2-22 12:57

Sub 查找红色突出显示替换为蓝色突出显示()
With ActiveDocument.Content.Find
.Highlight = True
Do While .Execute
If .Parent.HighlightColorIndex = wdRed Then
.Parent.Font.Color = wdColorWhite
.Parent.HighlightColorIndex = wdBlue
.Parent = Replace(.Parent, "▲", "★")
.Parent.Underline = wdUnderlineWavyHeavy '突出显示字体下划线：重波浪线----此语句可删除！
End If
Loop
End With
End Sub
Sub 查找红色黄色突出显示替换为粉红色突出显示()
With ActiveDocument.Content.Find
.Highlight = True
Do While .Execute
If .Parent.HighlightColorIndex = wdRed Or .Parent.HighlightColorIndex = wdYellow Then
.Parent.Font.Color = wdColorAutomatic '突出显示字体颜色：自动色----此语句可删除！
.Parent.Font.Name = "黑体" '突出显示字体名称：黑体----此语句可删除！
.Parent.HighlightColorIndex = wdPink '突出显示颜色：粉红色
.Parent = Replace(.Parent, "▲", "★")
.Parent.Underline = wdUnderlineDouble '突出显示字体下划线：双线----此语句可删除！
End If
Loop
End With
End Sub

复制代码

13907933959 · 发表于 2017-2-22 14:47

413191246se 发表于 2017-2-22 12:57

师傅好！
感谢师傅！
师傅您可能误判了我的意思，我是把指定颜色的指定字符，替换为另一指定颜色的指定字符，也就是：
1、只把红色突出显示的▲，替换为蓝色突出显示的★。
2、只把红色、黄色突出显示的▲，替换为粉红色突出显示的★。

413191246se · 发表于 2017-2-23 12:26

原来如此！那这样的话，就变成了《查找文字》宏，用杜先生代码套一下就 OK 了！

Sub 查找红色突出显示字符替换为蓝色突出显示字符()
Dim i As Paragraph, mt, oRang As Range, n%, m%
With CreateObject("vbscript.regexp")
.Pattern = "▲"
.Global = True: .IgnoreCase = False: .MultiLine = True
For Each i In ActiveDocument.Paragraphs
For Each mt In .Execute(i.Range.Text)
m = mt.FirstIndex: n = mt.Length
Set oRang = ActiveDocument.Range(i.Range.Start + m, i.Range.Start + m + n)
With oRang
If .HighlightColorIndex = wdRed Then
.HighlightColorIndex = wdBlue
.Text = "★"
.Font.Color = wdColorWhite
End If
End With
Next
Next
End With
End Sub
Sub 查找红色黄色突出显示字符替换为粉红色突出显示字符()
Dim i As Paragraph, mt, oRang As Range, n%, m%
With CreateObject("vbscript.regexp")
.Pattern = "▲"
.Global = True: .IgnoreCase = False: .MultiLine = True
For Each i In ActiveDocument.Paragraphs
For Each mt In .Execute(i.Range.Text)
m = mt.FirstIndex: n = mt.Length
Set oRang = ActiveDocument.Range(i.Range.Start + m, i.Range.Start + m + n)
With oRang
If .HighlightColorIndex = wdRed Or .HighlightColorIndex = wdYellow Then
.HighlightColorIndex = wdPink
.Text = "★"
.Font.Color = wdColorYellow
End If
End With
Next
Next
End With
End Sub

复制代码

13907933959 · 发表于 2017-2-23 15:11

413191246se 发表于 2017-2-23 12:26
原来如此！那这样的话，就变成了《查找文字》宏，用杜先生代码套一下就 OK 了！

师傅好！
现在OK了！师傅辛苦了！徒弟拜谢师傅！！！
另外、这些代码，看不懂，也查不到，师傅如有时间，想求您注释一下，（大概的意思即可）。

.Global = True: .IgnoreCase = False: .MultiLine = True
For Each mt In .Execute(i.Range.Text)
m = mt.FirstIndex: n = mt.Length
Set oRang = ActiveDocument.Range(i.Range.Start + m, i.Range.Start + m + n)
With oRang
――――――――――――――――――――――――――――――――――――――――――
Auto1
Dim apar As Paragraph
Dim i As Section
Dim i As String
Dim i As Shape
Dim i As Frame
Dim i As Section, j As Long, k As Long
Dim i As Long, j As Long
Dim x As String, y As String
For Each i In ActiveDocument.Frames
For Each i In ActiveDocument.Sections
With i.PageSetup
With .Borders
With Options
With t
With .Rows
With .Range
With .Borders
ctn:
Cont:
Selection.Paste

413191246se · 发表于 2017-2-24 01:21

139：虚线上面的语句，是杜先生（duquancai）的《正则表达式》中的语句，你不理解，我也不理解，英文意思虽懂，但属于正则表达式方面的专门语句，咱们就不必深究了！
Dim语句是声明语句，For Each...Next是循环遍历集合的语句，With后面加点的是属性，但不要光看它，还要看它前面的是属性还是对象……
我强烈建议你——每天学一点《微软官方VBA帮助》，就当换换脑筋了（因为天天学中医，偶尔抽出一小块时间学一下VBA入门知识，应该不错）。

13907933959 · 发表于 2017-2-24 10:40

413191246se 发表于 2017-2-24 01:21
139：虚线上面的语句，是杜先生（duquancai）的《正则表达式》中的语句，你不理解，我也不理解，英文意思 ...

师傅好！
好的、有时间尽量看，因自已在这方面属于零基础，主要是一二下看不懂，看不懂的东西就很难记住，前面看了过几天又不记得了，我又没有太多的时间能用在这上面，再一个来家里和中医师傅的压力，使心也不能很静下来学它，导致接触了这么长时间VBA，还是什么都不懂，实在是愧对师傅！还请师傅见谅！！！

师傅、昨天忙了、忘了问，这个查找替换“突出显示”指定的字符，我看您用的代码多了很多，像指定的字符替换字体颜色，4、5行代码就能解决，是不是替换“突出显示”指定的字符比较复杂的原因？

413191246se · 发表于 2017-2-24 11:06

前晚，我也是按照查找突出显示字符来处理的，昨天发现，其实就是普通的查找文字而已，找到后要处理，但是找到的“▲”号需要判断它的突出显示背景色，是红色才换成“★”号；至于上面的语句，是因为杜先生的正则表达式语句多了点，但查找速度比VBA查找速度还是快了不少。——我特意测试了一下大文档：杜先生正则表达式平均处理时间0.86秒，而普通VBA查找平均处理时间1.16秒，还是杜先生正则表达式完胜！（还有，我的Word2003通用模板里面有 3 个杜先生的代码应用，都是因为测试后杜先生的正则表达式胜出！但如果是超大规模文档，正则也慢了。）

13907933959 · 发表于 2017-2-25 06:44

本帖最后由 13907933959 于 2017-2-25 09:40 编辑

413191246se 发表于 2017-2-24 11:06
前晚，我也是按照查找突出显示字符来处理的，昨天发现，其实就是普通的查找文字而已，找到后要处理，但是找 ...

师傅好！
啊！是这样！我以为按普通的文字查找，不能把指定颜色指定字符的突出显示，替换为另一指定颜色指定字符的突出显示，师傅的意思是按普通的文字查找也能找到替换，只是速度上没有杜前辈用的正则表达式快，是吧？

师傅、我想让您再提供一个按普通的文字查找“指定颜色指定字符的突出显示，替换为另一指定颜色指定字符的突出显示”的宏，以便以后可用，我的水平师傅知道，对普通的文字查找的代码都只能看懂一点点，杜前辈用的正则表达式查找好是真好！可我一点都看不懂，又找不到相应的中文注释，真希望论坛上的代码都带有中文注释！

413191246se · 发表于 2017-2-25 13:24

139：杜先生的代码，正则表达式我也看不懂，但是，它里面变量 oRange 是 Range 变量，即“区域”变量，不是 Selection 变量——Range变量找到后光标是不动的，原来在哪里现在还在哪里，而 Selection变量找到后光标是移动的，但一般来说，用 Range变量是比 Selection变量快。

Sub 查找文字_红色突出显示转为蓝色突出显示_解释()
With ActiveDocument.Content.Find '活动文档全文查找
.ClearFormatting '清除格式
Do While .Execute(findtext:="▲", Forward:=True) '循环查找：.Execute方法（查找内容，查找方向：向下）
With .Parent '父对象
If .HighlightColorIndex = wdRed Then '如果,突出显示高亮颜色索引值=红色,则
.HighlightColorIndex = wdBlue '突出显示高亮颜色索引值=蓝色
.Font.Color = wdColorWhite '字体颜色=白色(此语句为了显示效果清晰,故设为白色)
.Text = "★" '文本值被赋值为五角星
.Collapse wdCollapseEnd '折叠到对象末尾(相当于向右移动一个字符)
End If
End With
Loop '循环控制语句结束
End With
End Sub
Sub 查找文字_红色突出显示转为蓝色突出显示()
With ActiveDocument.Content.Find
.ClearFormatting
Do While .Execute(findtext:="▲", Forward:=True)
With .Parent
If .HighlightColorIndex = wdRed Then
.HighlightColorIndex = wdBlue
.Font.Color = wdColorWhite
.Text = "★"
.Collapse wdCollapseEnd
End If
End With
Loop
End With
End Sub

复制代码

		自动登录	找回密码
密码			免费注册

[求助] 查找指定颜色的某字符替换为另外指定颜色的某字符