ppt学习资料

weiyingde

PublishObject对象
Presentation
PublishObjects (PublishObject)
代表已加载 PowerPoint 中且可作为 HTML 格式发布的整个或部分演示文稿。PublishObject对象是PublishObjects集合中的成员。
使用 PublishObject对象
使用 PublishObjects(index) 可返回一个对象，该对象代表了所加载的演示文稿，其中，index 的值总为“1”。对于每个加载的演示文稿，只能有一个 PublishObject对象与之对应。本示例将第二篇演示文稿中的第三张幻灯片到第五张幻灯片作为 HTML 格式发布。发布的演示文稿名为“Mallard.htm”。
With Presentations(2).PublishObjects(1)
    .FileName = "C:\Test\Mallard.htm"
    .SourceType = ppPublishSlideRange
    .RangeStart = 3
    .RangeEnd = 5
    .Publish
End With
说明
可以通过设置 PublishObject对象的不同属性值来指定所发布的演示文稿的内容和属性。例如，SourceType属性用于定义加载的演示文稿中需要进行发布的部分。RangeStart属性和RangeEnd属性用于指定要发布的幻灯片的范围，而SpeakerNotes属性则用于指定是否发布演讲者备注。
PublishObjects集合对象
Presentation
PublishObjects (PublishObject)
PublishObject对象的集合，它代表整个或部分已加载演示文稿的集合，这些演示文稿可作为 HTML 进行发布。
使用 PublishObjects集合
使用 PublishObjects属性可返回 PublishObjects集合。本示例将当前演示文稿的第三张到第五张幻灯片作为 HTML 进行发布。本示例将发布的演示文稿命名为“Mallard.htm”。
With ActivePresentation.PublishObjects(1)
    .FileName = "C:\Test\Mallard.htm"
    .SourceType = ppPublishSlideRange
    .RangeStart = 3
    .RangeEnd = 5
    .Publish
End With
使用 Item(index) 可为所加载的演示文稿返回一个 PublishObject对象，其中，index 的值总为“1”。对于每个加载的演示文稿，只能有一个对应的 PublishObject对象。
本示例通过将 SourceType 设置为 ppPublishAll 值，可以将 PublishObject对象定义为整个的当前演示文稿。
ActivePresentation.PublishObjects.Item(1).SourceType = ppPublishAll
说明
可以通过设置 PublishObject对象的不同属性值来指定所发布的演示文稿的内容和属性。例如，SourceType属性用于定义加载的演示文稿中需要进行发布的部分。RangeStart属性和RangeEnd属性用于指定要发布的幻灯片的范围，而SpeakerNotes属性则用于指定是否发布演讲者备注。
不能添加到 PublishObjects集合中。
RGBColor对象
ColorScheme
RGBColor
代表配色方案中的一种颜色。
使用 RGBColor对象
使用Colors方法可返回一个RGBColor对象。可以将一个 RGBColor对象赋给另一个 RGBColor对象。可使用RGB属性设置或返回 RGBColor对象的显式红-绿-蓝值（对于由 ppNotSchemeColor 和 ppSchemeColorMixed 常数定义的 RGBColor对象除外，这两个对象的 RGB属性可被返回，但不可设置）。以下示例将当前演示文稿配色方案的背景色设为红色，并将标题颜色设为第二个配色方案中定义的标题颜色。
With ActivePresentation.ColorSchemes
    .Item(1).Colors(ppBackground).RGB = RGB(255, 0, 0)
    .Item(1).Colors(ppTitle) = .Item(2).Colors(ppTitle)
End With

weiyingde

RotationEffect对象
AnimationBehavior
RotationEffect

代表AnimationBehavior对象的旋转效果。
使用 RotationEffect对象
使用 AnimationBehavior对象的RotationEffect属性返回 RotationEffect对象。以下示例引用了给定动画动作的旋转效果。
ActivePresentation.Slides(1).TimeLine.MainSequence.Item.Behaviors(1).RotationEffect
使用 RotationEffect对象的By、From 和To属性影响对象的动画旋转。以下示例向第一张幻灯片添加新的形状并设置旋转动画动作。
Sub AddRotation()
    Dim shpNew As Shape
    Dim effNew As Effect
    Dim aniNew As AnimationBehavior
    Set shpNew = ActivePresentation.Slides(1).Shapes _
        .AddShape(Type:=msoShape5pointStar, Left:=0, _
        Top:=0, Width:=100, Height:=100)
    Set effNew = ActivePresentation.Slides(1).TimeLine.MainSequence _
        .AddEffect(Shape:=shpNew, effectId:=msoAnimEffectCustom)
    Set aniNew = effNew.Behaviors.Add(msoAnimTypeRotation)
    With aniNew.RotationEffect
        'Rotate 270 degrees from current position
        .By = 270
    End With
End Sub
Row对象
Table
Rows (Row)
  CellRange (Cell)
代表表格中的一行。Row对象是Rows集合中的成员。Rows集合中包含指定表格中的所有行。
使用 Row对象
使用 Rows(index) 可返回一个 Row对象，其中，index 是一个数字，它代表表格中行所在的位置。本示例删除表格（当前演示文稿中第二张幻灯片上的第五个形状）中的第一行。
ActivePresentation.Slides(2).Shapes(5).Table.Rows(1).Delete
使用Select方法可从表格中选择一行。本示例选择指定表格中的第一行。
ActivePresentation.Slides(2).Shapes(5).Table.Rows(1).Select
说明
使用Cells属性可修改 Row对象中的各个单元格。本示例选择表格中的第二行，并对其下框线应用虚线样式。
ActiveWindow.Selection.ShapeRange.Table.Rows(2) _
    .Cells.Borders(ppBorderBottom).DashStyle = msoLineDash

weiyingde

Rows集合对象
Table
Rows (Row)
  CellRange (Cell)
Row对象的集合，代表表格中的行。
使用 Rows集合
使用Rows属性可返回 Rows集合。本示例把指定表格中所有行的高度更改为 160 磅。
Dim i As Integer
With ActivePresentation.Slides(2).Shapes(4).Table
    For i = 1 To .Rows.Count
        .Rows.Height = 160
    Next i
End With
使用Add方法可向表格中添加一行。本示例在被引用表格的第二行之前插入一个新行。
ActivePresentation.Slides(2).Shapes(5).Table.Rows.Add (2)
使用 Rows(index) 可返回一个 Row对象，其中，index 是一个数字，它代表表格中行所在的位置。本示例将删除表格（第二张幻灯片上的第五个形状）中的第一行。
ActivePresentation.Slides(2).Shapes(5).Table.Rows(1).Delete
Ruler对象
多个对象
Ruler
  RulerLevels (RulerLevel)
  TabStops (TabStop)
代表指定形状或指定样式中所有文本的标尺。包含大纲文本的制表位和缩进设置。
使用 Ruler对象
使用 TextFrame对象的Ruler属性返回代表指定形状中文本标尺的 Ruler对象；使用TabStops属性返回 TabStops对象，其中包含标尺中的制表位。使用Levels属性返回 RulerLevels对象，该对象包含大纲文本的缩进设置。以下示例在 2 英寸（144 磅）处设置一个左对齐的制表位，并为当前演示文稿第一张幻灯片第二个对象中的文本设置悬挂式缩进。
With ActivePresentation.Slides(1).Shapes(2).TextFrame.Ruler
    .TabStops.Add ppTabStopLeft, 144
    .Levels(1).FirstMargin = 0
    .Levels(1).LeftMargin = 36
End With
使用 TextStyle对象的Ruler属性返回 Ruler对象，该对象代表四种定义文本样式之一（标题文本、正文文本、备注文本、默认文本）的标尺。以下示例设置当前演示文稿幻灯片母版正文文本第一级大纲的首行缩进和悬挂式缩进。
With ActivePresentation.SlideMaster _
        .TextStyles(ppBodyStyle).Ruler.Levels(1)
    .FirstMargin = 9
    .LeftMargin = 54
End With
RulerLevel对象
Ruler
RulerLevels (RulerLevel)
包含大纲的首行缩进和悬挂式缩进信息。RulerLevel对象是RulerLevels集合的成员。RulerLevels集合包含五个可用大纲级别中每个级别的 RulerLevel对象。

使用 RulerLevel对象
使用 RulerLevels(index) 返回单个 RulerLevel对象，其中 index 为大纲级别。以下示例设置当前演示文稿幻灯片母版正文文本第一级大纲的首行缩进和悬挂式缩进。
With ActivePresentation.SlideMaster _
        .TextStyles(ppBodyStyle).Ruler.Levels(1)
    .FirstMargin = 9
    .LeftMargin = 54
End With
以下示例设置当前演示文稿第二个形状（第一张幻灯片中）第一级大纲的首行缩进和悬挂缩进。
With ActivePresentation.SlideMaster.Shapes(2) _
        .TextFrame.Ruler.Levels(1)
    .FirstMargin = 9
    .LeftMargin = 54
End With
RulerLevels集合对象
Ruler
RulerLevels (RulerLevel)
指定标尺上所有RulerLevel对象的集合。每个 RulerLevel对象代表特定大纲级别上文本的首行缩进和左缩进。该集合通常包含五个成员（每个可用大纲级别各一个）。
使用 RulerLevels集合
使用Levels属性返回 RulerLevels集合。以下示例设置当前演示文稿正文文本五级大纲的页边距。
With ActivePresentation.SlideMaster.TextStyles(ppBodyStyle).Ruler
    .Levels(1).FirstMargin = 0
    .Levels(1).LeftMargin = 40
    .Levels(2).FirstMargin = 60
    .Levels(2).LeftMargin = 100
    .Levels(3).FirstMargin = 120
    .Levels(3).LeftMargin = 160
    .Levels(4).FirstMargin = 180
    .Levels(4).LeftMargin = 220
    .Levels(5).FirstMargin = 240
    .Levels(5).LeftMargin = 280
End With

weiyingde

ScaleEffect对象
AnimationBehavior
ScaleEffect

代表AnimationBehavior对象的缩放效果。
使用 ScaleEffect对象
使用 AnimationBehavior 对象的ScaleEffect属性返回 ScaleEffect对象。以下示例引用了给定动画动作的缩放效果。
ActivePresentation.Slides(1).TimeLine.MainSequence.Item.Behaviors(1).ScaleEffect
使用 ScaleEffect对象的ByX、ByY、FromX、FromY、ToX 和ToY属性操纵对象的缩放。本示例对第一张幻灯片中的第一个形状进行缩放，该形状由零开始增长至其初始大小的 100%。本示例假定第一张幻灯片中有一个形状。
Sub ChangeScale()
    Dim shpFirst As Shape
    Dim effNew As Effect
    Dim aniScale As AnimationBehavior
    Set shpFirst = ActivePresentation.Slides(1).Shapes(1)
    Set effNew = ActivePresentation.Slides(1).TimeLine.MainSequence _
        .AddEffect(Shape:=shpFirst, effectId:=msoAnimEffectCustom)
    Set aniScale = effNew.Behaviors.Add(msoAnimTypeScale)
    With aniScale.ScaleEffect
        'Starting size
        .FromX = 0
        .FromY = 0
        'Size after scale effect
        .ToX = 100
        .ToY = 100
    End With
End Sub
Selection对象
DocumentWindows (DocumentWindow)
Selection
  ShapeRange (Shape)
  SlideRange (Slide)
  TextRange
代表指定文档窗口中的选中对象。
使用 Selection对象
使用Selection属性返回 Selection对象。以下示例将当前窗口中的选中对象复制到剪贴板。
ActiveWindow.Selection.Copy
使用ShapeRange、SlideRange 或TextRange属性从选中的对象返回一系列形状、幻灯片或文本。
以下示例设置第二个窗口中选中形状的前景色，假设至少选中了一个形状且所有选中的形状具有可以改变前景色的填充。
With Windows(2).Selection.ShapeRange.Fill
    .Visible = True
    .ForeColor.RGB = RGB(255, 0, 255)
End With
如果第二个窗口中的第一个选中形状包含一文本框，以下示例设置其中的文本。
With Windows(2).Selection.ShapeRange(1)
    If .HasTextFrame Then
        .TextFrame.TextRange = "Current Choice"
    End If
End With
以下示例剪切当前窗口中选中的文本，将其放到剪贴板。
ActiveWindow.Selection.TextRange.Cut
以下示例复制选中的所有幻灯片（如果位于幻灯片视图，则复制当前幻灯片）。
ActiveWindow.Selection.SlideRange.Duplicate
如果使用这些属性时而没有选中合适类型对象（例如，在没有选中形状的情况下使用 ShapeRange属性），则会发生错误。请使用Type属性判断选中对象的类型。以下示例检查选中的对象中是否包含幻灯片。如果其中包含幻灯片，该示例设置其中第一个选中幻灯片的背景色。
With Windows(2).Selection
    If .Type = ppSelectionSlides Then
        With .SlideRange(1)
            .FollowMasterBackground = False
            .Background.Fill.PresetGradient _
                msoGradientHorizontal, 1, msoGradientLateSunset
        End With
    End If
End With
说明
在某一幻灯片视图中修改幻灯片时，Selection对象将被删除（Type属性将返回 ppSelectionNone）。

weiyingde

Sequence集合
Multiple对象
Sequence
  Effect
代表幻灯片交互式动画序列的Effect对象的集合。Sequence集合是Sequences集合的成员之一。
使用 Sequence集合
使用TimeLine对象的MainSequence属性返回 Sequence对象。
使用AddEffect方法添加新的 Sequence对象。本示例向当前演示文稿第一张幻灯片第一个形状中添加形状和动画序列。
Sub NewEffect()
    Dim effNew As Effect
    Dim shpFirst As Shape
    Set shpFirst = ActivePresentation.Slides(1).Shapes(1)
    Set effNew = ActivePresentation.Slides(1).TimeLine.MainSequence.AddEffect _
        (Shape:=shpFirst, effectId:=msoAnimEffectBlinds)
End Sub
Sequences集合
TimeLine
Sequences
  Sequence

代表Sequence对象的集合。使用 Sequence对象添加、查找、修改和复制动画效果。
使用 Sequences集合
使用TimeLine对象的InteractiveSequences属性返回 Sequences集合。使用Add方法添加交互式动画序列。以下示例向当前演示文稿的第一张幻灯片中添加两个形状并设置星形形状的交互式效果，这样在单击棱台形状时该星形形状会具有动画效果。
Sub AddNewSequence()
    Dim shp1 As Shape
    Dim shp2 As Shape
    Dim interEffect As Effect
    Set shp1 = ActivePresentation.Slides(1).Shapes.AddShape _
        (Type:=msoShape32pointStar, Left:=100, _
        Top:=100, Width:=200, Height:=200)
    Set shp2 = ActivePresentation.Slides(1).Shapes.AddShape _
        (Type:=msoShapeBevel, Left:=400, _
        Top:=200, Width:=150, Height:=100)
    With ActivePresentation.Slides(1).TimeLine.InteractiveSequences.Add(1)
        Set interEffect = .AddEffect(shp2, msoAnimEffectBlinds, _
            trigger:=msoAnimTriggerOnShapeClick)
        interEffect.Shape = shp1
    End With
End Sub

weiyingde

ShadowFormat对象
Shapes (Shape)
ShadowFormat
  ColorFormat
代表形状的阴影格式。
使用 ShadowFormat对象
使用 Shadow属性返回单个 ShadowFormat对象。以下示例向myDocument 中添加带有阴影的矩形。半透明的蓝色阴影印在该矩形的右边 5 磅和上面 3 磅。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes.AddShape(msoShapeRectangle, _
        50, 50, 100, 200).Shadow
    .ForeColor.RGB = RGB(0, 0, 128)
    .OffsetX = 5
    .OffsetY = -3
    .Transparency = 0.5
    .Visible = True
End With
Shape对象
多个对象
Shape
  多个对象
代表绘图层中的对象，例如自选图形、任意多边形、OLE对象或图片。
注意  共有三个代表形状的对象：Shapes集合，代表文档中的所有形状；ShapeRange集合，代表文档中指定的部分形状（例如，ShapeRange对象可以代表文档中的第一个和第四个形状，或代表文档中所有选定的形状）；Shape对象，代表文档中的单个形状。如果要同时使用多个形状或集合中的形状，请使用 ShapeRange集合。关于一次使用单个形状或多个形状的概述，请参阅使用形状（绘图对象）。
使用 Shape对象
本节描述如何：
按名称或编号索引，返回幻灯片中现有的形状。
返回幻灯片中新建的形状。
返回选定对象中的形状。
返回幻灯片中的幻灯片标题和其他占位符。
返回与连接符的端点相连的形状。
返回演示文稿的默认形状。
返回新建的任意多边形。
返回组中的单个形状。
返回新组成的形状组。
返回幻灯片中现有的形状
使用 Shapes(index) 返回一个代表幻灯片中形状的 Shape对象，其中 index 是形状名称或索引号。以下示例水平翻转 myDocument 中的第一个形状和形状 Rectangle 1。
Set myDocument = ActivePresentation.Slides(1)
myDocument.Shapes(1).Flip msoFlipHorizontal
myDocument.Shapes("Rectangle 1").Flip msoFlipHorizontal
每个添加到 Shapes集合的形状将被分配一个默认名称。若要赋予该形状一个更有意义的名称，请使用 Name属性。以下示例在 myDocument 中添加一个矩形，将其命名为 Red Square，并设置其前景色与线条样式。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes.AddShape(Type:=msoShapeRectangle, _
        Top:=144, Left:=144, Width:=72, Height:=72)
    .Name = "Red Square"
    .Fill.ForeColor.RGB = RGB(255, 0, 0)
    .Line.DashStyle = msoLineDashDot
End With
返回幻灯片中新建的形状
若要在幻灯片中添加形状并返回一个代表新建形状的 Shape对象，请使用 Shapes集合的下列方法之一：AddCallout、AddComment、AddConnector、AddCurve、AddLabel、AddLine、AddMediaObject、AddOLEObject、AddPicture、AddPlaceholder、AddPolyline、AddShape、AddTable、AddTextbox、AddTextEffect 和AddTitle。
返回选定对象中的形状
使用 Selection.ShapeRange(index) 返回一个代表选定对象中的形状的 Shape对象，其中 index 是形状名称或索引号。以下示例设置当前窗口中选定对象的第一个形状的填充（假定选中的对象中至少有一个形状）。
ActiveWindow.Selection.ShapeRange(1).Fill _
    .ForeColor.RGB = RGB(255, 0, 0)
返回幻灯片中的幻灯片标题和其他占位符
使用 Shapes.Title 返回代表幻灯片标题的 Shape对象。使用 Shapes.AddTitle 在无标题的幻灯片中添加标题并返回代表新建标题的 Shape对象。使用 Shapes.Placeholders(index) 返回一个代表占位符的 Shape对象，其中 index 是占位符的索引号。如果没有改变过幻灯片中形状的排列顺序，以下三句是等价的（假定第一张幻灯片有标题）。
ActivePresentation.Slides(1).Shapes.Title _
    .TextFrame.TextRange.Font.Italic = True
ActivePresentation.Slides(1).Shapes.Placeholders(1) _
    .TextFrame.TextRange.Font.Italic = True
ActivePresentation.Slides(1).Shapes(1).TextFrame _
    .TextRange.Font.Italic = True
返回与连接符的端点相连的形状
若要返回一个 Shape对象，该对象代表连接符所连接的形状之一，请使用BeginConnectedShape 或EndConnectedShape属性。
返回演示文稿的默认形状
若要返回代表演示文稿默认形状的 Shape对象，请使用DefaultShape属性。
返回新建的任意多边形
使用BuildFreeform 和AddNodes方法定义新任意多边形的几何外形，使用ConvertToShape方法创建任意多边形并返回代表该形状的 Shape对象。
返回组中的单个形状
使用 GroupItems(index) 返回代表组合形状中的单个形状的 Shape对象，其中 index 是组中形状的名称或索引号。
返回新组成的形状组
使用Group 或Regroup方法对若干形状进行组合，并返回代表新建组的单个 Shape对象。创建组后，可以如使用任何其他形状一样使用该组。

weiyingde

ShapeNode对象
Shapes (Shape)
ShapeNodes (ShapeNode)
代表用户定义任意多边形的结点的几何外形和几何编辑属性。结点包括任意多边形的线段之间的顶点和曲线段的控制点。ShapeNode对象是ShapeNodes集合的成员。ShapeNodes集合包含任意多边形的所有结点。
使用 ShapeNode对象
使用 Nodes（index），返回一单一 ShapeNode对象，此处 index 是结点索引号。如果在myDocument 上第三个形状中的第一个结点是一个角的顶点，则以下示例使其成为平滑顶点。要使此示例运行，形状三必须是任意多边形。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes(3)
    If .Nodes(1).EditingType = msoEditingCorner Then
        .Nodes.SetEditingType 1, msoEditingSmooth
    End If
End With
ShapeNodes集合对象
Shapes (Shape)
ShapeNodes (ShapeNode)
指定任意多边形中所有ShapeNode对象的集合。每个 ShapeNode对象代表任意多边形段间的结点或曲线段的控制点。可以手动或使用BuildFreeform 和ConvertToShape方法创建任意多边形。
使用 ShapeNodes集合
使用 Nodes属性返回 ShapeNodes集合。以下示例在myDocument 上删除第三个形状三中的第四个结点。要使该示例运行，第三个形状至少是一有四个结点的任意多边形。
Set myDocument = ActivePresentation.Slides(1)
myDocument.Shapes(3).Nodes.Delete 4
使用Insert方法创建一新结点并且将此结点添加到 ShapeNodes集合中。以下示例在myDocument 上的第三个形状中的第四个结点之后添加一带有曲线段的平滑结点。要使此示例运行，第三个形状必须是至少有四个结点的任意多边形。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes(3).Nodes
    .Insert 4, msoSegmentCurve, msoEditingSmooth, 210, 100
End With
使用 Nodes（index），返回一单一 ShapeNode对象，此处 index 是结点索引号。如果在myDocument 上第三个形状中的第一个结点是一个角部顶点，则以下示例使其成为平滑顶点。要使此示例运行，第三个形状必须是任意多边形。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes(3)
    If .Nodes(1).EditingType = msoEditingCorner Then
        .Nodes.SetEditingType 1, msoEditingSmooth
    End If
End With
ShapeRange集合对象
多个对象
ShapeRange (Shape)
  多个对象
表示一个形状范围，该范围包含文档上的一组形状。形状范围包含的形状少则一个，多则文档上的所有形状。要构造形状范围，可从文档上的所有形状或选定的所有形状中选择所需的任何形状。例如，可以构造一个 ShapeRange集合，该集合在包含文档上前三个形状、所有选取的形状或所有任意多边形。
关于如何使用一个形状或同时使用多个形状的概述，请参阅使用形状（绘图对象）。
使用 ShapeRange集合
本节描述如何：
返回指定名称或索引号的一组形状。
返回文档上所有或部分选定形状。
返回指定名称或索引号的一组形状
使用 Shapes.Range(index) 返回代表文档上一组形状的 ShapeRange集合，此处 index 是形状或包含名称或索引的数组的名称或索引号。可以使用 Array函数来构造名称或索引号数组。以下示例对myDocument 上的第一个和第三个形状设置填充模式。
Set myDocument = ActivePresentation.Slides(1)
myDocument.Shapes.Range(Array(1, 3)).Fill _
    .Patterned msoPatternHorizontalBrick
以下示例为myDocument 上名为“Oval 4”和“Rectangle 5”的形状设置填充模式。
Set myDocument = ActivePresentation.Slides(1)
Set myRange = myDocument.Shapes _
    .Range(Array("Oval 4", "Rectangle 5"))
myRange.Fill.Patterned msoPatternHorizontalBrick
虽然可以使用Range 方法返回任意数量的形状或幻灯片，如果仅想返回一个集合成员，则使用Item 方法更为简单。例如，Shapes(1) 比 Shapes.Range(1) 简单。
返回文档中所有或部分选定形状
使用 Selection对象的ShapeRange属性返回选定对象中的所有形状。以下示例设置第一个窗口中选定对象的所有形状的填充前景颜色（假设选定对象中至少有一个形状）。
Windows(1).Selection.ShapeRange.Fill.ForeColor _
    .RGB = RGB(255, 0, 255)
使用 Selection.ShapeRange(index) 返回选定对象中的单个形状，其中 index 是形状的名称或索引号。以下示例设置第一个窗口选定形状的集合中第二个形状的前景填充颜色（假设选定对象中至少有两个形状）。
Windows(1).Selection.ShapeRange(2).Fill.ForeColor _
    .RGB = RGB(255, 0, 255)

weiyingde

Shapes集合对象
多个对象
Shapes
  多个对象
指定幻灯片中所有Shape对象的集合。每个 Shape对象代表绘图层中的一个对象，例如自选图形、任意多边形、OLE对象或图片。
注意  如果要使用文档中的部分形状（例如，只对文档中的自选图形或选定的形状进行操作），则必须构造一个包含要使用的形状的ShapeRange集合。关于一次使用单个形状或多个形状的概述，请参阅使用形状（绘图对象）。
使用 Shapes集合
使用 Shapes属性返回 Shapes集合。以下示例选择当前演示文稿中的所有形状。
ActivePresentation.Slides(1).Shapes.SelectAll
注意  如果要同时对文档中的所有形状进行某种操作（例如删除或设置一个属性），可使用Range方法不带参数来创建一个 ShapeRange对象（该对象包含 Shapes集合中的所有形状），然后对 ShapeRange对象应用适当的属性或方法。
使用AddCallout、AddComment、AddConnector、AddCurve、AddLabel、AddLine、AddMediaObject、AddOLEObject、AddPicture、AddPlaceholder、AddPolyline、AddShape、AddTable、AddTextbox、AddTextEffect 或AddTitle方法新建一个形状并将其添加到 Shapes集合中。将BuildFreeform方法和ConvertToShape方法联合使用，可以新建任意多边形并添加到该集合。以下示例在当前演示文稿中添加一个矩形。
ActivePresentation.Slides(1).Shapes.AddShape Type:=msoShapeRectangle, _
    Left:=50, Top:=50, Width:=100, Height:=200
使用 Shapes(index) 返回一个 Shape对象，其中 index 是该形状的名称或索引号。以下示例将当前演示文稿中第一个形状的填充设为预设的底纹。
ActivePresentation.Slides(1).Shapes(1).Fill _
    .PresetGradient Style:=msoGradientHorizontal, Variant:=1, _
    PresetGradientType:=msoGradientBrass
使用 Shapes.Range(index) 返回ShapeRange集合，其中 index 是该形状的名称或索引号或是一组形状的名称或索引号。该集合代表 Shapes集合的一个子集。以下示例设置当前演示文稿中第一个和第三个形状的填充图案。
ActivePresentation.Slides(1).Shapes.Range(Array(1, 3)).Fill _
    .Patterned Pattern:=msoPatternHorizontalBrick
使用 Shapes.Placeholders(index) 返回一个代表占位符的 Shape对象，其中 index 是占位符编号。如果指定的幻灯片有标题，使用 Shapes.Placeholders(1) 或 Shapes.Title 返回标题占位符。以下示例在当前演示文稿中添加一张幻灯片并为标题和副标题添加文本（副标题是此版式的幻灯片中的第二个占位符）。
With ActivePresentation.Slides.Add(Index:=1, Layout:=ppLayoutTitle).Shapes
    .Title.TextFrame.TextRange = "This is the title text"
    .Placeholders(2).TextFrame.TextRange = "This is subtitle text"
End With

weiyingde

Slide对象
多个对象
Slide
  多个对象
代表一个幻灯片。Slides集合包含演示文稿中的所有 Slide对象。
注意  如果试图返回对单张幻灯片的引用却得到了一个SlideRange对象时，请不要奇怪。单张的幻灯片既可以由 Slide对象返回也可以由只包含一个对象的SlideRange集合返回，这取决于返回该幻灯片引用的方式。例如，使用Add方法创建并返回对幻灯片的引用，幻灯片由 Slide对象表示。然而，如果使用Duplicate方法创建并返回对幻灯片的引用，则幻灯片由包含单张幻灯片的 SlideRange集合表示。因为应用于 Slide对象的所有属性和方法也可应用于包含单张幻灯片的 SlideRange集合，所以可对返回的幻灯片进行相同的操作，而不管它是由 Slide对象还是 SlideRange集合表示。
使用 Slide对象
本节描述如何：
返回一个以名称、索引号或幻灯片标识符指定的幻灯片
返回所选对象中的幻灯片
返回指定的任意文档窗口或幻灯片放映窗口中当前显示的幻灯片
新建幻灯片
返回一个以名称、索引号或幻灯片标识符指定的幻灯片
使用 Slides(index)（其中 index 为幻灯片名称或索引号）或 Slides.FindBySlideID(index)（其中 index 为幻灯片标识符）返回单个 Slide对象。以下示例设置当前演示文稿中第一张幻灯片的版式。
ActivePresentation.Slides(1).Layout = ppLayoutTitle
以下示例设置标识符为 265 的幻灯片的版式。
ActivePresentation.Slides.FindBySlideID(265).Layout = ppLayoutTitle
返回所选对象中的幻灯片
使用 Selection.SlideRange(index) 返回单个 Slide对象，其中 index 为所选对象中的幻灯片名称或索引号。以下示例设置当前窗口的所选对象中第一张幻灯片的版式（假设至少选定一张幻灯片）。
ActiveWindow.Selection.SlideRange(1).Layout = ppLayoutTitle
如果只选定了一张幻灯片，可以使用 Selection.SlideRange 返回包含选定幻灯片的 SlideRange集合。以下示例设置当前窗口当前所选对象中第一张幻灯片的版式（假设正好只选定一张幻灯片）。
ActiveWindow.Selection.SlideRange.Layout = ppLayoutTitle
返回指定的任意文档窗口或幻灯片放映窗口中当前显示的幻灯片
使用 Slide属性返回指定文档窗口或幻灯片放映窗口视图中当前显示的幻灯片。以下示例将第二个文档窗口中当前显示的幻灯片复制到剪贴板。
Windows(2).View.Slide.Copy
新建幻灯片
使用 Add方法新建幻灯片并添加到演示文稿中。以下示例在当前演示文稿的开头添加一个标题幻灯片。
ActivePresentation.Slides.Add 1, ppLayoutTitleOnly

weiyingde

SlideRange集合对象
多个对象
SlideRange (Slide)
  多个对象
代表备注页或幻灯片范围的集合，该范围是一组幻灯片，少则仅包含一个，多则包含演示文稿中的所有幻灯片。要构造幻灯片范围，可通过从演示文稿中的所有幻灯片或已选择的幻灯片中选择所需的任意幻灯片。例如，可以构造一个 SlideRange集合，它包含演示文稿中的前三张幻灯片、演示文稿中所有已选择的幻灯片或演示文稿中的所有标题幻灯片。
使用 SlideRange集合
本节描述如何：
返回有指定名称或索引号的一组幻灯片
返回演示文稿中所有或部分选定幻灯片
返回备注页
将属性和方法应用于幻灯片范围
返回指定名称或索引号的一组幻灯片
使用 Slides.Range(index) 返回代表演示文稿中一组幻灯片的 SlideRange集合，其中 index 为幻灯片名称或索引号，或者为包含幻灯片名称或索引号的数组。可以使用 Array函数构建名称或索引号数组。以下示例设置当前演示文稿第一张和第三张幻灯片的背景填充。
With ActivePresentation.Slides.Range(Array(1, 3))
    .FollowMasterBackground = False
    .Background.Fill.PresetGradient msoGradientHorizontal, _
         1, msoGradientLateSunset
End With
以下示例设置当前演示文稿中幻灯片“Intro”和“Big Chart”的背景填充。请注意，幻灯片创建时被自动赋予形如 Sliden（n 为一个整数）的名称。若要赋予幻灯片更有意义的名称，请使用Name属性。
With ActivePresentation.Slides.Range(Array("Intro", "Big Chart"))
    .FollowMasterBackground = False
    .Background.Fill.PresetGradient msoGradientHorizontal, _
        1, msoGradientLateSunset
End With
虽然可以使用Range方法返回任意数量的幻灯片，如果仅想返回一个 SlideRange集合的成员，则使用Item 方法更为简单。例如，Slides(1) 比 Slides.Range(1) 简单。
返回演示文稿中所有或部分选中幻灯片
使用Selection对象的SlideRange属性返回所有选中对象中的幻灯片。以下示例设置第一个窗口中所有选中幻灯片的背景填充（假设至少已选中一张幻灯片）。
With Windows(1).Selection.SlideRange
    .FollowMasterBackground = False
    .Background.Fill.PresetGradient msoGradientHorizontal, _
        1, msoGradientLateSunset
End With
使用 Selection.SlideRange(index) 从选中对象中返回一张幻灯片，其中 index 为幻灯片名称或索引号。以下示例设置第一个窗口的选中幻灯片集合中第二张幻灯片的背景填充（假设至少已选中两张幻灯片）。
With Windows(1).Selection.SlideRange(2)
    .FollowMasterBackground = False
    .Background.Fill.PresetGradient msoGradientHorizontal, _
        1, msoGradientLateSunset
End With
返回备注页
使用 NotesPage属性返回代表指定备注页的 SlideRange集合。以下示例在当前演示文稿第一张幻灯片备注页的第二个占位符（备注区）中插入文本。
ActivePresentation.Slides(1).NotesPage.Shapes _
    .Placeholders(2).TextFrame.TextRange.InsertAfter "Added Text"
将属性和方法应用于幻灯片范围
如同在用户界面中选中多个幻灯片并通过命令同时操作它们一样，通过建立一个 SlideRange集合并对其使用属性和方法，可以在编程中同时操作多个幻灯片。如同用户界面中用于单张幻灯片的命令不能用于多张幻灯片一样，某些应用于单独 Slide对象或只包含一张幻灯片的 SlideRange集合的属性和方法不能用于包含多张幻灯片的 SlideRange集合。一般情况下，如果选中多张幻灯片时，某些操作无法手动完成（例如返回某一幻灯片中的单个形状），则编程时也不能对包含多张幻灯片的 SlideRange集合进行该操作。
对于用户界面中可用于一张或多张选中幻灯片的操作（例如复制幻灯片到剪贴板或设置幻灯片背景填充），相应的属性和方法也可用于包含多张幻灯片的 SlideRange集合。下面是如何对多张幻灯片使用这些属性和方法的一些指导。
对 SlideRange集合应用某方法等价于对该集合中所有 Slide对象应用该方法。
设置 SlideRange集合的属性值等价于单独设置该区域中所有幻灯片的属性值（对于枚举类型的属性，设置“Mixed”值无效）。
如果集合中所有幻灯片的某一枚举类型属性有相同的值，SlideRange集合的该属性返回集合中单张幻灯片的属性值。如果集合中的幻灯片属性不同，该属性返回“Mixed”值。
如果在集合中的所有幻灯片关于某属性具有相同的属性值，则返回简单数据类型（例如 Long、Single 或 String）的 SlideRange集合的属性返回集合中单独幻灯片的该属性值。如果集合中的幻灯片该属性的属性值不都相同，则属性将返回 -2 或产生一个错误。例如，使用包含多个幻灯片的 SlideRange对象上的 Name属性将产生一个错误，因为每一幻灯片都有不同的 Name属性值。
幻灯片的某些格式属性不是通过直接应用于 SlideRange集合的属性和方法来设置，而是通过应用于包含在 SlideRange集合中对象的属性和方法来设置，例如 ColorScheme对象。如果所包含的对象代表用户界面中可用于多个对象的操作，则可以从包含多张幻灯片的 SlideRange集合返回该对象，且其属性和方法与前述规则相同。例如，可以使用 ColorScheme属性返回 ColorScheme对象，该对象代表用于指定 SlideRange集合中所有幻灯片的配色方案。设置该 ColorScheme对象的属性也将设置 SlideRange集合中所有单个幻灯片的 ColorScheme对象的这些属性。