在同一个单元格中提取多个金额进行求和

myonmy · 发表于 2015-4-4 09:55

用函数能否实现在同一个单元格中提取多个金额进行求和

BOOK1.zip (7.66 KB, 下载次数: 47)

交叉点 · 发表于 2015-4-4 10:53

试试
=SUMPRODUCT(--LOOKUP(ROW($1:$50)*2,ROW($1:$99),(0&TRIM(MID(SUBSTITUTE(SUBSTITUTE(E3,"；",","),",",REPT(" ",99)),(ROW($1:$99)-1)*99+1,99)))))
此外，E7单元格有一个全角逗号，如果要用公式处理，就再加套一层SUBSTITUTE函数。

wangjguo44 · 发表于 2015-4-4 11:29

本帖最后由 wangjguo44 于 2015-4-4 11:33 编辑

1、数据要规范：E列有单字节逗号，也有双字节逗号，还有日期与金额用分号隔开的（E7），都会造成计算错误。（附件已通过查找替换全部改成单字节逗号分号，错误也纠正）
2、写了公式，适合于笔数不超过15笔（因你E列最多14笔，超过未验证，是否要修改公式），金额不超过4位数。

=SUM(--(0&MID(TRIM(MID(SUBSTITUTE(E3,";",REPT(" ",100)),ROW($1:$25)*106-105,100)),FIND(",",TRIM(MID(SUBSTITUTE(E3,";",REPT(" ",100)),ROW($1:$25)*106-105,100))&",")+1,4)))

复制代码

念无 · 发表于 2015-4-4 11:39

BOOK1.zip (8.04 KB, 下载次数: 11)

=SUM(TEXT(MID(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(E3,"；",","),"，",","),",",REPT(" ",199)),COLUMN(A:Z)*2*199-199,199),"0;;0;!0")*1)

复制代码

交叉点 · 发表于 2015-4-4 12:15

=SUMPRODUCT(--(0&TRIM(MID(SUBSTITUTE(SUBSTITUTE(E3,"；",","),",",REPT(" ",99)),(ROW($1:$99)-1)*200+99,99))))

ggmmlol · 发表于 2018-8-18 18:44

正则表达式

替换方法：把日期和非数字字符以及它们的组合替换成 +号

日期：月份-日期，表示为 \d+-\d+
非数字字符1个或以1个以上，表示为 \D+

表示这两者以上的组合，为 \d+-\d+|\D+
表示组合的数量是1个以上，就是(\d+-\d+|\D+)+

综合，即用正则对象查找：(\d+-\d+|\D+)+，替换为+

演示如下：

超级查找替换.rar (8.1 KB, 下载次数: 28)

超级替换67.gif

laowuwyx · 发表于 2018-8-18 19:27

=SUMPRODUCT(--TEXT(MID(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(ASC(E3),",","w(")&";",";",")w("),"-","w"),ROW($1:$999),COLUMN(A:Z)),"!0;0;0;!0"))

复制代码

		自动登录	找回密码
密码			免费注册