如何将普通表变为交叉表

jjmysjg

《项目汇总》为基础表，《科目汇总》为结果表。
1、提取《项目汇总》表B列不重复值到《科目汇总》的C2向右.
2、提取《项目汇总》表C列不重复值到《科目汇总》的C3向右.
3、提取《项目汇总》表D列不重复值到《科目汇总》的A4向下.
4、提取《项目汇总》表E列不重复值到《科目汇总》的B4向下.
5、将《项目汇总》F列的数据，按照《科目汇总》B列与第三行的对应关系写入C4向下、向右。
希望用代码。

huang1314wei

看不懂你要达到什么目的

yiyiyicz

详细解释 “交叉表”
不要过于简单，做到不下载附件也能看懂

不知道你的交叉表是什么意思，很多判断交叉（关系）的场合，往往采用矩阵就可以解决。构造要达到目的地矩阵，最简单是用数组，当然也有不行的时候

jjmysjg

新上传了附件，请各位看看。谢谢

jjmysjg

huang1314wei 发表于 2015-7-2 06:22
看不懂你要达到什么目的

重新上传了附件

zez

数据透视表

jjmysjg

zez 发表于 2015-7-2 15:40
数据透视表

能用代码达到效果吗。谢谢

小花鹿

Sub test()
Dim d1, d2, d3, ar, i&, j&, d1k, d2k, br, s
Set d1 = CreateObject("scripting.dictionary")
Set d2 = CreateObject("scripting.dictionary")
Set d3 = CreateObject("scripting.dictionary")
ar = Sheet1.[a1].CurrentRegion
For i = 2 To UBound(ar)
    d1(ar(i, 4) & "|" & ar(i, 5)) = ""
    d2(ar(i, 2) & "|" & ar(i, 3)) = ""
    d3(ar(i, 4) & ar(i, 5) & ar(i, 2) & ar(i, 3)) = ar(i, 6)
Next i
ReDim br(d1.Count + 2, d2.Count + 2)
d1k = d1.keys
For i = 0 To UBound(d1k)
    br(i + 2, 0) = Split(d1k(i), "|")(0)
    br(i + 2, 1) = Split(d1k(i), "|")(1)
Next i
d2k = d2.keys
For i = 0 To UBound(d2k)
    br(0, i + 2) = Split(d2k(i), "|")(0)
    br(1, i + 2) = Split(d2k(i), "|")(1)
Next i
For i = 2 To UBound(br)
    For j = 2 To UBound(br, 2)
        s = br(i, 0) & br(i, 1) & br(0, j) & br(1, j)
        br(i, j) = d3(s)
    Next j
Next i
Sheet2.[a2].Resize(UBound(br) + 1, UBound(br, 2) + 1) = br
End Sub

zax010

Sub zz()
    Dim d1 As New Dictionary, d2 As New Dictionary, d3 As New Dictionary, ar
    ar = Sheet1.Range("A1").CurrentRegion
    For i = 2 To UBound(ar)
        d1(ar(i, 2)) = ar(i, 3): d2(ar(i, 4)) = ar(i, 5)
        d3(ar(i, 4) & ar(i, 2)) = d3(ar(i, 4) & ar(i, 2)) + ar(i, 6)
    Next
    Application.ScreenUpdating = False
    With Sheet3
        .UsedRange.Cells.ClearContents
        .[a4].Resize(d2.Count, 2) = Application.Transpose(Array(d2.Keys, d2.Items))
        .[c2].Resize(1, d1.Count) = d1.Keys: .[c3].Resize(1, d1.Count) = d1.Items
        For i = 4 To d2.Count + 3
            For j = 3 To d1.Count + 2
                .Cells(i, j) = d3(.Cells(i, 1).Value & .Cells(2, j).Value)
            Next
        Next
    End With
    Application.ScreenUpdating = True
End Sub

zax010

>>>>>>>>>>>>>>>>>>>>>>>>


交叉表-如何将普通表变为交叉表.rar (47.95 KB, 下载次数: 89)

2015-7-3 15:07 上传

点击文件名下载附件